configure.in

   1 #
   2 # ngIRCd -- The Next Generation IRC Daemon
   3 # Copyright (c)2001-2012 Alexander Barton (alex@barton.de) and Contributors
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 # Please read the file COPYING, README and AUTHORS for more information.
  10 #
  11
  12 define(VERSION_ID,esyscmd(git describe|sed -e 's/rel-//g'|sed -e 's/-/~/'|tr -d \\n))
  13
  14 # -- Initialisation --
  15
  16 AC_PREREQ([2.67])
  17 AC_INIT([ngIRCd], VERSION_ID,
  18         [ngircd-ml@ngircd.barton.de], [ngircd], [http://ngircd.barton.de/])
  19
  20 AC_CONFIG_SRCDIR([src/ngircd/ngircd.c])
  21 AC_CONFIG_HEADER([src/config.h])
  22 AC_CANONICAL_TARGET
  23
  24 AM_INIT_AUTOMAKE([1.11])
  25
  26 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  27
  28 # -- Templates for config.h --
  29
  30 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
  31 AH_TEMPLATE([HAVE_sockaddr_in_len], [Define if sockaddr_in.sin_len exists])
  32 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
  33 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
  34 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
  35 AH_TEMPLATE([PAM], [Define if PAM should be used])
  36 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
  37 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
  38 AH_TEMPLATE([SYSLOG], [Define if syslog should be used for logging])
  39 AH_TEMPLATE([TCPWRAP], [Define if TCP wrappers should be used])
  40 AH_TEMPLATE([WANT_IPV6], [Define if IPV6 protocol should be enabled])
  41 AH_TEMPLATE([ZLIB], [Define if zlib compression should be enabled])
  42
  43 AH_TEMPLATE([TARGET_OS], [Target operating system name])
  44 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
  45 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
  46
  47 # -- C Compiler --
  48
  49 AC_PROG_CC
  50 AC_PROG_CC_STDC
  51
  52 # -- Helper programs --
  53
  54 AC_PROG_AWK
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_RANLIB
  59
  60 # -- Compiler Features --
  61
  62 AC_C_CONST
  63 AC_C_INLINE
  64 AM_C_PROTOTYPES
  65
  66 # -- Hard coded system and compiler dependencies/features/options ... --
  67
  68 AC_DEFUN([GCC_STACK_PROTECT_CC],[
  69   ssp_cc=yes
  70   # we use -fstack-protector-all for the test to enfoce the use of the guard variable
  71   AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
  72   ssp_old_cflags="$CFLAGS"
  73   CFLAGS="$CFLAGS -fstack-protector-all"
  74   AC_TRY_LINK(,,, ssp_cc=no)
  75   echo $ssp_cc
  76   CFLAGS="$ssp_old_cflags"
  77   if test "X$ssp_cc" = "Xyes"; then
  78       CFLAGS="$CFLAGS -fstack-protector"
  79       AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
  80   fi
  81 ])
  82
  83 if test "$GCC" = "yes"; then
  84         # We are using the GNU C compiler. Good!
  85         CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
  86
  87         GCC_STACK_PROTECT_CC
  88 fi
  89
  90 case "$target_os" in
  91         hpux*)
  92                 # This is HP/UX, we need to define _XOPEN_SOURCE_EXTENDED
  93                 # (tested with HP/UX 11.11)
  94                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
  95                 ;;
  96 esac
  97
  98 # Add additional CFLAGS, eventually specified on the command line:
  99 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
 100
 101 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
 102
 103 # -- Headers --
 104
 105 AC_HEADER_STDC
 106 AC_HEADER_SYS_WAIT
 107 AC_HEADER_TIME
 108
 109 # Required header files
 110 AC_CHECK_HEADERS([ \
 111         fcntl.h netdb.h netinet/in.h netinet/in_systm.h stdlib.h string.h \
 112         strings.h sys/socket.h sys/time.h unistd.h \
 113         ],,AC_MSG_ERROR([required C header missing!]))
 114
 115 # Optional header files
 116 AC_CHECK_HEADERS([ \
 117         arpa/inet.h inttypes.h malloc.h netinet/ip.h stdbool.h stddef.h \
 118         stdint.h varargs.h \
 119         ])
 120
 121 # -- Datatypes --
 122
 123 AC_MSG_CHECKING(whether socklen_t exists)
 124 AC_TRY_COMPILE([
 125 #include <sys/types.h>
 126 #include <sys/socket.h>
 127         ],[
 128         socklen_t a, b;
 129         a = 2; b = 4; a += b;
 130         ],[
 131         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
 132         ],[
 133         AC_MSG_RESULT(no)
 134 ])
 135
 136 AC_TYPE_PID_T
 137 AC_TYPE_SIGNAL
 138 AC_TYPE_SIZE_T
 139 AC_TYPE_SSIZE_T
 140 AC_TYPE_UID_T
 141 AC_TYPE_UINT16_T
 142 AC_TYPE_UINT32_T
 143 AC_TYPE_UINT8_T
 144
 145 AC_CHECK_MEMBER([struct sockaddr_in.sin_len], AC_DEFINE(HAVE_sockaddr_in_len),,
 146  [#include <arpa/inet.h>])
 147
 148 # -- Libraries --
 149
 150 # A/UX needs this.
 151 AC_CHECK_LIB(UTIL,memmove)
 152 # needed on solaris. GNU libc also has a libnsl, but we do not need it.
 153 AC_SEARCH_LIBS(gethostbyname,nsl)
 154 AC_CHECK_LIB(socket,bind)
 155
 156 # -- Functions --
 157
 158 AC_FUNC_FORK
 159 AC_FUNC_MALLOC
 160 AC_FUNC_REALLOC
 161 AC_FUNC_STRFTIME
 162
 163 # Required functions
 164 AC_CHECK_FUNCS([ \
 165         alarm dup2 endpwent gethostbyaddr gethostbyname gethostname \
 166         gettimeofday inet_ntoa memmove memset setsid socket strcasecmp \
 167         strchr strcspn strerror strncasecmp strrchr strspn strstr \
 168         ],,
 169         AC_MSG_ERROR([required function missing!]))
 170
 171 # Optional functions
 172 AC_CHECK_FUNCS([ \
 173         gai_strerror getaddrinfo getnameinfo inet_aton sigaction sigprocmask \
 174         snprintf vsnprintf strdup strlcpy strlcat strtok_r waitpid])
 175
 176 # -- Configuration options --
 177
 178 # use syslog?
 179
 180 x_syslog_on=no
 181 AC_ARG_WITH(syslog,
 182         [  --without-syslog        disable syslog (autodetected by default)],
 183         [       if test "$withval" != "no"; then
 184                         if test "$withval" != "yes"; then
 185                                 CFLAGS="-I$withval/include $CFLAGS"
 186                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 187                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 188                         fi
 189                         AC_CHECK_LIB(be, syslog)
 190                         AC_CHECK_FUNCS(syslog, x_syslog_on=yes,
 191                                 AC_MSG_ERROR([Can't enable syslog!])
 192                         )
 193                 fi
 194         ],
 195         [
 196                 AC_CHECK_LIB(be, syslog)
 197                 AC_CHECK_FUNCS(syslog, x_syslog_on=yes)
 198         ]
 199 )
 200 if test "$x_syslog_on" = "yes"; then
 201         AC_DEFINE(SYSLOG, 1)
 202         AC_CHECK_HEADERS(syslog.h,,AC_MSG_ERROR([required C header missing!]))
 203 fi
 204
 205 # use zlib compression?
 206
 207 x_zlib_on=no
 208 AC_ARG_WITH(zlib,
 209         [  --without-zlib          disable zlib compression (autodetected by default)],
 210         [       if test "$withval" != "no"; then
 211                         if test "$withval" != "yes"; then
 212                                 CFLAGS="-I$withval/include $CFLAGS"
 213                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 214                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 215                         fi
 216                         AC_CHECK_LIB(z, deflate)
 217                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
 218                                 AC_MSG_ERROR([Can't enable zlib!])
 219                         )
 220                 fi
 221         ],
 222         [       AC_CHECK_LIB(z, deflate)
 223                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
 224         ]
 225 )
 226 if test "$x_zlib_on" = "yes"; then
 227         AC_DEFINE(ZLIB, 1)
 228         AC_CHECK_HEADERS(zlib.h,,AC_MSG_ERROR([required C header missing!]))
 229 fi
 230
 231 # detect which IO API to use:
 232
 233 x_io_backend=none
 234
 235 AC_ARG_WITH(select,
 236         [  --without-select        disable select IO support (autodetected by default)],
 237         [       if test "$withval" != "no"; then
 238                         if test "$withval" != "yes"; then
 239                                 CFLAGS="-I$withval/include $CFLAGS"
 240                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 241                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 242                         fi
 243                         AC_CHECK_FUNCS(select, x_io_select=yes,
 244                                 AC_MSG_ERROR([Can't enable select IO support!])
 245                         )
 246                 fi
 247         ],
 248         [
 249                 AC_CHECK_FUNCS(select, x_io_select=yes)
 250         ]
 251 )
 252
 253 AC_ARG_WITH(poll,
 254         [  --without-poll          disable poll support (autodetected by default)],
 255         [       if test "$withval" != "no"; then
 256                         if test "$withval" != "yes"; then
 257                                 CFLAGS="-I$withval/include $CFLAGS"
 258                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 259                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 260                         fi
 261                         AC_CHECK_FUNCS(poll, [
 262                                 AC_CHECK_HEADERS(poll.h,
 263                                         x_io_backend=poll\(\),
 264                                         AC_MSG_ERROR(
 265                                              [Can't enable poll IO support!])
 266                                 )
 267                         ], [
 268                                 AC_MSG_ERROR([Can't enable poll IO support!])
 269                         ])
 270                 fi
 271         ],
 272         [
 273                 AC_CHECK_FUNCS(poll, [
 274                         AC_CHECK_HEADERS(poll.h, x_io_backend=poll\(\))
 275                 ])
 276         ]
 277 )
 278
 279 AC_ARG_WITH(devpoll,
 280         [  --without-devpoll       disable /dev/poll IO support (autodetected by default)],
 281         [       if test "$withval" != "no"; then
 282                         if test "$withval" != "yes"; then
 283                                 CFLAGS="-I$withval/include $CFLAGS"
 284                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 285                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 286                         fi
 287
 288                                 AC_CHECK_HEADERS(sys/devpoll.h,,AC_MSG_ERROR([required C header missing!]))
 289                 fi
 290         ],
 291         [
 292                 AC_CHECK_HEADERS(sys/devpoll.h, x_io_backend=/dev/poll)
 293         ]
 294 )
 295
 296 AC_ARG_WITH(epoll,
 297         [  --without-epoll         disable epoll IO support (autodetected by default)],
 298         [       if test "$withval" != "no"; then
 299                         if test "$withval" != "yes"; then
 300                                 CFLAGS="-I$withval/include $CFLAGS"
 301                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 302                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 303                         fi
 304                         AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes,
 305                                 AC_MSG_ERROR([Can't enable epoll IO support!])
 306                         )
 307                 fi
 308         ],
 309         [
 310                 AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes)
 311         ]
 312 )
 313
 314 AC_ARG_WITH(kqueue,
 315         [  --without-kqueue        disable kqueue IO support (autodetected by default)],
 316         [       if test "$withval" != "no"; then
 317                         if test "$withval" != "yes"; then
 318                                 CFLAGS="-I$withval/include $CFLAGS"
 319                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 320                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 321                         fi
 322                         AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\),
 323                                 AC_MSG_ERROR([Can't enable kqueue IO support!])
 324                         )
 325                 fi
 326         ],
 327         [
 328                 AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\))
 329         ]
 330 )
 331
 332 if test "$x_io_epoll" = "yes" -a "$x_io_select" = "yes"; then
 333         # when epoll() and select() are available, we'll use both!
 334         x_io_backend="epoll(), select()"
 335 else
 336         if test "$x_io_epoll" = "yes"; then
 337                 # we prefere epoll() if it is available
 338                 x_io_backend="epoll()"
 339         else
 340                 if test "$x_io_select" = "yes" -a "$x_io_backend" = "none"; then
 341                         # we'll use select, when available and no "better"
 342                         # interface has been detected ...
 343                         x_io_backend="select()"
 344                 fi
 345         fi
 346 fi
 347
 348 if test "$x_io_backend" = "none"; then
 349         AC_MSG_ERROR([No useable IO API activated/found!?])
 350 fi
 351
 352 # use SSL?
 353
 354 AC_ARG_WITH(openssl,
 355         [  --with-openssl          enable SSL support using OpenSSL],
 356         [       if test "$withval" != "no"; then
 357                         if test "$withval" != "yes"; then
 358                                 CFLAGS="-I$withval/include $CFLAGS"
 359                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 360                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 361                         fi
 362                         AC_CHECK_LIB(crypto, BIO_s_mem)
 363                         AC_CHECK_LIB(ssl, SSL_library_init)
 364                         AC_CHECK_FUNCS(SSL_library_init, x_ssl_openssl=yes,
 365                                 AC_MSG_ERROR([Can't enable openssl])
 366                         )
 367                 fi
 368         ]
 369 )
 370
 371 AC_ARG_WITH(gnutls,
 372         [  --with-gnutls           enable SSL support using gnutls],
 373         [       if test "$withval" != "no"; then
 374                         if test "$withval" != "yes"; then
 375                                 CFLAGS="-I$withval/include $CFLAGS"
 376                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 377                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 378                         fi
 379                         AC_CHECK_LIB(gnutls, gnutls_global_init)
 380                         AC_CHECK_FUNCS(gnutls_global_init, x_ssl_gnutls=yes,
 381                                 AC_MSG_ERROR([Can't enable gnutls])
 382                         )
 383                 fi
 384         ]
 385 )
 386
 387 x_ssl_lib="no"
 388 if test "$x_ssl_gnutls" = "yes"; then
 389         if test "$x_ssl_openssl" = "yes";then
 390                 AC_MSG_ERROR([Cannot enable both gnutls and openssl])
 391         fi
 392         x_ssl_lib=gnutls
 393 fi
 394 if test "$x_ssl_openssl" = "yes"; then
 395         x_ssl_lib=openssl
 396 fi
 397
 398 # use TCP wrappers?
 399
 400 x_tcpwrap_on=no
 401 AC_ARG_WITH(tcp-wrappers,
 402         [  --with-tcp-wrappers     enable TCP wrappers support],
 403         [       if test "$withval" != "no"; then
 404                         if test "$withval" != "yes"; then
 405                                 CFLAGS="-I$withval/include $CFLAGS"
 406                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 407                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 408                         fi
 409                         AC_MSG_CHECKING(for hosts_access)
 410                         LIBS="-lwrap $LIBS"
 411                         AC_TRY_LINK([
 412 #include <tcpd.h>
 413 int allow_severity = 0;
 414 int deny_severity = 0;
 415                                 ],[
 416                                 tcpd_warn("link test");
 417                                 ],[
 418                                 AC_MSG_RESULT(yes)
 419                                 AC_DEFINE(TCPWRAP, 1)
 420                                 x_tcpwrap_on=yes
 421                                 ],[
 422                                 AC_MSG_RESULT(no)
 423                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
 424                         ])
 425                 fi
 426         ]
 427 )
 428
 429 # do IDENT requests using libident?
 430
 431 x_identauth_on=no
 432 AC_ARG_WITH(ident,
 433         [  --with-ident            enable "IDENT" ("AUTH") protocol support],
 434         [       if test "$withval" != "no"; then
 435                         if test "$withval" != "yes"; then
 436                                 CFLAGS="-I$withval/include $CFLAGS"
 437                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 438                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 439                         fi
 440                         AC_CHECK_LIB(ident, ident_id)
 441                         AC_CHECK_FUNCS(ident_id, x_identauth_on=yes,
 442                                 AC_MSG_ERROR([Can't enable IDENT support!])
 443                         )
 444                 fi
 445         ]
 446 )
 447 if test "$x_identauth_on" = "yes"; then
 448         AC_DEFINE(IDENTAUTH, 1)
 449         AC_CHECK_HEADERS(ident.h,,AC_MSG_ERROR([required C header missing!]))
 450 fi
 451
 452 # compile in PAM support?
 453
 454 x_pam_on=no
 455 AC_ARG_WITH(pam,
 456         [  --with-pam              enable user authentication using PAM],
 457         [       if test "$withval" != "no"; then
 458                         if test "$withval" != "yes"; then
 459                                 CFLAGS="-I$withval/include $CFLAGS"
 460                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 461                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 462                         fi
 463                         AC_CHECK_LIB(pam, pam_authenticate)
 464                         AC_CHECK_FUNCS(pam_authenticate, x_pam_on=yes,
 465                                 AC_MSG_ERROR([Can't enable PAM support!])
 466                         )
 467                 fi
 468         ]
 469 )
 470 if test "$x_pam_on" = "yes"; then
 471         AC_DEFINE(PAM, 1)
 472         AC_CHECK_HEADERS(security/pam_appl.h,pam_ok=yes)
 473         if test "$pam_ok" != "yes"; then
 474                 AC_CHECK_HEADERS(pam/pam_appl.h,pam_ok=yes,
 475                         AC_MSG_ERROR([required C header missing!]))
 476         fi
 477 fi
 478
 479 # compile in IRC+ protocol support?
 480
 481 x_ircplus_on=yes
 482 AC_ARG_ENABLE(ircplus,
 483         [  --disable-ircplus       disable IRC+ protocol],
 484         if test "$enableval" = "no"; then x_ircplus_on=no; fi
 485 )
 486 if test "$x_ircplus_on" = "yes"; then
 487         AC_DEFINE(IRCPLUS, 1)
 488 fi
 489
 490 # enable support for IPv6?
 491 x_ipv6_on=no
 492 AC_ARG_ENABLE(ipv6,
 493         [  --enable-ipv6           enable IPv6 protocol support],
 494         if test "$enableval" = "yes"; then x_ipv6_on=yes; fi
 495 )
 496 if test "$x_ipv6_on" = "yes"; then
 497         # getaddrinfo() and getnameinfo() are optional when not compiling
 498         # with IPv6 support, but are required for IPv6 to work!
 499         AC_CHECK_FUNCS([ \
 500                 getaddrinfo getnameinfo \
 501                 ],,AC_MSG_ERROR([required function missing for IPv6 support!]))
 502         AC_DEFINE(WANT_IPV6, 1)
 503 fi
 504
 505 # compile in IRC "sniffer"?
 506
 507 x_sniffer_on=no; x_debug_on=no
 508 AC_ARG_ENABLE(sniffer,
 509         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
 510         if test "$enableval" = "yes"; then
 511                 AC_DEFINE(SNIFFER, 1)
 512                 x_sniffer_on=yes; x_debug_on=yes
 513         fi
 514 )
 515
 516 # enable additional debugging code?
 517
 518 AC_ARG_ENABLE(debug,
 519         [  --enable-debug          show additional debug output],
 520         if test "$enableval" = "yes"; then x_debug_on=yes; fi
 521 )
 522 if test "$x_debug_on" = "yes"; then
 523         AC_DEFINE(DEBUG, 1)
 524         test "$GCC" = "yes" && CFLAGS="-pedantic $CFLAGS"
 525         AC_CHECK_FUNCS(mtrace)
 526 fi
 527
 528 # enable "strict RFC rules"?
 529
 530 x_strict_rfc_on=no
 531 AC_ARG_ENABLE(strict-rfc,
 532         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
 533         if test "$enableval" = "yes"; then
 534                 AC_DEFINE(STRICT_RFC, 1)
 535                 x_strict_rfc_on=yes
 536         fi
 537 )
 538
 539 # -- Definitions --
 540
 541 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
 542 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
 543 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
 544
 545 # Add additional CFLAGS, eventually specified on the command line, but after
 546 # running this configure script. Useful for "-Werror" for example.
 547 test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
 548
 549 # -- Generate files --
 550
 551 AC_CONFIG_FILES([ \
 552         Makefile \
 553         contrib/Anope/Makefile \
 554         contrib/Debian/Makefile \
 555         contrib/MacOSX/Makefile \
 556         contrib/MacOSX/ngIRCd.pmdoc/Makefile \
 557         contrib/MacOSX/ngIRCd.xcodeproj/Makefile \
 558         contrib/Makefile \
 559         doc/Makefile \
 560         doc/src/Makefile \
 561         man/Makefile \
 562         src/ipaddr/Makefile \
 563         src/Makefile \
 564         src/ngircd/Makefile \
 565         src/portab/Makefile \
 566         src/testsuite/Makefile \
 567         src/tool/Makefile \
 568 ])
 569
 570 AC_OUTPUT
 571
 572 type dpkg >/dev/null 2>&1
 573 if test $? -eq 0; then
 574         # Generate debian/ link if the dpkg command exists
 575         # (read: if we are running on a debian compatible system)
 576         echo "creating Debian-specific links ..."
 577         test -f debian/rules || ln -s contrib/Debian debian
 578 fi
 579
 580 # -- Result --
 581
 582 echo
 583 echo "ngIRCd $PACKAGE_VERSION has been configured with the following options:"
 584 echo
 585
 586 # Someone please show me a better way :)  [borrowed by OpenSSH]
 587 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
 588 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
 589 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
 590 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
 591 D=`eval echo ${docdir}` ; D=`eval echo ${D}`
 592
 593 echo "             Target: ${target}"
 594 test "$target" != "$host" && echo "               Host: ${host}"
 595 echo "           Compiler: ${CC}"
 596 test -n "$CFLAGS"       && echo "     Compiler flags: ${CFLAGS}"
 597 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
 598 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
 599 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
 600 echo
 601 echo "    'ngircd' binary: $S"
 602 echo " Configuration file: $C"
 603 echo "       Manual pages: $M"
 604 echo "      Documentation: $D"
 605 echo
 606
 607 echo $ECHO_N "     Syslog support: $ECHO_C"
 608 test "$x_syslog_on" = "yes" \
 609         && echo $ECHO_N "yes   $ECHO_C" \
 610         || echo $ECHO_N "no    $ECHO_C"
 611 echo $ECHO_N "  Enable debug code: $ECHO_C"
 612 test "$x_debug_on" = "yes" \
 613         && echo "yes" \
 614         || echo "no"
 615
 616 echo $ECHO_N "   zlib compression: $ECHO_C"
 617 test "$x_zlib_on" = "yes" \
 618         && echo $ECHO_N "yes   $ECHO_C" \
 619         || echo $ECHO_N "no    $ECHO_C"
 620 echo $ECHO_N "        IRC sniffer: $ECHO_C"
 621 test "$x_sniffer_on" = "yes" \
 622         && echo "yes" \
 623         || echo "no"
 624
 625 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
 626 test "$x_tcpwrap_on" = "yes" \
 627         && echo $ECHO_N "yes   $ECHO_C" \
 628         || echo $ECHO_N "no    $ECHO_C"
 629 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
 630 test "$x_strict_rfc_on" = "yes" \
 631         && echo "yes" \
 632         || echo "no"
 633
 634 echo $ECHO_N "      IDENT support: $ECHO_C"
 635 test "$x_identauth_on" = "yes" \
 636         && echo $ECHO_N "yes   $ECHO_C" \
 637         || echo $ECHO_N "no    $ECHO_C"
 638 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
 639 test "$x_ircplus_on" = "yes" \
 640         && echo "yes" \
 641         || echo "no"
 642
 643 echo $ECHO_N "      IPv6 protocol: $ECHO_C"
 644 test "$x_ipv6_on" = "yes" \
 645         && echo $ECHO_N "yes   $ECHO_C" \
 646         || echo $ECHO_N "no    $ECHO_C"
 647 echo $ECHO_N "        I/O backend: $ECHO_C"
 648         echo "\"$x_io_backend\""
 649
 650 echo $ECHO_N "        PAM support: $ECHO_C"
 651 test "$x_pam_on" = "yes" \
 652         && echo $ECHO_N "yes   $ECHO_C" \
 653         || echo $ECHO_N "no    $ECHO_C"
 654 echo $ECHO_N "        SSL support: $ECHO_C"
 655 echo "$x_ssl_lib"
 656
 657 echo
 658
 659 # -eof-