configure.in

   1 #
   2 # ngIRCd -- The Next Generation IRC Daemon
   3 # Copyright (c)2001-2003 by Alexander Barton (alex@barton.de)
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 # Please read the file COPYING, README and AUTHORS for more information.
  10 #
  11 # $Id: configure.in,v 1.90 2003/04/22 18:44:03 alex Exp $
  12 #
  13
  14 # -- Initialisierung --
  15
  16 AC_PREREQ(2.50)
  17 AC_INIT(ngircd, CVSHEAD)
  18 AC_CONFIG_SRCDIR(src/ngircd/ngircd.c)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE(1.6)
  21 AM_CONFIG_HEADER(src/config.h)
  22
  23 # -- Templates fuer config.h --
  24
  25 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
  26 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
  27 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
  28 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
  29 AH_TEMPLATE([USE_SYSLOG], [Define if syslog should be used for logging])
  30 AH_TEMPLATE([USE_ZLIB], [Define if zlib compression should be enabled])
  31 AH_TEMPLATE([USE_TCPWRAP], [Define if TCP wrappers should be used])
  32 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
  33 AH_TEMPLATE([RENDEZVOUS], [Define if Rendezvous support should be included])
  34
  35 AH_TEMPLATE([TARGET_OS], [Target operating system name])
  36 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
  37 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
  38
  39 # -- C Compiler --
  40
  41 AC_PROG_CC
  42
  43 # -- Hilfsprogramme --
  44
  45 AC_PROG_AWK
  46 AC_PROG_INSTALL
  47 AC_PROG_LN_S
  48 AC_PROG_MAKE_SET
  49 AC_PROG_RANLIB
  50
  51 # -- Compiler Features --
  52
  53 AC_LANG_C
  54
  55 AM_C_PROTOTYPES
  56 AC_C_CONST
  57
  58 # -- Defines --
  59
  60 if test `uname` = "Linux"; then
  61         # define _POSIX_SOURCE, _GNU_SOURCE and _BSD_SOURCE when compiling
  62         # on Linux (glibc-based systems):
  63         AC_MSG_RESULT([detected Linux, defining _POSIX_SOURCE, _GNU_SOURCE and _BSD_SOURCE])
  64         add_DEFINES="-D_POSIX_SOURCE -D_GNU_SOURCE -D_BSD_SOURCE $add_DEFINES"
  65 fi
  66
  67 if test `uname` = "A/UX"; then
  68         # define _POSIX_SOURCE when compiling on A/UX:
  69         AC_MSG_RESULT([detected A/UX, defining _POSIX_SOURCE])
  70         add_DEFINES="-D_POSIX_SOURCE $add_DEFINES"
  71 fi
  72
  73 if test `uname` = "HP-UX"; then
  74         # define _XOPEN_SOURCE_EXTENDED when compiling on HP-UX (11.11):
  75         AC_MSG_RESULT([detected HP-UX, defining _XOPEN_SOURCE_EXTENDED])
  76         add_DEFINES="-D_XOPEN_SOURCE_EXTENDED $add_DEFINES"
  77 fi
  78
  79 if test `uname` = "SunOS"; then
  80         # define _XOPEN_SOURCE, _XOPEN_SOURCE_EXTENDED=1 and __EXTENSIONS__
  81         # when compiling on SunOS (tested with 5.6):
  82         AC_MSG_RESULT([detected SunOS, defining _XOPEN_SOURCE, _XOPEN_SOURCE_EXTENDED=1 and __EXTENSIONS__])
  83         add_DEFINES="-D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1 -D__EXTENSIONS__ $add_DEFINES"
  84 fi
  85
  86 # -- Header --
  87
  88 AC_HEADER_STDC
  89
  90 AC_HEADER_TIME
  91
  92 AC_HEADER_SYS_WAIT
  93
  94 AC_CHECK_HEADERS([ \
  95         ctype.h errno.h fcntl.h netdb.h netinet/in.h stdlib.h string.h \
  96         strings.h sys/socket.h sys/time.h unistd.h \
  97         ],,AC_MSG_ERROR([required C header missing!]))
  98
  99 AC_CHECK_HEADERS([arpa/inet.h ctype.h malloc.h stdint.h varargs.h])
 100
 101 # -- Datentypen --
 102
 103 AC_MSG_CHECKING(whether socklen_t exists)
 104 AC_TRY_COMPILE([
 105         #include <sys/socket.h>
 106         #include <sys/types.h>
 107         ],[
 108         socklen_t a, b;
 109         a = 2; b = 4; a += b;
 110         ],[
 111         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
 112         ],[
 113         AC_MSG_RESULT(no)
 114 ])
 115
 116 AC_TYPE_SIGNAL
 117
 118 AC_TYPE_SIZE_T
 119
 120 # -- Libraries --
 121
 122 AC_CHECK_LIB(UTIL,memmove)
 123 AC_CHECK_LIB(socket,bind)
 124 AC_CHECK_LIB(nsl,gethostent)
 125
 126 # -- Funktionen --
 127
 128 AC_FUNC_MALLOC
 129
 130 AC_FUNC_FORK
 131
 132 AC_FUNC_STRFTIME
 133
 134 AC_CHECK_FUNCS([ \
 135         bind gethostbyaddr gethostbyname gethostname inet_ntoa memmove \
 136         memset setsockopt socket strcasecmp strchr strerror strstr waitpid \
 137         ],,AC_MSG_ERROR([required function missing!]))
 138
 139 AC_CHECK_FUNCS(inet_aton isdigit sigaction snprintf vsnprintf strlcpy strlcat)
 140
 141 AC_CHECK_FUNCS(select,[AC_CHECK_HEADERS(sys/select.h)],
 142         AC_MSG_ERROR([required function select() is missing!])
 143 )
 144
 145 # -- Konfigurationsoptionen --
 146
 147 x_syslog_on=no
 148 AC_ARG_WITH(syslog,
 149         [  --without-syslog        disable syslog (autodetected by default)],
 150         [       if test "$withval" = "yes"; then
 151                         AC_CHECK_LIB(be, syslog)
 152                         AC_CHECK_FUNCS(syslog, x_syslog_on=yes,
 153                                 AC_MSG_ERROR([Can't enable syslog!])
 154                         )
 155                 fi
 156         ],
 157         [
 158                 AC_CHECK_LIB(be, syslog)
 159                 AC_CHECK_FUNCS(syslog, x_syslog_on=yes)
 160         ]
 161 )
 162 if test "$x_syslog_on" = "yes"; then
 163         AC_DEFINE(USE_SYSLOG, 1)
 164         AC_CHECK_HEADERS(syslog.h)
 165 fi
 166
 167 x_zlib_on=no
 168 AC_ARG_WITH(zlib,
 169         [  --without-zlib          disable zlib compression (autodetected by default)],
 170         [       if test "$withval" = "yes"; then
 171                         AC_CHECK_LIB(z, deflate)
 172                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
 173                                 AC_MSG_ERROR([Can't enable zlib!])
 174                         )
 175                 fi
 176         ],
 177         [       AC_CHECK_LIB(z, deflate)
 178                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
 179         ]
 180 )
 181 if test "$x_zlib_on" = "yes"; then
 182         AC_DEFINE(USE_ZLIB, 1)
 183         AC_CHECK_HEADERS(zlib.h)
 184 fi
 185
 186 x_tcpwrap_on=no
 187 AC_ARG_WITH(tcp-wrappers,
 188         [  --with-tcp-wrappers     enable TCP wrappers support],
 189         [       if test "$withval" = "yes"; then
 190                         AC_CHECK_LIB(wrap, tcpd_warn)
 191                         AC_MSG_CHECKING(for hosts_access)
 192                         AC_TRY_LINK([
 193                                 #include <tcpd.h>
 194                                 ],[
 195                                 void *ptr;
 196                                 ptr = hosts_access;
 197                                 ],[
 198                                 AC_MSG_RESULT(yes)
 199                                 AC_DEFINE(USE_TCPWRAP, 1)
 200                                 x_tcpwrap_on=yes
 201                                 ],[
 202                                 AC_MSG_RESULT(no)
 203                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
 204                         ])
 205                 fi
 206         ]
 207 )
 208
 209 x_rendezvous_on=no
 210 AC_ARG_WITH(rendezvous,
 211         [  --with-rendezvous       enable support for "Rendezvous"],
 212         [       if test "$withval" = "yes"; then
 213                         AC_CHECK_FUNCS(DNSServiceRegistrationCreate, x_rendezvous_on=yes,
 214                                 AC_MSG_ERROR([Can't enable Rendezvous!])
 215                         )
 216                 fi
 217         ]
 218 )
 219 if test "$x_rendezvous_on" = "yes"; then
 220         AC_DEFINE(RENDEZVOUS, 1)
 221         AC_CHECK_HEADERS(DNSServiceDiscovery/DNSServiceDiscovery.h mach/port.h)
 222 fi
 223
 224 x_ircplus_on=yes
 225 AC_ARG_ENABLE(ircplus,
 226         [  --disable-ircplus       disable IRC+ protocol],
 227         if test "$enableval" = "no"; then x_ircplus_on=no; fi
 228 )
 229 if test "$x_ircplus_on" = "yes"; then
 230         AC_DEFINE(IRCPLUS, 1)
 231 fi
 232
 233 x_sniffer_on=no; x_debug_on=no
 234 AC_ARG_ENABLE(sniffer,
 235         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
 236         if test "$enableval" = "yes"; then
 237                 AC_DEFINE(SNIFFER, 1)
 238                 x_sniffer_on=yes; x_debug_on=yes
 239         fi
 240 )
 241
 242 AC_ARG_ENABLE(debug,
 243         [  --enable-debug          show additional debug output],
 244         if test "$enableval" = "yes"; then x_debug_on=yes; fi
 245 )
 246 if test "$x_debug_on" = "yes"; then
 247         AC_DEFINE(DEBUG, 1)
 248 fi
 249
 250 x_strict_rfc_on=no
 251 AC_ARG_ENABLE(strict-rfc,
 252         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
 253         if test "$enableval" = "yes"; then
 254                 AC_DEFINE(STRICT_RFC, 1)
 255                 x_strict_rfc_on=yes
 256         fi
 257 )
 258
 259 # -- Definitionen --
 260
 261 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
 262 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
 263 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
 264
 265 # -- Variablen --
 266
 267 if test "$GCC" = "yes"; then
 268         the_CFLAGS="-Wmissing-declarations -Wpointer-arith -Wstrict-prototypes"
 269         add_CFLAGS="-Wall -W -ansi -pedantic $CFLAGS $CFLAGS_ADD"
 270 else
 271         the_CFLAGS="$CFLAGS"
 272         add_CFLAGS="$CFLAGS_ADD"
 273 fi
 274
 275 CFLAGS="$the_CFLAGS $add_CFLAGS $add_DEFINES -DSYSCONFDIR='\"\$(sysconfdir)\"'"
 276
 277 # -- Ausgabe der Dateien --
 278
 279 AC_OUTPUT([ \
 280         Makefile \
 281         doc/Makefile \
 282         MacOSX/Makefile \
 283         MacOSX/ngircd.pbproj/Makefile \
 284         src/Makefile \
 285         src/portab/Makefile \
 286         src/tool/Makefile \
 287         src/ngircd/Makefile \
 288         src/testsuite/Makefile \
 289         man/Makefile \
 290         contrib/Makefile \
 291 ])
 292
 293 # -- Result --
 294
 295 echo
 296 echo "ngIRCd has been configured with the following options:"
 297 echo
 298
 299 # Someone please show me a better way :)  [borrowed by OpenSSH]
 300 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
 301 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
 302 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
 303 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
 304 D=`eval echo ${datadir}/doc/${PACKAGE}` ; D=`eval echo ${D}`
 305
 306 echo "               Host: ${host}"
 307 echo "           Compiler: ${CC}"
 308 echo "     Compiler flags: ${the_CFLAGS}"
 309 test -n "$add_CFLAGS"   && echo "                     ${add_CFLAGS}"
 310 test -n "$add_DEFINES"  && echo "                     ${add_DEFINES}"
 311 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
 312 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
 313 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
 314 echo
 315 echo "    'ngircd' binary: $S"
 316 echo " Configuration file: $C"
 317 echo "       Manual pages: $M"
 318 echo "      Documentation: $D"
 319 echo
 320
 321 echo $ECHO_N "     Syslog support: $ECHO_C"
 322 test "$x_syslog_on" = "yes" \
 323         && echo $ECHO_N "yes $ECHO_C" \
 324         || echo $ECHO_N "no  $ECHO_C"
 325 echo $ECHO_N "  Enable debug code: $ECHO_C"
 326 test "$x_debug_on" = "yes" \
 327         && echo "yes" \
 328         || echo "no"
 329
 330 echo $ECHO_N "   zlib compression: $ECHO_C"
 331 test "$x_zlib_on" = "yes" \
 332         && echo $ECHO_N "yes $ECHO_C" \
 333         || echo $ECHO_N "no  $ECHO_C"
 334 echo $ECHO_N "        IRC sniffer: $ECHO_C"
 335 test "$x_sniffer_on" = "yes" \
 336         && echo "yes" \
 337         || echo "no"
 338
 339 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
 340 test "$x_tcpwrap_on" = "yes" \
 341         && echo $ECHO_N "yes $ECHO_C" \
 342         || echo $ECHO_N "no  $ECHO_C"
 343 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
 344 test "$x_strict_rfc_on" = "yes" \
 345         && echo "yes" \
 346         || echo "no"
 347
 348 echo $ECHO_N " Rendezvous support: $ECHO_C"
 349 test "$x_rendezvous_on" = "yes" \
 350         && echo $ECHO_N "yes $ECHO_C" \
 351         || echo $ECHO_N "no  $ECHO_C"
 352 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
 353 test "$x_ircplus_on" = "yes" \
 354         && echo "yes" \
 355         || echo "no"
 356 echo
 357
 358 # -eof-