5e334963975a660c92d95c7790054614aa5e9049
[ngircd-alex.git] / configure.in
1 #
2 # ngIRCd -- The Next Generation IRC Daemon
3 # Copyright (c)2001-2010 Alexander Barton <alex@barton.de>
4 #
5 # This program is free software; you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 2 of the License, or
8 # (at your option) any later version.
9 # Please read the file COPYING, README and AUTHORS for more information.
10 #
11
12 define(VERSION_ID,esyscmd(git describe|sed -e 's/rel-//g'|sed -e 's/-/~/'|tr -d \\n))
13
14 # -- Initialisation --
15
16 AC_PREREQ(2.50)
17 AC_INIT(ngircd, VERSION_ID)
18 AC_CONFIG_SRCDIR(src/ngircd/ngircd.c)
19 AC_CANONICAL_TARGET
20 AM_INIT_AUTOMAKE(1.6)
21 AM_CONFIG_HEADER(src/config.h)
22
23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
24
25 # -- Templates for config.h --
26
27 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
28 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
29 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
30 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
31 AH_TEMPLATE([SYSLOG], [Define if syslog should be used for logging])
32 AH_TEMPLATE([ZLIB], [Define if zlib compression should be enabled])
33 AH_TEMPLATE([TCPWRAP], [Define if TCP wrappers should be used])
34 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
35 AH_TEMPLATE([WANT_IPV6], [Define if IPV6 protocol should be enabled])
36 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
37 AH_TEMPLATE([PAM], [Define if PAM should be used])
38 AH_TEMPLATE([HAVE_sockaddr_in_len], [Define if sockaddr_in.sin_len exists])
39
40 AH_TEMPLATE([TARGET_OS], [Target operating system name])
41 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
42 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
43
44 # -- C Compiler --
45
46 AC_PROG_CC
47 AC_PROG_CC_STDC
48 AC_C_PROTOTYPES
49
50 # -- Helper programs --
51
52 AC_PROG_AWK
53 AC_PROG_INSTALL
54 AC_PROG_LN_S
55 AC_PROG_MAKE_SET
56 AC_PROG_RANLIB
57
58 # -- Compiler Features --
59
60 AM_C_PROTOTYPES
61 AC_C_CONST
62 AC_C_INLINE
63
64 # -- Hard coded system and compiler dependencies/features/options ... --
65
66 AC_DEFUN([GCC_STACK_PROTECT_CC],[
67   ssp_cc=yes
68   # we use -fstack-protector-all for the test to enfoce the use of the guard variable 
69   AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
70   ssp_old_cflags="$CFLAGS"
71   CFLAGS="$CFLAGS -fstack-protector-all"
72   AC_TRY_LINK(,,, ssp_cc=no)
73   echo $ssp_cc
74   CFLAGS="$ssp_old_cflags"
75   if test "X$ssp_cc" = "Xyes"; then
76       CFLAGS="$CFLAGS -fstack-protector"
77       AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
78   fi
79 ])
80
81 if test "$GCC" = "yes"; then
82         # We are using the GNU C compiler. Good!
83         CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
84
85         GCC_STACK_PROTECT_CC
86 fi
87
88 case "$target_os" in
89         hpux*)
90                 # This is HP/UX, we need to define _XOPEN_SOURCE_EXTENDED
91                 # (tested with HP/UX 11.11)
92                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
93                 ;;
94 esac
95
96 # Add additional CFLAGS, eventually specified on the command line:
97 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
98
99 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
100
101 # -- Headers --
102
103 AC_HEADER_STDC
104 AC_HEADER_TIME
105 AC_HEADER_SYS_WAIT
106
107 AC_CHECK_HEADERS([ \
108         ctype.h errno.h fcntl.h netdb.h netinet/in.h netinet/in_systm.h \
109         stdlib.h string.h strings.h sys/socket.h sys/time.h unistd.h \
110         ],,AC_MSG_ERROR([required C header missing!]))
111
112 AC_CHECK_HEADERS([ \
113         arpa/inet.h ctype.h malloc.h netinet/ip.h stdbool.h stddef.h varargs.h \
114         ],[],[],[[
115         #ifdef HAVE_SYS_TYPES_H
116                 #include <sys/types.h>
117         #endif
118         #ifdef HAVE_SYS_SOCKET_H
119                 #include <sys/socket.h>
120         #endif
121         #ifdef HAVE_NETINET_IN_H
122                 #include <netinet/in.h>
123         #endif
124         ]]
125 )
126
127 # -- Datatypes --
128
129 AC_MSG_CHECKING(whether socklen_t exists)
130 AC_TRY_COMPILE([
131 #include <sys/types.h>
132 #include <sys/socket.h>
133         ],[
134         socklen_t a, b;
135         a = 2; b = 4; a += b;
136         ],[
137         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
138         ],[
139         AC_MSG_RESULT(no)
140 ])
141
142 AC_TYPE_SIGNAL
143 AC_TYPE_SIZE_T
144
145 AC_CHECK_MEMBER([struct sockaddr_in.sin_len], AC_DEFINE(HAVE_sockaddr_in_len),,
146  [#include <arpa/inet.h>])
147
148 # -- Libraries --
149
150 # A/UX needs this.
151 AC_CHECK_LIB(UTIL,memmove)
152 # needed on solaris. GNU libc also has a libnsl, but we do not need it.
153 AC_SEARCH_LIBS(gethostbyname,nsl)
154 AC_CHECK_LIB(socket,bind)
155
156 # -- Functions --
157
158 AC_FUNC_FORK
159 AC_FUNC_STRFTIME
160
161 AC_CHECK_FUNCS([ \
162         bind gethostbyaddr gethostbyname gethostname inet_ntoa \
163         setsid setsockopt socket strcasecmp waitpid],,AC_MSG_ERROR([required function missing!]))
164
165 AC_CHECK_FUNCS(getaddrinfo getnameinfo inet_aton sigaction sigprocmask snprintf \
166  vsnprintf strdup strlcpy strlcat strtok_r)
167
168 # -- Configuration options --
169
170 # use syslog?
171
172 x_syslog_on=no
173 AC_ARG_WITH(syslog,
174         [  --without-syslog        disable syslog (autodetected by default)],
175         [       if test "$withval" != "no"; then
176                         if test "$withval" != "yes"; then
177                                 CFLAGS="-I$withval/include $CFLAGS"
178                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
179                                 LDFLAGS="-L$withval/lib $LDFLAGS"
180                         fi
181                         AC_CHECK_LIB(be, syslog)
182                         AC_CHECK_FUNCS(syslog, x_syslog_on=yes,
183                                 AC_MSG_ERROR([Can't enable syslog!])
184                         )
185                 fi
186         ],
187         [
188                 AC_CHECK_LIB(be, syslog)
189                 AC_CHECK_FUNCS(syslog, x_syslog_on=yes)
190         ]
191 )
192 if test "$x_syslog_on" = "yes"; then
193         AC_DEFINE(SYSLOG, 1)
194         AC_CHECK_HEADERS(syslog.h,,AC_MSG_ERROR([required C header missing!]))
195 fi
196
197 # use zlib compression?
198
199 x_zlib_on=no
200 AC_ARG_WITH(zlib,
201         [  --without-zlib          disable zlib compression (autodetected by default)],
202         [       if test "$withval" != "no"; then
203                         if test "$withval" != "yes"; then
204                                 CFLAGS="-I$withval/include $CFLAGS"
205                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
206                                 LDFLAGS="-L$withval/lib $LDFLAGS"
207                         fi
208                         AC_CHECK_LIB(z, deflate)
209                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
210                                 AC_MSG_ERROR([Can't enable zlib!])
211                         )
212                 fi
213         ],
214         [       AC_CHECK_LIB(z, deflate)
215                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
216         ]
217 )
218 if test "$x_zlib_on" = "yes"; then
219         AC_DEFINE(ZLIB, 1)
220         AC_CHECK_HEADERS(zlib.h,,AC_MSG_ERROR([required C header missing!]))
221 fi
222
223 # detect which IO API to use:
224
225 x_io_backend=none
226
227 AC_ARG_WITH(select,
228         [  --without-select        disable select IO support (autodetected by default)],
229         [       if test "$withval" != "no"; then
230                         if test "$withval" != "yes"; then
231                                 CFLAGS="-I$withval/include $CFLAGS"
232                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
233                                 LDFLAGS="-L$withval/lib $LDFLAGS"
234                         fi
235                         AC_CHECK_FUNCS(select, x_io_select=yes,
236                                 AC_MSG_ERROR([Can't enable select IO support!])
237                         )
238                 fi
239         ],
240         [
241                 AC_CHECK_FUNCS(select, x_io_select=yes)
242         ]
243 )
244
245 AC_ARG_WITH(poll,
246         [  --without-poll          disable poll support (autodetected by default)],
247         [       if test "$withval" != "no"; then
248                         if test "$withval" != "yes"; then
249                                 CFLAGS="-I$withval/include $CFLAGS"
250                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
251                                 LDFLAGS="-L$withval/lib $LDFLAGS"
252                         fi
253                         AC_CHECK_FUNCS(poll, x_io_backend=poll\(\),
254                                 AC_MSG_ERROR([Can't enable poll IO support!])
255                         )
256                 fi
257         ],
258         [
259                 AC_CHECK_FUNCS(poll, x_io_backend=poll\(\))
260         ]
261 )
262
263 AC_ARG_WITH(devpoll,
264         [  --without-devpoll       disable /dev/poll IO support (autodetected by default)],
265         [       if test "$withval" != "no"; then
266                         if test "$withval" != "yes"; then
267                                 CFLAGS="-I$withval/include $CFLAGS"
268                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
269                                 LDFLAGS="-L$withval/lib $LDFLAGS"
270                         fi
271
272                                 AC_CHECK_HEADERS(sys/devpoll.h,,AC_MSG_ERROR([required C header missing!]))
273                 fi
274         ],
275         [
276                 AC_CHECK_HEADERS(sys/devpoll.h, x_io_backend=/dev/poll)
277         ]
278 )
279
280 AC_ARG_WITH(epoll,
281         [  --without-epoll         disable epoll IO support (autodetected by default)],
282         [       if test "$withval" != "no"; then
283                         if test "$withval" != "yes"; then
284                                 CFLAGS="-I$withval/include $CFLAGS"
285                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
286                                 LDFLAGS="-L$withval/lib $LDFLAGS"
287                         fi
288                         AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes,
289                                 AC_MSG_ERROR([Can't enable epoll IO support!])
290                         )
291                 fi
292         ],
293         [
294                 AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes)
295         ]
296 )
297
298 AC_ARG_WITH(kqueue,
299         [  --without-kqueue        disable kqueue IO support (autodetected by default)],
300         [       if test "$withval" != "no"; then
301                         if test "$withval" != "yes"; then
302                                 CFLAGS="-I$withval/include $CFLAGS"
303                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
304                                 LDFLAGS="-L$withval/lib $LDFLAGS"
305                         fi
306                         AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\),
307                                 AC_MSG_ERROR([Can't enable kqueue IO support!])
308                         )
309                 fi
310         ],
311         [
312                 AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\))
313         ]
314 )
315
316 if test "$x_io_epoll" = "yes" -a "$x_io_select" = "yes"; then
317         # when epoll() and select() are available, we'll use both!
318         x_io_backend="epoll(), select()"
319 else
320         if test "$x_io_epoll" = "yes"; then
321                 # we prefere epoll() if it is available
322                 x_io_backend="epoll()"
323         else
324                 if test "$x_io_select" = "yes" -a "$x_io_backend" = "none"; then
325                         # we'll use select, when available and no "better"
326                         # interface has been detected ...
327                         x_io_backend="select()"
328                 fi
329         fi
330 fi
331
332 if test "$x_io_backend" = "none"; then
333         AC_MSG_ERROR([No useabe IO API activated/found!?])
334 fi
335
336 # use SSL?
337
338 AC_ARG_WITH(openssl,
339         [  --with-openssl          enable SSL support using OpenSSL],
340         [       if test "$withval" != "no"; then
341                         if test "$withval" != "yes"; then
342                                 CFLAGS="-I$withval/include $CFLAGS"
343                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
344                                 LDFLAGS="-L$withval/lib $LDFLAGS"
345                         fi
346                         AC_CHECK_LIB(crypto, BIO_s_mem)
347                         AC_CHECK_LIB(ssl, SSL_library_init)
348                         AC_CHECK_FUNCS(SSL_library_init, x_ssl_openssl=yes,
349                                 AC_MSG_ERROR([Can't enable openssl])
350                         )
351                 fi
352         ]
353 )
354
355 AC_ARG_WITH(gnutls,
356         [  --with-gnutls           enable SSL support using gnutls],
357         [       if test "$withval" != "no"; then
358                         if test "$withval" != "yes"; then
359                                 CFLAGS="-I$withval/include $CFLAGS"
360                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
361                                 LDFLAGS="-L$withval/lib $LDFLAGS"
362                         fi
363                         AC_CHECK_LIB(gnutls, gnutls_global_init)
364                         AC_CHECK_FUNCS(gnutls_global_init, x_ssl_gnutls=yes,
365                                 AC_MSG_ERROR([Can't enable gnutls])
366                         )
367                 fi
368         ]
369 )
370
371 x_ssl_lib="no"
372 if test "$x_ssl_gnutls" = "yes"; then
373         if test "$x_ssl_openssl" = "yes";then
374                 AC_MSG_ERROR([Cannot enable both gnutls and openssl])
375         fi
376         x_ssl_lib=gnutls
377 fi
378 if test "$x_ssl_openssl" = "yes"; then
379         x_ssl_lib=openssl
380 fi
381
382 # use TCP wrappers?
383
384 x_tcpwrap_on=no
385 AC_ARG_WITH(tcp-wrappers,
386         [  --with-tcp-wrappers     enable TCP wrappers support],
387         [       if test "$withval" != "no"; then
388                         if test "$withval" != "yes"; then
389                                 CFLAGS="-I$withval/include $CFLAGS"
390                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
391                                 LDFLAGS="-L$withval/lib $LDFLAGS"
392                         fi
393                         AC_MSG_CHECKING(for hosts_access)
394                         LIBS="-lwrap $LIBS"
395                         AC_TRY_LINK([
396 #include <tcpd.h>
397 int allow_severity = 0;
398 int deny_severity = 0;
399                                 ],[
400                                 tcpd_warn("link test");
401                                 ],[
402                                 AC_MSG_RESULT(yes)
403                                 AC_DEFINE(TCPWRAP, 1)
404                                 x_tcpwrap_on=yes
405                                 ],[
406                                 AC_MSG_RESULT(no)
407                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
408                         ])
409                 fi
410         ]
411 )
412
413 # do IDENT requests using libident?
414
415 x_identauth_on=no
416 AC_ARG_WITH(ident,
417         [  --with-ident            enable "IDENT" ("AUTH") protocol support],
418         [       if test "$withval" != "no"; then
419                         if test "$withval" != "yes"; then
420                                 CFLAGS="-I$withval/include $CFLAGS"
421                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
422                                 LDFLAGS="-L$withval/lib $LDFLAGS"
423                         fi
424                         AC_CHECK_LIB(ident, ident_id)
425                         AC_CHECK_FUNCS(ident_id, x_identauth_on=yes,
426                                 AC_MSG_ERROR([Can't enable IDENT support!])
427                         )
428                 fi
429         ]
430 )
431 if test "$x_identauth_on" = "yes"; then
432         AC_DEFINE(IDENTAUTH, 1)
433         AC_CHECK_HEADERS(ident.h,,AC_MSG_ERROR([required C header missing!]))
434 fi
435
436 # compile in PAM support?
437
438 x_pam_on=no
439 AC_ARG_WITH(pam,
440         [  --with-pam              enable user authentication using PAM],
441         [       if test "$withval" != "no"; then
442                         if test "$withval" != "yes"; then
443                                 CFLAGS="-I$withval/include $CFLAGS"
444                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
445                                 LDFLAGS="-L$withval/lib $LDFLAGS"
446                         fi
447                         AC_CHECK_LIB(pam, pam_authenticate)
448                         AC_CHECK_FUNCS(pam_authenticate, x_pam_on=yes,
449                                 AC_MSG_ERROR([Can't enable PAM support!])
450                         )
451                 fi
452         ]
453 )
454 if test "$x_pam_on" = "yes"; then
455         AC_DEFINE(PAM, 1)
456         AC_CHECK_HEADERS(security/pam_appl.h,pam_ok=yes)
457         if test "$pam_ok" != "yes"; then
458                 AC_CHECK_HEADERS(pam/pam_appl.h,pam_ok=yes,
459                         AC_MSG_ERROR([required C header missing!]))
460         fi
461 fi
462
463 # compile in IRC+ protocol support?
464
465 x_ircplus_on=yes
466 AC_ARG_ENABLE(ircplus,
467         [  --disable-ircplus       disable IRC+ protocol],
468         if test "$enableval" = "no"; then x_ircplus_on=no; fi
469 )
470 if test "$x_ircplus_on" = "yes"; then
471         AC_DEFINE(IRCPLUS, 1)
472 fi
473
474 # enable support for IPv6?
475 x_ipv6_on=no
476 AC_ARG_ENABLE(ipv6,
477         [  --enable-ipv6           enable IPv6 protocol support],
478         if test "$enableval" = "yes"; then x_ipv6_on=yes; fi
479 )
480 if test "$x_ipv6_on" = "yes"; then
481         # getaddrinfo() and getnameinfo() are optional when not compiling
482         # with IPv6 support, but are required for IPv6 to work!
483         AC_CHECK_FUNCS([ \
484                 getaddrinfo getnameinfo \
485                 ],,AC_MSG_ERROR([required function missing for IPv6 support!]))
486         AC_DEFINE(WANT_IPV6, 1)
487 fi
488
489 # compile in IRC "sniffer"?
490
491 x_sniffer_on=no; x_debug_on=no
492 AC_ARG_ENABLE(sniffer,
493         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
494         if test "$enableval" = "yes"; then
495                 AC_DEFINE(SNIFFER, 1)
496                 x_sniffer_on=yes; x_debug_on=yes
497         fi
498 )
499
500 # enable additional debugging code?
501
502 AC_ARG_ENABLE(debug,
503         [  --enable-debug          show additional debug output],
504         if test "$enableval" = "yes"; then x_debug_on=yes; fi
505 )
506 if test "$x_debug_on" = "yes"; then
507         AC_DEFINE(DEBUG, 1)
508         test "$GCC" = "yes" && CFLAGS="-pedantic $CFLAGS"
509         AC_CHECK_FUNCS(mtrace)
510 fi
511
512 # enable "strict RFC rules"?
513
514 x_strict_rfc_on=no
515 AC_ARG_ENABLE(strict-rfc,
516         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
517         if test "$enableval" = "yes"; then
518                 AC_DEFINE(STRICT_RFC, 1)
519                 x_strict_rfc_on=yes
520         fi
521 )
522
523 # -- Definitions --
524
525 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
526 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
527 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
528
529 # Add additional CFLAGS, eventually specified on the command line, but after
530 # running this configure script. Useful for "-Werror" for example.
531 test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
532
533 # -- Generate files --
534
535 AC_OUTPUT([ \
536         Makefile \
537         doc/Makefile \
538         doc/src/Makefile \
539         src/Makefile \
540         src/portab/Makefile \
541         src/ipaddr/Makefile \
542         src/tool/Makefile \
543         src/ngircd/Makefile \
544         src/testsuite/Makefile \
545         man/Makefile \
546         contrib/Makefile \
547         contrib/Debian/Makefile \
548         contrib/MacOSX/Makefile \
549         contrib/MacOSX/ngIRCd.xcodeproj/Makefile \
550         contrib/MacOSX/ngIRCd.pmdoc/Makefile \
551 ])
552
553 type dpkg >/dev/null 2>&1
554 if test $? -eq 0; then
555         # Generate debian/ link if the dpkg command exists
556         # (read: if we are running on a debian compatible system)
557         echo "creating Debian-specific links ..."
558         test -f debian/rules || ln -s contrib/Debian debian
559 fi
560
561 # -- Result --
562
563 echo
564 echo "ngIRCd $PACKAGE_VERSION has been configured with the following options:"
565 echo
566
567 # Someone please show me a better way :)  [borrowed by OpenSSH]
568 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
569 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
570 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
571 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
572 D=`eval echo ${docdir}` ; D=`eval echo ${D}`
573
574 echo "             Target: ${target}"
575 test "$target" != "$host" && echo "               Host: ${host}"
576 echo "           Compiler: ${CC}"
577 test -n "$CFLAGS"       && echo "     Compiler flags: ${CFLAGS}"
578 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
579 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
580 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
581 echo
582 echo "    'ngircd' binary: $S"
583 echo " Configuration file: $C"
584 echo "       Manual pages: $M"
585 echo "      Documentation: $D"
586 echo
587
588 echo $ECHO_N "     Syslog support: $ECHO_C"
589 test "$x_syslog_on" = "yes" \
590         && echo $ECHO_N "yes   $ECHO_C" \
591         || echo $ECHO_N "no    $ECHO_C"
592 echo $ECHO_N "  Enable debug code: $ECHO_C"
593 test "$x_debug_on" = "yes" \
594         && echo "yes" \
595         || echo "no"
596
597 echo $ECHO_N "   zlib compression: $ECHO_C"
598 test "$x_zlib_on" = "yes" \
599         && echo $ECHO_N "yes   $ECHO_C" \
600         || echo $ECHO_N "no    $ECHO_C"
601 echo $ECHO_N "        IRC sniffer: $ECHO_C"
602 test "$x_sniffer_on" = "yes" \
603         && echo "yes" \
604         || echo "no"
605
606 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
607 test "$x_tcpwrap_on" = "yes" \
608         && echo $ECHO_N "yes   $ECHO_C" \
609         || echo $ECHO_N "no    $ECHO_C"
610 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
611 test "$x_strict_rfc_on" = "yes" \
612         && echo "yes" \
613         || echo "no"
614
615 echo $ECHO_N "      IDENT support: $ECHO_C"
616 test "$x_identauth_on" = "yes" \
617         && echo $ECHO_N "yes   $ECHO_C" \
618         || echo $ECHO_N "no    $ECHO_C"
619 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
620 test "$x_ircplus_on" = "yes" \
621         && echo "yes" \
622         || echo "no"
623
624 echo $ECHO_N "      IPv6 protocol: $ECHO_C"
625 test "$x_ipv6_on" = "yes" \
626         && echo $ECHO_N "yes   $ECHO_C" \
627         || echo $ECHO_N "no    $ECHO_C"
628 echo $ECHO_N "        I/O backend: $ECHO_C"
629         echo "\"$x_io_backend\""
630
631 echo $ECHO_N "        PAM support: $ECHO_C"
632 test "$x_pam_on" = "yes" \
633         && echo $ECHO_N "yes   $ECHO_C" \
634         || echo $ECHO_N "no    $ECHO_C"
635 echo $ECHO_N "        SSL support: $ECHO_C"
636 echo "$x_ssl_lib"
637
638 echo
639
640 # -eof-