configure.in

   1 #
   2 # ngIRCd -- The Next Generation IRC Daemon
   3 # Copyright (c)2001-2012 Alexander Barton (alex@barton.de) and Contributors
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 # Please read the file COPYING, README and AUTHORS for more information.
  10 #
  11
  12 define(VERSION_ID,esyscmd(git describe|sed -e 's/rel-//g'|sed -e 's/-/~/'|tr -d \\n))
  13
  14 # -- Initialisation --
  15
  16 AC_PREREQ([2.67])
  17 AC_INIT([ngIRCd], VERSION_ID,
  18         [ngircd-ml@ngircd.barton.de], [ngircd], [http://ngircd.barton.de/])
  19
  20 AC_CONFIG_SRCDIR([src/ngircd/ngircd.c])
  21 AC_CONFIG_HEADER([src/config.h])
  22 AC_CANONICAL_HOST
  23
  24 AM_INIT_AUTOMAKE([1.11])
  25
  26 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  27
  28 # -- Templates for config.h --
  29
  30 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
  31 AH_TEMPLATE([HAVE_sockaddr_in_len], [Define if sockaddr_in.sin_len exists])
  32 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
  33 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
  34 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
  35 AH_TEMPLATE([PAM], [Define if PAM should be used])
  36 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
  37 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
  38 AH_TEMPLATE([SYSLOG], [Define if syslog should be used for logging])
  39 AH_TEMPLATE([TCPWRAP], [Define if TCP wrappers should be used])
  40 AH_TEMPLATE([WANT_IPV6], [Define if IPV6 protocol should be enabled])
  41 AH_TEMPLATE([ZLIB], [Define if zlib compression should be enabled])
  42
  43 AH_TEMPLATE([HOST_OS], [Target operating system name])
  44 AH_TEMPLATE([HOST_VENDOR], [Target system vendor])
  45 AH_TEMPLATE([HOST_CPU], [Target CPU name])
  46
  47 # -- C Compiler --
  48
  49 AC_PROG_CC
  50 AC_PROG_CC_STDC
  51
  52 # -- Helper programs --
  53
  54 AC_PROG_AWK
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57 AC_PROG_MAKE_SET
  58 AC_PROG_RANLIB
  59
  60 # -- Compiler Features --
  61
  62 AC_C_CONST
  63 AC_C_INLINE
  64 AM_C_PROTOTYPES
  65
  66 # -- Hard coded system and compiler dependencies/features/options ... --
  67
  68 AC_DEFUN([GCC_STACK_PROTECT_CC],[
  69   ssp_cc=yes
  70   # we use -fstack-protector-all for the test to enfoce the use of the guard variable
  71   AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
  72   ssp_old_cflags="$CFLAGS"
  73   CFLAGS="$CFLAGS -fstack-protector-all"
  74   AC_TRY_LINK(,,, ssp_cc=no)
  75   echo $ssp_cc
  76   CFLAGS="$ssp_old_cflags"
  77   if test "X$ssp_cc" = "Xyes"; then
  78       CFLAGS="$CFLAGS -fstack-protector"
  79       AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
  80   fi
  81 ])
  82
  83 if test "$GCC" = "yes"; then
  84         # We are using the GNU C compiler. Good!
  85         CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
  86
  87         GCC_STACK_PROTECT_CC
  88 fi
  89
  90 case "$host_os" in
  91         hpux*)
  92                 # This is HP/UX, we need to define _XOPEN_SOURCE_EXTENDED
  93                 # (tested with HP/UX 11.11)
  94                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
  95                 ;;
  96 esac
  97
  98 # Add additional CFLAGS, eventually specified on the command line:
  99 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
 100
 101 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
 102
 103 # -- Headers --
 104
 105 AC_HEADER_STDC
 106 AC_HEADER_SYS_WAIT
 107 AC_HEADER_TIME
 108
 109 # Required header files
 110 AC_CHECK_HEADERS([ \
 111         fcntl.h netdb.h netinet/in.h netinet/in_systm.h stdlib.h string.h \
 112         strings.h sys/socket.h sys/time.h unistd.h \
 113         ],,AC_MSG_ERROR([required C header missing!]))
 114
 115 # Optional header files
 116 AC_CHECK_HEADERS([ \
 117         arpa/inet.h inttypes.h malloc.h netinet/ip.h stdbool.h stddef.h \
 118         stdint.h varargs.h \
 119         ])
 120
 121 # -- Datatypes --
 122
 123 AC_MSG_CHECKING(whether socklen_t exists)
 124 AC_TRY_COMPILE([
 125 #include <sys/types.h>
 126 #include <sys/socket.h>
 127         ],[
 128         socklen_t a, b;
 129         a = 2; b = 4; a += b;
 130         ],[
 131         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
 132         ],[
 133         AC_MSG_RESULT(no)
 134 ])
 135
 136 AC_TYPE_PID_T
 137 AC_TYPE_SIGNAL
 138 AC_TYPE_SIZE_T
 139 AC_TYPE_SSIZE_T
 140 AC_TYPE_UID_T
 141 AC_TYPE_UINT16_T
 142 AC_TYPE_UINT32_T
 143 AC_TYPE_UINT8_T
 144
 145 AC_CHECK_MEMBER([struct sockaddr_in.sin_len], AC_DEFINE(HAVE_sockaddr_in_len),,
 146  [#include <arpa/inet.h>])
 147
 148 # -- Libraries --
 149
 150 # A/UX needs this.
 151 AC_CHECK_LIB(UTIL,memmove)
 152 # needed on solaris. GNU libc also has a libnsl, but we do not need it.
 153 AC_SEARCH_LIBS(gethostbyname,nsl)
 154 AC_CHECK_LIB(socket,bind)
 155
 156 # -- Functions --
 157
 158 AC_FUNC_FORK
 159 AC_FUNC_MALLOC
 160 AC_FUNC_REALLOC
 161 AC_FUNC_STRFTIME
 162
 163 # Required functions
 164 AC_CHECK_FUNCS([ \
 165         alarm dup2 endpwent gethostbyaddr gethostbyname gethostname \
 166         gettimeofday inet_ntoa memmove memset setsid socket strcasecmp \
 167         strchr strcspn strerror strncasecmp strrchr strspn strstr \
 168         ],,
 169         AC_MSG_ERROR([required function missing!]))
 170
 171 # Optional functions
 172 AC_CHECK_FUNCS([ \
 173         gai_strerror getaddrinfo getnameinfo inet_aton sigaction sigprocmask \
 174         snprintf vsnprintf strdup strlcpy strlcat strtok_r waitpid])
 175
 176 # -- Configuration options --
 177
 178 # use syslog?
 179
 180 x_syslog_on=no
 181 AC_ARG_WITH(syslog,
 182         AS_HELP_STRING([--without-syslog],
 183                        [disable syslog (autodetected by default)]),
 184         [       if test "$withval" != "no"; then
 185                         if test "$withval" != "yes"; then
 186                                 CFLAGS="-I$withval/include $CFLAGS"
 187                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 188                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 189                         fi
 190                         AC_CHECK_LIB(be, syslog)
 191                         AC_CHECK_FUNCS(syslog, x_syslog_on=yes,
 192                                 AC_MSG_ERROR([Can't enable syslog!])
 193                         )
 194                 fi
 195         ],
 196         [
 197                 AC_CHECK_LIB(be, syslog)
 198                 AC_CHECK_FUNCS(syslog, x_syslog_on=yes)
 199         ]
 200 )
 201 if test "$x_syslog_on" = "yes"; then
 202         AC_DEFINE(SYSLOG, 1)
 203         AC_CHECK_HEADERS(syslog.h,,AC_MSG_ERROR([required C header missing!]))
 204 fi
 205
 206 # use zlib compression?
 207
 208 x_zlib_on=no
 209 AC_ARG_WITH(zlib,
 210         AS_HELP_STRING([--without-zlib],
 211                        [disable zlib compression (autodetected by default)]),
 212         [       if test "$withval" != "no"; then
 213                         if test "$withval" != "yes"; then
 214                                 CFLAGS="-I$withval/include $CFLAGS"
 215                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 216                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 217                         fi
 218                         AC_CHECK_LIB(z, deflate)
 219                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
 220                                 AC_MSG_ERROR([Can't enable zlib!])
 221                         )
 222                 fi
 223         ],
 224         [       AC_CHECK_LIB(z, deflate)
 225                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
 226         ]
 227 )
 228 if test "$x_zlib_on" = "yes"; then
 229         AC_DEFINE(ZLIB, 1)
 230         AC_CHECK_HEADERS(zlib.h,,AC_MSG_ERROR([required C header missing!]))
 231 fi
 232
 233 # detect which IO API to use:
 234
 235 x_io_backend=none
 236
 237 AC_ARG_WITH(select,
 238         AS_HELP_STRING([--without-select],
 239                        [disable select IO support (autodetected by default)]),
 240         [       if test "$withval" != "no"; then
 241                         if test "$withval" != "yes"; then
 242                                 CFLAGS="-I$withval/include $CFLAGS"
 243                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 244                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 245                         fi
 246                         AC_CHECK_FUNCS(select, x_io_select=yes,
 247                                 AC_MSG_ERROR([Can't enable select IO support!])
 248                         )
 249                 fi
 250         ],
 251         [
 252                 AC_CHECK_FUNCS(select, x_io_select=yes)
 253         ]
 254 )
 255
 256 AC_ARG_WITH(poll,
 257         AS_HELP_STRING([--without-poll],
 258                        [disable poll support (autodetected by default)]),
 259         [       if test "$withval" != "no"; then
 260                         if test "$withval" != "yes"; then
 261                                 CFLAGS="-I$withval/include $CFLAGS"
 262                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 263                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 264                         fi
 265                         AC_CHECK_FUNCS(poll, [
 266                                 AC_CHECK_HEADERS(poll.h,
 267                                         x_io_backend=poll\(\),
 268                                         AC_MSG_ERROR(
 269                                              [Can't enable poll IO support!])
 270                                 )
 271                         ], [
 272                                 AC_MSG_ERROR([Can't enable poll IO support!])
 273                         ])
 274                 fi
 275         ],
 276         [
 277                 AC_CHECK_FUNCS(poll, [
 278                         AC_CHECK_HEADERS(poll.h, x_io_backend=poll\(\))
 279                 ])
 280         ]
 281 )
 282
 283 AC_ARG_WITH(devpoll,
 284         AS_HELP_STRING([--without-devpoll],
 285                        [disable /dev/poll IO support (autodetected by default)]),
 286         [       if test "$withval" != "no"; then
 287                         if test "$withval" != "yes"; then
 288                                 CFLAGS="-I$withval/include $CFLAGS"
 289                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 290                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 291                         fi
 292
 293                                 AC_CHECK_HEADERS(sys/devpoll.h,,AC_MSG_ERROR([required C header missing!]))
 294                 fi
 295         ],
 296         [
 297                 AC_CHECK_HEADERS(sys/devpoll.h, x_io_backend=/dev/poll)
 298         ]
 299 )
 300
 301 AC_ARG_WITH(epoll,
 302         AS_HELP_STRING([--without-epoll],
 303                        [disable epoll IO support (autodetected by default)]),
 304         [       if test "$withval" != "no"; then
 305                         if test "$withval" != "yes"; then
 306                                 CFLAGS="-I$withval/include $CFLAGS"
 307                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 308                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 309                         fi
 310                         AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes,
 311                                 AC_MSG_ERROR([Can't enable epoll IO support!])
 312                         )
 313                 fi
 314         ],
 315         [
 316                 AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes)
 317         ]
 318 )
 319
 320 AC_ARG_WITH(kqueue,
 321         AS_HELP_STRING([--without-kqueue],
 322                        [disable kqueue IO support (autodetected by default)]),
 323         [       if test "$withval" != "no"; then
 324                         if test "$withval" != "yes"; then
 325                                 CFLAGS="-I$withval/include $CFLAGS"
 326                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 327                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 328                         fi
 329                         AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\),
 330                                 AC_MSG_ERROR([Can't enable kqueue IO support!])
 331                         )
 332                 fi
 333         ],
 334         [
 335                 AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\))
 336         ]
 337 )
 338
 339 if test "$x_io_epoll" = "yes" -a "$x_io_select" = "yes"; then
 340         # when epoll() and select() are available, we'll use both!
 341         x_io_backend="epoll(), select()"
 342 else
 343         if test "$x_io_epoll" = "yes"; then
 344                 # we prefere epoll() if it is available
 345                 x_io_backend="epoll()"
 346         else
 347                 if test "$x_io_select" = "yes" -a "$x_io_backend" = "none"; then
 348                         # we'll use select, when available and no "better"
 349                         # interface has been detected ...
 350                         x_io_backend="select()"
 351                 fi
 352         fi
 353 fi
 354
 355 if test "$x_io_backend" = "none"; then
 356         AC_MSG_ERROR([No useable IO API activated/found!?])
 357 fi
 358
 359 # use SSL?
 360
 361 AC_ARG_WITH(openssl,
 362         AS_HELP_STRING([--with-openssl],
 363                        [enable SSL support using OpenSSL]),
 364         [       if test "$withval" != "no"; then
 365                         if test "$withval" != "yes"; then
 366                                 CFLAGS="-I$withval/include $CFLAGS"
 367                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 368                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 369                         fi
 370                         AC_CHECK_LIB(crypto, BIO_s_mem)
 371                         AC_CHECK_LIB(ssl, SSL_library_init)
 372                         AC_CHECK_FUNCS(SSL_library_init, x_ssl_openssl=yes,
 373                                 AC_MSG_ERROR([Can't enable openssl])
 374                         )
 375                 fi
 376         ]
 377 )
 378
 379 AC_ARG_WITH(gnutls,
 380         AS_HELP_STRING([--with-gnutls],
 381                        [enable SSL support using gnutls]),
 382         [       if test "$withval" != "no"; then
 383                         if test "$withval" != "yes"; then
 384                                 CFLAGS="-I$withval/include $CFLAGS"
 385                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 386                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 387                         fi
 388                         AC_CHECK_LIB(gnutls, gnutls_global_init)
 389                         AC_CHECK_FUNCS(gnutls_global_init, x_ssl_gnutls=yes,
 390                                 AC_MSG_ERROR([Can't enable gnutls])
 391                         )
 392                 fi
 393         ]
 394 )
 395
 396 x_ssl_lib="no"
 397 if test "$x_ssl_gnutls" = "yes"; then
 398         if test "$x_ssl_openssl" = "yes";then
 399                 AC_MSG_ERROR([Cannot enable both gnutls and openssl])
 400         fi
 401         x_ssl_lib=gnutls
 402 fi
 403 if test "$x_ssl_openssl" = "yes"; then
 404         x_ssl_lib=openssl
 405 fi
 406
 407 # use TCP wrappers?
 408
 409 x_tcpwrap_on=no
 410 AC_ARG_WITH(tcp-wrappers,
 411         AS_HELP_STRING([--with-tcp-wrappers],
 412                        [enable TCP wrappers support]),
 413         [       if test "$withval" != "no"; then
 414                         if test "$withval" != "yes"; then
 415                                 CFLAGS="-I$withval/include $CFLAGS"
 416                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 417                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 418                         fi
 419                         AC_MSG_CHECKING(for hosts_access)
 420                         LIBS="-lwrap $LIBS"
 421                         AC_TRY_LINK([
 422 #include <tcpd.h>
 423 int allow_severity = 0;
 424 int deny_severity = 0;
 425                                 ],[
 426                                 tcpd_warn("link test");
 427                                 ],[
 428                                 AC_MSG_RESULT(yes)
 429                                 AC_DEFINE(TCPWRAP, 1)
 430                                 x_tcpwrap_on=yes
 431                                 ],[
 432                                 AC_MSG_RESULT(no)
 433                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
 434                         ])
 435                 fi
 436         ]
 437 )
 438
 439 # do IDENT requests using libident?
 440
 441 x_identauth_on=no
 442 AC_ARG_WITH(ident,
 443         AS_HELP_STRING([--with-ident],
 444                        [enable "IDENT" ("AUTH") protocol support]),
 445         [       if test "$withval" != "no"; then
 446                         if test "$withval" != "yes"; then
 447                                 CFLAGS="-I$withval/include $CFLAGS"
 448                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 449                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 450                         fi
 451                         AC_CHECK_LIB(ident, ident_id)
 452                         AC_CHECK_FUNCS(ident_id, x_identauth_on=yes,
 453                                 AC_MSG_ERROR([Can't enable IDENT support!])
 454                         )
 455                 fi
 456         ]
 457 )
 458 if test "$x_identauth_on" = "yes"; then
 459         AC_DEFINE(IDENTAUTH, 1)
 460         AC_CHECK_HEADERS(ident.h,,AC_MSG_ERROR([required C header missing!]))
 461 fi
 462
 463 # compile in PAM support?
 464
 465 x_pam_on=no
 466 AC_ARG_WITH(pam,
 467         AS_HELP_STRING([--with-pam],
 468                        [enable user authentication using PAM]),
 469         [       if test "$withval" != "no"; then
 470                         if test "$withval" != "yes"; then
 471                                 CFLAGS="-I$withval/include $CFLAGS"
 472                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 473                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 474                         fi
 475                         AC_CHECK_LIB(pam, pam_authenticate)
 476                         AC_CHECK_FUNCS(pam_authenticate, x_pam_on=yes,
 477                                 AC_MSG_ERROR([Can't enable PAM support!])
 478                         )
 479                 fi
 480         ]
 481 )
 482 if test "$x_pam_on" = "yes"; then
 483         AC_DEFINE(PAM, 1)
 484         AC_CHECK_HEADERS(security/pam_appl.h,pam_ok=yes)
 485         if test "$pam_ok" != "yes"; then
 486                 AC_CHECK_HEADERS(pam/pam_appl.h,pam_ok=yes,
 487                         AC_MSG_ERROR([required C header missing!]))
 488         fi
 489 fi
 490
 491 # compile in IRC+ protocol support?
 492
 493 x_ircplus_on=yes
 494 AC_ARG_ENABLE(ircplus,
 495         AS_HELP_STRING([--disable-ircplus],
 496                        [disable IRC+ protocol]),
 497         if test "$enableval" = "no"; then x_ircplus_on=no; fi
 498 )
 499 if test "$x_ircplus_on" = "yes"; then
 500         AC_DEFINE(IRCPLUS, 1)
 501 fi
 502
 503 # enable support for IPv6?
 504 x_ipv6_on=no
 505 AC_ARG_ENABLE(ipv6,
 506         AS_HELP_STRING([--enable-ipv6],
 507                        [enable IPv6 protocol support]),
 508         if test "$enableval" = "yes"; then x_ipv6_on=yes; fi
 509 )
 510 if test "$x_ipv6_on" = "yes"; then
 511         # getaddrinfo() and getnameinfo() are optional when not compiling
 512         # with IPv6 support, but are required for IPv6 to work!
 513         AC_CHECK_FUNCS([ \
 514                 getaddrinfo getnameinfo \
 515                 ],,AC_MSG_ERROR([required function missing for IPv6 support!]))
 516         AC_DEFINE(WANT_IPV6, 1)
 517 fi
 518
 519 # compile in IRC "sniffer"?
 520
 521 x_sniffer_on=no; x_debug_on=no
 522 AC_ARG_ENABLE(sniffer,
 523         AS_HELP_STRING([--enable-sniffer],
 524                        [enable IRC traffic sniffer (enables debug mode)]),
 525         if test "$enableval" = "yes"; then
 526                 AC_DEFINE(SNIFFER, 1)
 527                 x_sniffer_on=yes; x_debug_on=yes
 528         fi
 529 )
 530
 531 # enable additional debugging code?
 532
 533 AC_ARG_ENABLE(debug,
 534         AS_HELP_STRING([--enable-debug],
 535                        [show additional debug output]),
 536         if test "$enableval" = "yes"; then x_debug_on=yes; fi
 537 )
 538 if test "$x_debug_on" = "yes"; then
 539         AC_DEFINE(DEBUG, 1)
 540         test "$GCC" = "yes" && CFLAGS="-pedantic $CFLAGS"
 541         AC_CHECK_FUNCS(mtrace)
 542 fi
 543
 544 # enable "strict RFC rules"?
 545
 546 x_strict_rfc_on=no
 547 AC_ARG_ENABLE(strict-rfc,
 548         AS_HELP_STRING([--enable-strict-rfc],
 549                        [strict RFC conformance -- may break clients!]),
 550         if test "$enableval" = "yes"; then
 551                 AC_DEFINE(STRICT_RFC, 1)
 552                 x_strict_rfc_on=yes
 553         fi
 554 )
 555
 556 # -- Definitions --
 557
 558 AC_DEFINE_UNQUOTED(HOST_CPU, "$host_cpu" )
 559 AC_DEFINE_UNQUOTED(HOST_VENDOR, "$host_vendor" )
 560 AC_DEFINE_UNQUOTED(HOST_OS, "$host_os" )
 561
 562 # Add additional CFLAGS, eventually specified on the command line, but after
 563 # running this configure script. Useful for "-Werror" for example.
 564 test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
 565
 566 # -- Generate files --
 567
 568 AC_CONFIG_FILES([ \
 569         Makefile \
 570         contrib/Anope/Makefile \
 571         contrib/Debian/Makefile \
 572         contrib/MacOSX/Makefile \
 573         contrib/MacOSX/ngIRCd.pmdoc/Makefile \
 574         contrib/MacOSX/ngIRCd.xcodeproj/Makefile \
 575         contrib/Makefile \
 576         doc/Makefile \
 577         doc/src/Makefile \
 578         man/Makefile \
 579         src/ipaddr/Makefile \
 580         src/Makefile \
 581         src/ngircd/Makefile \
 582         src/portab/Makefile \
 583         src/testsuite/Makefile \
 584         src/tool/Makefile \
 585 ])
 586
 587 AC_OUTPUT
 588
 589 type dpkg >/dev/null 2>&1
 590 if test $? -eq 0; then
 591         # Generate debian/ link if the dpkg command exists
 592         # (read: if we are running on a debian compatible system)
 593         echo "creating Debian-specific links ..."
 594         test -f debian/rules || ln -s contrib/Debian debian
 595 fi
 596
 597 # -- Result --
 598
 599 echo
 600 echo "ngIRCd $PACKAGE_VERSION has been configured with the following options:"
 601 echo
 602
 603 # Someone please show me a better way :)  [borrowed by OpenSSH]
 604 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
 605 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
 606 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
 607 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
 608 D=`eval echo ${docdir}` ; D=`eval echo ${D}`
 609
 610 echo "               Host: ${host}"
 611 echo "           Compiler: ${CC}"
 612 test -n "$CFLAGS"       && echo "     Compiler flags: ${CFLAGS}"
 613 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
 614 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
 615 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
 616 echo
 617 echo "    'ngircd' binary: $S"
 618 echo " Configuration file: $C"
 619 echo "       Manual pages: $M"
 620 echo "      Documentation: $D"
 621 echo
 622
 623 echo $ECHO_N "     Syslog support: $ECHO_C"
 624 test "$x_syslog_on" = "yes" \
 625         && echo $ECHO_N "yes   $ECHO_C" \
 626         || echo $ECHO_N "no    $ECHO_C"
 627 echo $ECHO_N "  Enable debug code: $ECHO_C"
 628 test "$x_debug_on" = "yes" \
 629         && echo "yes" \
 630         || echo "no"
 631
 632 echo $ECHO_N "   zlib compression: $ECHO_C"
 633 test "$x_zlib_on" = "yes" \
 634         && echo $ECHO_N "yes   $ECHO_C" \
 635         || echo $ECHO_N "no    $ECHO_C"
 636 echo $ECHO_N "        IRC sniffer: $ECHO_C"
 637 test "$x_sniffer_on" = "yes" \
 638         && echo "yes" \
 639         || echo "no"
 640
 641 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
 642 test "$x_tcpwrap_on" = "yes" \
 643         && echo $ECHO_N "yes   $ECHO_C" \
 644         || echo $ECHO_N "no    $ECHO_C"
 645 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
 646 test "$x_strict_rfc_on" = "yes" \
 647         && echo "yes" \
 648         || echo "no"
 649
 650 echo $ECHO_N "      IDENT support: $ECHO_C"
 651 test "$x_identauth_on" = "yes" \
 652         && echo $ECHO_N "yes   $ECHO_C" \
 653         || echo $ECHO_N "no    $ECHO_C"
 654 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
 655 test "$x_ircplus_on" = "yes" \
 656         && echo "yes" \
 657         || echo "no"
 658
 659 echo $ECHO_N "      IPv6 protocol: $ECHO_C"
 660 test "$x_ipv6_on" = "yes" \
 661         && echo $ECHO_N "yes   $ECHO_C" \
 662         || echo $ECHO_N "no    $ECHO_C"
 663 echo $ECHO_N "        I/O backend: $ECHO_C"
 664         echo "\"$x_io_backend\""
 665
 666 echo $ECHO_N "        PAM support: $ECHO_C"
 667 test "$x_pam_on" = "yes" \
 668         && echo $ECHO_N "yes   $ECHO_C" \
 669         || echo $ECHO_N "no    $ECHO_C"
 670 echo $ECHO_N "        SSL support: $ECHO_C"
 671 echo "$x_ssl_lib"
 672
 673 echo
 674
 675 # -eof-