- ngircd wird nun gegen die libngportab gelinkt, die evtl. benoetigte
[ngircd-alex.git] / configure.in
1 #
2 # ngIRCd -- The Next Generation IRC Daemon
3 # Copyright (c)2001,2002 by Alexander Barton (alex@barton.de)
4 #
5 # Dieses Programm ist freie Software. Sie koennen es unter den Bedingungen
6 # der GNU General Public License (GPL), wie von der Free Software Foundation
7 # herausgegeben, weitergeben und/oder modifizieren, entweder unter Version 2
8 # der Lizenz oder (wenn Sie es wuenschen) jeder spaeteren Version.
9 # Naehere Informationen entnehmen Sie bitter der Datei COPYING. Eine Liste
10 # der an ngIRCd beteiligten Autoren finden Sie in der Datei AUTHORS.
11 #
12 # $Id: configure.in,v 1.46 2002/05/19 01:14:42 alex Exp $
13 #
14
15 # -- Initialisierung --
16
17 AC_INIT
18 AC_CANONICAL_TARGET
19 AC_CONFIG_SRCDIR(src/config.h.in)
20 AM_INIT_AUTOMAKE(ngircd,CurrentCVS)
21 AM_CONFIG_HEADER(src/config.h)
22
23 # -- Templates fuer config.h --
24
25 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
26 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
27 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
28 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
29 AH_TEMPLATE([USE_SYSLOG], [Define if syslog should be used for logging])
30 AH_TEMPLATE([REGEX], [Define if POSIX regular expression functions are available])
31
32 AH_TEMPLATE([TARGET_OS], [Target operating system name])
33 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
34 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
35
36 # -- C Compiler --
37
38 AC_PROG_CC
39 AC_LANG_C
40
41 # -- Hilfsprogramme --
42
43 AC_PROG_AWK
44 AC_PROG_INSTALL
45 AC_PROG_LN_S
46 AC_PROG_MAKE_SET
47 AC_PROG_RANLIB
48
49 # -- Header --
50
51 AC_HEADER_STDC
52
53 AC_HEADER_TIME
54
55 AC_CHECK_HEADERS([ \
56         ctype.h errno.h fcntl.h netdb.h netinet/in.h stdlib.h string.h \
57         sys/socket.h sys/time.h sys/wait.h unistd.h \
58         ],,AC_MSG_ERROR([required C header missing!]))
59
60 AC_CHECK_HEADERS(arpa/inet.h)
61
62 AC_CHECK_HEADERS(regex.h,regex_h_ok=1)
63
64 # -- Datentypen --
65
66 AC_MSG_CHECKING(whether socklen_t exists)
67 AC_TRY_COMPILE([
68         #include <sys/socket.h>
69         #include <sys/types.h>
70         ],[
71         socklen_t a, b;
72         a = 2; b = 4; a += b;
73         ],[
74         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
75         ],[
76         AC_MSG_RESULT(no)
77 ])
78
79 # -- Libraries --
80
81 AC_CHECK_LIB(UTIL,memmove)
82 AC_CHECK_LIB(socket,bind)
83 AC_CHECK_LIB(nsl,gethostent)
84
85 # -- Funktionen --
86
87 AC_FUNC_MALLOC
88
89 AC_CHECK_FUNCS([ \
90         bind gethostbyaddr gethostbyname gethostname inet_ntoa memmove \
91         memset select setsockopt socket strcasecmp strchr strerror strftime \
92         strstr waitpid \
93         ],,AC_MSG_ERROR([required function missing!]))
94
95 AC_CHECK_FUNCS(inet_aton)
96
97 AC_CHECK_FUNCS(regcomp,regcomp_ok=1)
98
99 AC_CHECK_FUNCS(sigaction)
100
101 AC_CHECK_FUNCS(vsnprintf)
102
103 # -- Konfigurationsoptionen --
104
105 AC_ARG_ENABLE(syslog,
106         [  --disable-syslog        disable syslog (autodetected by default)],
107         [       if test "$enableval" = "yes"; then
108                         AC_CHECK_HEADER(syslog.h,
109                                 [       AC_DEFINE(USE_SYSLOG, 1)
110                                         AC_CHECK_LIB(be,syslog)
111                                 ],
112                                 AC_MSG_ERROR([Can't enable syslog: syslog.h not found!])
113                         )
114                 else
115                         AC_MSG_RESULT([disabling syslog])
116                 fi
117         ],
118         [       AC_CHECK_HEADER(syslog.h,
119                         [       AC_DEFINE(USE_SYSLOG, 1)
120                                 AC_CHECK_LIB(be,syslog)
121                         ]
122                 )
123         ]
124 )
125
126 AC_ARG_ENABLE(strict-rfc,
127         [  --enable-strict-rfc     strict RFC conformance, may break clients],
128         if test "$enableval" = "yes"; then
129                 AC_DEFINE(STRICT_RFC, 1)
130                 AC_MSG_RESULT([enabling strict RFC conformance])
131         fi
132 )
133
134 AC_ARG_ENABLE(sniffer,
135         [  --enable-sniffer        enable network traffic monitor (enables debug mode!)],
136         if test "$enableval" = "yes"; then
137                 AC_DEFINE(SNIFFER, 1)
138                 AC_MSG_RESULT([enabling network traffic monitor])
139                 x_debug_on=yes
140         fi
141 )
142
143 AC_ARG_ENABLE(debug,
144         [  --enable-debug          show additional debug output],
145         if test "$enableval" = "yes"; then x_debug_on=yes; fi
146 )
147 if test "$x_debug_on" = "yes"; then
148         AC_DEFINE(DEBUG, 1)
149         AC_MSG_RESULT([enabling additional debug output])
150 fi
151
152 # -- Definitionen --
153
154 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
155 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
156 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
157
158 if test `uname` = "A/UX"; then
159         # unter A/UX sollte _POSIX_SOURCE definiert sein.
160         AC_MSG_RESULT([detected A/UX, defining _POSIX_SOURCE])
161         CFLAGS="$CFLAGS -D_POSIX_SOURCE"
162 fi
163
164 if test "$regcomp_ok" -eq 1 -a "$regex_h_ok" -eq 1; then
165         # POSIX Regular Expression Library ist verfuegbar
166         AC_MSG_RESULT([detected POSIX regular expression library])
167         AC_DEFINE(REGEX)
168 fi
169
170 # -- Variablen --
171
172 if test "$GCC" = "yes"; then
173         CFLAGS="-Wall $CFLAGS"
174 fi
175
176 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
177
178 # -- Ausgabe --
179
180 AC_OUTPUT([ \
181         Makefile \
182         doc/Makefile \
183         doc/en/Makefile \
184         MacOSX/Makefile \
185         MacOSX/ngircd.pbproj/Makefile \
186         src/Makefile \
187         src/portab/Makefile \
188         src/ngircd/Makefile \
189         man/Makefile \
190 ])
191
192 # -eof-