- Test-Suite an korrigiertest RPL_UMODEIS angepasst.
[ngircd-alex.git] / configure.in
1 #
2 # ngIRCd -- The Next Generation IRC Daemon
3 # Copyright (c)2001,2002 by Alexander Barton (alex@barton.de)
4 #
5 # Dieses Programm ist freie Software. Sie koennen es unter den Bedingungen
6 # der GNU General Public License (GPL), wie von der Free Software Foundation
7 # herausgegeben, weitergeben und/oder modifizieren, entweder unter Version 2
8 # der Lizenz oder (wenn Sie es wuenschen) jeder spaeteren Version.
9 # Naehere Informationen entnehmen Sie bitter der Datei COPYING. Eine Liste
10 # der an ngIRCd beteiligten Autoren finden Sie in der Datei AUTHORS.
11 #
12 # $Id: configure.in,v 1.67 2002/11/15 22:08:19 alex Exp $
13 #
14
15 # -- Initialisierung --
16
17 AC_INIT
18 AC_PREREQ(2.50)
19 AC_CANONICAL_TARGET
20 AC_CONFIG_SRCDIR(src/config.h.in)
21 AM_INIT_AUTOMAKE(ngircd,CVSHEAD)
22 AM_CONFIG_HEADER(src/config.h)
23
24 # -- Templates fuer config.h --
25
26 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
27 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
28 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
29 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
30 AH_TEMPLATE([USE_SYSLOG], [Define if syslog should be used for logging])
31 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
32
33 AH_TEMPLATE([TARGET_OS], [Target operating system name])
34 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
35 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
36
37 # -- C Compiler --
38
39 AC_PROG_CC
40
41 # -- Hilfsprogramme --
42
43 AC_PROG_AWK
44 AC_PROG_INSTALL
45 AC_PROG_LN_S
46 AC_PROG_MAKE_SET
47 AC_PROG_RANLIB
48
49 # -- Compiler Features --
50
51 AC_LANG_C
52
53 AM_C_PROTOTYPES
54 AC_C_CONST
55
56 # -- Defines --
57
58 if test `uname` = "A/UX"; then
59         # unter A/UX sollte _POSIX_SOURCE definiert sein.
60         AC_MSG_RESULT([detected A/UX, defining _POSIX_SOURCE])
61         CFLAGS="$CFLAGS -D_POSIX_SOURCE"
62 fi
63
64 if test `uname` = "HP-UX"; then
65         # unter HP-UX 11.11 muss _XOPEN_SOURCE_EXTENDED definiert sein.
66         AC_MSG_RESULT([detected HP-UX, defining _XOPEN_SOURCE_EXTENDED])
67         CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
68 fi
69
70 # -- Header --
71
72 AC_HEADER_STDC
73
74 AC_HEADER_TIME
75
76 AC_HEADER_SYS_WAIT
77
78 AC_CHECK_HEADERS([ \
79         ctype.h errno.h fcntl.h netdb.h netinet/in.h stdlib.h string.h \
80         strings.h sys/socket.h sys/time.h unistd.h \
81         ],,AC_MSG_ERROR([required C header missing!]))
82
83 AC_CHECK_HEADERS(arpa/inet.h malloc.h stdint.h sys/select.h varargs.h)
84
85 # -- Datentypen --
86
87 AC_MSG_CHECKING(whether socklen_t exists)
88 AC_TRY_COMPILE([
89         #include <sys/socket.h>
90         #include <sys/types.h>
91         ],[
92         socklen_t a, b;
93         a = 2; b = 4; a += b;
94         ],[
95         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
96         ],[
97         AC_MSG_RESULT(no)
98 ])
99
100 AC_TYPE_SIGNAL
101
102 AC_TYPE_SIZE_T
103
104 # -- Libraries --
105
106 AC_CHECK_LIB(UTIL,memmove)
107 AC_CHECK_LIB(socket,bind)
108 AC_CHECK_LIB(nsl,gethostent)
109
110 # -- Funktionen --
111
112 AC_FUNC_MALLOC
113
114 AC_FUNC_FORK
115
116 AC_FUNC_STRFTIME
117
118 AC_CHECK_FUNCS([ \
119         bind gethostbyaddr gethostbyname gethostname inet_ntoa memmove \
120         memset select setsockopt socket strcasecmp strchr strerror \
121         strstr waitpid \
122         ],,AC_MSG_ERROR([required function missing!]))
123
124 AC_CHECK_FUNCS(inet_aton sigaction snprintf vsnprintf)
125
126 # -- Konfigurationsoptionen --
127
128 x_syslog_on=no
129 AC_ARG_ENABLE(syslog,
130         [  --disable-syslog        disable syslog (autodetected by default)],
131         [       if test "$enableval" = "yes"; then
132                         AC_CHECK_HEADER(syslog.h, x_syslog_on=yes,
133                                 AC_MSG_ERROR([Can't enable syslog: syslog.h not found!])
134                         )
135                 fi
136         ],
137         [       AC_CHECK_HEADER(syslog.h, x_syslog_on=yes) ]
138 )
139 if test "$x_syslog_on" = "yes"; then
140         AC_DEFINE(USE_SYSLOG, 1)
141         AC_CHECK_LIB(be,syslog)
142 fi
143
144 x_ircplus_on=yes
145 AC_ARG_ENABLE(ircplus,
146         [  --disable-ircplus       disable IRC+ protocol],
147         if test "$enableval" = "no"; then x_ircplus_on=no; fi
148 )
149 if test "$x_ircplus_on" = "yes"; then
150         AC_DEFINE(IRCPLUS, 1)
151 fi
152
153 AC_ARG_ENABLE(sniffer,
154         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
155         if test "$enableval" = "yes"; then
156                 AC_DEFINE(SNIFFER, 1)
157                 x_sniffer_on=yes; x_debug_on=yes
158         fi
159 )
160
161 AC_ARG_ENABLE(debug,
162         [  --enable-debug          show additional debug output],
163         if test "$enableval" = "yes"; then x_debug_on=yes; fi
164 )
165 if test "$x_debug_on" = "yes"; then
166         AC_DEFINE(DEBUG, 1)
167 fi
168
169 AC_ARG_ENABLE(strict-rfc,
170         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
171         if test "$enableval" = "yes"; then
172                 AC_DEFINE(STRICT_RFC, 1)
173                 x_strict_rfc_on=yes
174         fi
175 )
176
177
178 # -- Definitionen --
179
180 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
181 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
182 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
183
184 # -- Variablen --
185
186 if test "$GCC" = "yes"; then
187         CFLAGS="-Wall $CFLAGS"
188 fi
189
190 the_CFLAGS="$CFLAGS"
191
192 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
193
194 # -- Ausgabe der Dateien --
195
196 AC_OUTPUT([ \
197         Makefile \
198         doc/Makefile \
199         doc/en/Makefile \
200         MacOSX/Makefile \
201         MacOSX/ngircd.pbproj/Makefile \
202         src/Makefile \
203         src/portab/Makefile \
204         src/ngircd/Makefile \
205         src/testsuite/Makefile \
206         man/Makefile \
207         contrib/Makefile \
208 ])
209
210 # -- Ergebnis --
211
212 echo
213
214 # Someone please show me a better way :)  [borrowed by OpenSSH]
215 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
216 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
217 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
218 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
219
220 echo "                host: ${host}"
221 echo "            compiler: ${CC}"
222 echo "      compiler flags: ${the_CFLAGS}"
223 echo "  preprocessor flags: ${CPPFLAGS}"
224 echo "        linker flags: ${LDFLAGS}"
225 echo "           libraries: ${LIBS}"
226 echo
227 echo "     'ngircd' binary: $S"
228 echo "  configuration file: $C"
229 echo "        manual pages: $M"
230 echo
231
232 echo $ECHO_N "      active options: $ECHO_C"
233 test "$x_syslog_on" = "yes"     && echo $ECHO_N "Syslog $ECHO_C"
234 test "$x_debug_on" = "yes"      && echo $ECHO_N "Debug $ECHO_C"
235 test "$x_sniffer_on" = "yes"    && echo $ECHO_N "Sniffer $ECHO_C"
236 test "$x_strict_rfc_on" = "yes" && echo $ECHO_N "Strict-RFC $ECHO_C"
237 test "$x_ircplus_on" = "yes"    && echo $ECHO_N "IRC+ $ECHO_C"
238 echo; echo
239
240 # -eof-