configure.in

   1 #
   2 # ngIRCd -- The Next Generation IRC Daemon
   3 # Copyright (c)2001-2005 Alexander Barton <alex@barton.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 # Please read the file COPYING, README and AUTHORS for more information.
  10 #
  11 # $Id: configure.in,v 1.117 2005/12/06 22:37:50 alex Exp $
  12 #
  13
  14 # -- Initialisation --
  15
  16 AC_PREREQ(2.50)
  17 AC_INIT(ngircd, CVSHEAD)
  18 AC_CONFIG_SRCDIR(src/ngircd/ngircd.c)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE(1.6)
  21 AM_CONFIG_HEADER(src/config.h)
  22
  23 # -- Templates for config.h --
  24
  25 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
  26 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
  27 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
  28 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
  29 AH_TEMPLATE([SYSLOG], [Define if syslog should be used for logging])
  30 AH_TEMPLATE([ZLIB], [Define if zlib compression should be enabled])
  31 AH_TEMPLATE([TCPWRAP], [Define if TCP wrappers should be used])
  32 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
  33 AH_TEMPLATE([ZEROCONF], [Define if support for Zeroconf should be included])
  34 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
  35
  36 AH_TEMPLATE([TARGET_OS], [Target operating system name])
  37 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
  38 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
  39
  40 # -- C Compiler --
  41
  42 AC_PROG_CC
  43
  44 # -- Helper programs --
  45
  46 AC_PROG_AWK
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AC_PROG_RANLIB
  51
  52 # -- Compiler Features --
  53
  54 AM_C_PROTOTYPES
  55 AC_C_CONST
  56
  57 # -- Hard coded system and compiler dependencies/features/options ... --
  58
  59 if test "$GCC" = "yes"; then
  60         # We are using the GNU C compiler. Good!
  61         CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
  62 fi
  63
  64
  65 AC_DEFUN([GCC_STACK_PROTECT_CC],[
  66   ssp_cc=yes
  67   if test "X$CC" != "X"; then
  68     AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
  69     ssp_old_cflags="$CFLAGS"
  70     CFLAGS="$CFLAGS -fstack-protector"
  71     AC_TRY_COMPILE(,,, ssp_cc=no)
  72     echo $ssp_cc
  73     if test "X$ssp_cc" = "Xno"; then
  74       CFLAGS="$ssp_old_cflags"
  75     else
  76       AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
  77     fi
  78   fi
  79 ])
  80
  81 GCC_STACK_PROTECT_CC
  82
  83 case "$target_os" in
  84         hpux*)
  85                 # This is HP/UX, we need to define _XOPEN_SOURCE_EXTENDED
  86                 # (tested with HP/UX 11.11)
  87                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
  88                 ;;
  89 esac
  90
  91 # Add additional CFLAGS, eventually specified on the command line:
  92 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
  93
  94 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
  95
  96 # -- Headers --
  97
  98 AC_HEADER_STDC
  99 AC_HEADER_TIME
 100 AC_HEADER_SYS_WAIT
 101
 102 AC_CHECK_HEADERS([ \
 103         ctype.h errno.h fcntl.h netdb.h netinet/in.h stdlib.h string.h \
 104         strings.h sys/socket.h sys/time.h unistd.h \
 105         ],,AC_MSG_ERROR([required C header missing!]))
 106
 107 AC_CHECK_HEADERS([arpa/inet.h ctype.h malloc.h stdbool.h stddef.h varargs.h])
 108
 109 # -- Datatypes --
 110
 111 AC_MSG_CHECKING(whether socklen_t exists)
 112 AC_TRY_COMPILE([
 113 #include <sys/types.h>
 114 #include <sys/socket.h>
 115         ],[
 116         socklen_t a, b;
 117         a = 2; b = 4; a += b;
 118         ],[
 119         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
 120         ],[
 121         AC_MSG_RESULT(no)
 122 ])
 123
 124 AC_TYPE_SIGNAL
 125 AC_TYPE_SIZE_T
 126
 127
 128 # -- Libraries --
 129
 130 AC_CHECK_LIB(UTIL,memmove)
 131 AC_CHECK_LIB(socket,bind)
 132 AC_CHECK_LIB(nsl,gethostent)
 133
 134 # -- Functions --
 135
 136 AC_FUNC_FORK
 137 AC_FUNC_STRFTIME
 138
 139 AC_CHECK_FUNCS([ \
 140         bind gethostbyaddr gethostbyname gethostname inet_ntoa malloc memmove \
 141         memset realloc setsid setsockopt socket strcasecmp strchr strerror \
 142         strstr waitpid],,AC_MSG_ERROR([required function missing!]))
 143
 144 AC_CHECK_FUNCS(inet_aton isdigit sigaction snprintf vsnprintf strdup strlcpy strlcat)
 145
 146 AC_CHECK_FUNCS(select,[AC_CHECK_HEADERS(sys/select.h)],
 147         AC_MSG_ERROR([required function select() is missing!])
 148 )
 149
 150 # -- Configuration options --
 151
 152 x_syslog_on=no
 153 AC_ARG_WITH(syslog,
 154         [  --without-syslog        disable syslog (autodetected by default)],
 155         [       if test "$withval" != "no"; then
 156                         if test "$withval" != "yes"; then
 157                                 CFLAGS="-I$withval/include $CFLAGS"
 158                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 159                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 160                         fi
 161                         AC_CHECK_LIB(be, syslog)
 162                         AC_CHECK_FUNCS(syslog, x_syslog_on=yes,
 163                                 AC_MSG_ERROR([Can't enable syslog!])
 164                         )
 165                 fi
 166         ],
 167         [
 168                 AC_CHECK_LIB(be, syslog)
 169                 AC_CHECK_FUNCS(syslog, x_syslog_on=yes)
 170         ]
 171 )
 172 if test "$x_syslog_on" = "yes"; then
 173         AC_DEFINE(SYSLOG, 1)
 174         AC_CHECK_HEADERS(syslog.h,,AC_MSG_ERROR([required C header missing!]))
 175 fi
 176
 177 x_zlib_on=no
 178 AC_ARG_WITH(zlib,
 179         [  --without-zlib          disable zlib compression (autodetected by default)],
 180         [       if test "$withval" != "no"; then
 181                         if test "$withval" != "yes"; then
 182                                 CFLAGS="-I$withval/include $CFLAGS"
 183                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 184                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 185                         fi
 186                         AC_CHECK_LIB(z, deflate)
 187                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
 188                                 AC_MSG_ERROR([Can't enable zlib!])
 189                         )
 190                 fi
 191         ],
 192         [       AC_CHECK_LIB(z, deflate)
 193                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
 194         ]
 195 )
 196 if test "$x_zlib_on" = "yes"; then
 197         AC_DEFINE(ZLIB, 1)
 198         AC_CHECK_HEADERS(zlib.h,,AC_MSG_ERROR([required C header missing!]))
 199 fi
 200
 201
 202 x_io_backend=select
 203 AC_ARG_WITH(epoll,
 204         [  --without-epoll         disable epoll support (autodetected by default)],
 205         [       if test "$withval" != "no"; then
 206                         if test "$withval" != "yes"; then
 207                                 CFLAGS="-I$withval/include $CFLAGS"
 208                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 209                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 210                         fi
 211                         AC_CHECK_FUNCS(epoll_create, x_io_backend=epoll,
 212                                 AC_MSG_ERROR([Can't enable epoll support!])
 213                         )
 214                 fi
 215         ],
 216         [
 217                 AC_CHECK_FUNCS(epoll_create, x_io_backend=epoll)
 218         ]
 219 )
 220
 221 AC_ARG_WITH(kqueue,
 222         [  --without-kqueue        disable kqueue support (autodetected by default)],
 223         [       if test "$withval" != "no"; then
 224                         if test "$withval" != "yes"; then
 225                                 CFLAGS="-I$withval/include $CFLAGS"
 226                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 227                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 228                         fi
 229                         AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue,
 230                                 AC_MSG_ERROR([Can't enable kqueue support!])
 231                         )
 232                 fi
 233         ],
 234         [
 235                 AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue)
 236         ]
 237 )
 238
 239
 240 x_tcpwrap_on=no
 241 AC_ARG_WITH(tcp-wrappers,
 242         [  --with-tcp-wrappers     enable TCP wrappers support],
 243         [       if test "$withval" != "no"; then
 244                         if test "$withval" != "yes"; then
 245                                 CFLAGS="-I$withval/include $CFLAGS"
 246                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 247                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 248                         fi
 249                         AC_MSG_CHECKING(for hosts_access)
 250                         LIBS="-lwrap $LIBS"
 251                         AC_TRY_LINK([
 252 #include <tcpd.h>
 253 int allow_severity = 0;
 254 int deny_severity = 0;
 255                                 ],[
 256                                 tcpd_warn("link test");
 257                                 ],[
 258                                 AC_MSG_RESULT(yes)
 259                                 AC_DEFINE(TCPWRAP, 1)
 260                                 x_tcpwrap_on=yes
 261                                 ],[
 262                                 AC_MSG_RESULT(no)
 263                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
 264                         ])
 265                 fi
 266         ]
 267 )
 268
 269 x_zeroconf_on=no
 270 AC_ARG_WITH(zeroconf,
 271         [  --with-zeroconf         enable support for "Zeroconf"],
 272         [       if test "$withval" != "no"; then
 273                         if test "$withval" != "yes"; then
 274                                 CFLAGS="-I$withval/include $CFLAGS"
 275                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 276                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 277                         fi
 278                         AC_CHECK_FUNCS(DNSServiceRegistrationCreate, x_zeroconf_on=osx,
 279                         [
 280                                 AC_CHECK_LIB(pthread, pthread_mutexattr_init)
 281                                 AC_CHECK_LIB(howl, sw_discovery_init)
 282                                 AC_CHECK_FUNCS(sw_discovery_init, \
 283                                  x_zeroconf_on=howl, \
 284                                  AC_MSG_ERROR([Can't enable Zeroconf!]))
 285                         ])
 286                 fi
 287         ]
 288 )
 289 if test "$x_zeroconf_on" = "osx"; then
 290         AC_CHECK_HEADERS([DNSServiceDiscovery/DNSServiceDiscovery.h \
 291          mach/port.h],,AC_MSG_ERROR([required C header missing!]))
 292         AC_DEFINE(ZEROCONF, 1)
 293 fi
 294 if test "$x_zeroconf_on" = "howl"; then
 295         for dir in /usr/local/include /usr/local/include/howl* \
 296          /usr/include /usr/include/howl*; do
 297                 test -d "$dir" || continue
 298                 AC_MSG_CHECKING([for Howl headers in $dir])
 299                 if test -f "$dir/rendezvous/rendezvous.h"; then
 300                         if test "$dir" != "/usr/local/include" -a \
 301                          "$dir" != "/usr/include"; then
 302                                 CFLAGS="-I$dir $CFLAGS"
 303                                 CPPFLAGS="-I$dir $CPPFLAGS"
 304                         fi
 305                         AC_MSG_RESULT(yes)
 306                         break
 307                 else
 308                         AC_MSG_RESULT(no)
 309                 fi
 310         done
 311         AC_CHECK_HEADERS([rendezvous/rendezvous.h],, \
 312          AC_MSG_ERROR([required C header missing!]))
 313         AC_DEFINE(ZEROCONF, 1)
 314 fi
 315
 316 x_identauth_on=no
 317 AC_ARG_WITH(ident,
 318         [  --with-ident            enable "IDENT" ("AUTH") protocol support],
 319         [       if test "$withval" != "no"; then
 320                         if test "$withval" != "yes"; then
 321                                 CFLAGS="-I$withval/include $CFLAGS"
 322                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
 323                                 LDFLAGS="-L$withval/lib $LDFLAGS"
 324                         fi
 325                         AC_CHECK_LIB(ident, ident_id)
 326                         AC_CHECK_FUNCS(ident_id, x_identauth_on=yes,
 327                                 AC_MSG_ERROR([Can't enable IDENT support!])
 328                         )
 329                 fi
 330         ]
 331 )
 332 if test "$x_identauth_on" = "yes"; then
 333         AC_DEFINE(IDENTAUTH, 1)
 334         AC_CHECK_HEADERS(ident.h,,AC_MSG_ERROR([required C header missing!]))
 335 fi
 336
 337 x_ircplus_on=yes
 338 AC_ARG_ENABLE(ircplus,
 339         [  --disable-ircplus       disable IRC+ protocol],
 340         if test "$enableval" = "no"; then x_ircplus_on=no; fi
 341 )
 342 if test "$x_ircplus_on" = "yes"; then
 343         AC_DEFINE(IRCPLUS, 1)
 344 fi
 345
 346 x_sniffer_on=no; x_debug_on=no
 347 AC_ARG_ENABLE(sniffer,
 348         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
 349         if test "$enableval" = "yes"; then
 350                 AC_DEFINE(SNIFFER, 1)
 351                 x_sniffer_on=yes; x_debug_on=yes
 352         fi
 353 )
 354
 355 AC_ARG_ENABLE(debug,
 356         [  --enable-debug          show additional debug output],
 357         if test "$enableval" = "yes"; then x_debug_on=yes; fi
 358 )
 359 if test "$x_debug_on" = "yes"; then
 360         AC_DEFINE(DEBUG, 1)
 361         test "$GCC" = "yes" && CFLAGS="-pedantic $CFLAGS"
 362 fi
 363
 364 x_strict_rfc_on=no
 365 AC_ARG_ENABLE(strict-rfc,
 366         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
 367         if test "$enableval" = "yes"; then
 368                 AC_DEFINE(STRICT_RFC, 1)
 369                 x_strict_rfc_on=yes
 370         fi
 371 )
 372
 373 # -- Definitions --
 374
 375 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
 376 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
 377 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
 378
 379 # Add additional CFLAGS, eventually specified on the command line, but after
 380 # running this configure script. Useful for "-Werror" for example.
 381 test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
 382
 383 # -- Generate files --
 384
 385 AC_OUTPUT([ \
 386         Makefile \
 387         doc/Makefile \
 388         doc/src/Makefile \
 389         src/Makefile \
 390         src/portab/Makefile \
 391         src/tool/Makefile \
 392         src/ngircd/Makefile \
 393         src/testsuite/Makefile \
 394         man/Makefile \
 395         contrib/Makefile \
 396         contrib/Debian/Makefile \
 397         contrib/MacOSX/Makefile \
 398 ])
 399
 400 type dpkg >/dev/null 2>&1
 401 if test $? -eq 0; then
 402         # Generate debian/ link if the dpkg command exists
 403         # (read: if we are running on a debian compatible system)
 404         echo "creating Debian-specific links ..."
 405         test -f debian/rules || ln -s contrib/Debian debian
 406 fi
 407
 408 # -- Result --
 409
 410 echo
 411 echo "ngIRCd $PACKAGE_VERSION has been configured with the following options:"
 412 echo
 413
 414 # Someone please show me a better way :)  [borrowed by OpenSSH]
 415 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
 416 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
 417 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
 418 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
 419 D=`eval echo ${datadir}/doc/${PACKAGE}` ; D=`eval echo ${D}`
 420
 421 echo "             Target: ${target}"
 422 test "$target" != "$host" && echo "               Host: ${host}"
 423 echo "           Compiler: ${CC}"
 424 test -n "$CFLAGS"       && echo "     Compiler flags: ${CFLAGS}"
 425 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
 426 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
 427 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
 428 echo
 429 echo "    'ngircd' binary: $S"
 430 echo " Configuration file: $C"
 431 echo "       Manual pages: $M"
 432 echo "      Documentation: $D"
 433 echo
 434
 435 echo $ECHO_N "     Syslog support: $ECHO_C"
 436 test "$x_syslog_on" = "yes" \
 437         && echo $ECHO_N "yes   $ECHO_C" \
 438         || echo $ECHO_N "no    $ECHO_C"
 439 echo $ECHO_N "  Enable debug code: $ECHO_C"
 440 test "$x_debug_on" = "yes" \
 441         && echo "yes" \
 442         || echo "no"
 443
 444 echo $ECHO_N "   zlib compression: $ECHO_C"
 445 test "$x_zlib_on" = "yes" \
 446         && echo $ECHO_N "yes   $ECHO_C" \
 447         || echo $ECHO_N "no    $ECHO_C"
 448 echo $ECHO_N "        IRC sniffer: $ECHO_C"
 449 test "$x_sniffer_on" = "yes" \
 450         && echo "yes" \
 451         || echo "no"
 452
 453 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
 454 test "$x_tcpwrap_on" = "yes" \
 455         && echo $ECHO_N "yes   $ECHO_C" \
 456         || echo $ECHO_N "no    $ECHO_C"
 457 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
 458 test "$x_strict_rfc_on" = "yes" \
 459         && echo "yes" \
 460         || echo "no"
 461
 462 echo $ECHO_N "   Zeroconf support: $ECHO_C"
 463 case "$x_zeroconf_on" in
 464         osx)
 465                 echo $ECHO_N "Apple $ECHO_C"
 466                 ;;
 467         howl)
 468                 echo $ECHO_N "Howl  $ECHO_C"
 469                 ;;
 470         *)
 471                 echo $ECHO_N "no    $ECHO_C"
 472                 ;;
 473 esac
 474 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
 475 test "$x_ircplus_on" = "yes" \
 476         && echo "yes" \
 477         || echo "no"
 478
 479 echo $ECHO_N "      IDENT support: $ECHO_C"
 480 test "$x_identauth_on" = "yes" \
 481         && echo $ECHO_N "yes   $ECHO_C" \
 482         || echo $ECHO_N "no    $ECHO_C"
 483 echo $ECHO_N "        I/O backend: $ECHO_C"
 484         echo "\"$x_io_backend()\""
 485
 486 echo
 487
 488 # -eof-