Add doc/Contributing.txt to distribution archive
[ngircd-alex.git] / configure.in
1 #
2 # ngIRCd -- The Next Generation IRC Daemon
3 # Copyright (c)2001-2012 Alexander Barton (alex@barton.de) and Contributors
4 #
5 # This program is free software; you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 2 of the License, or
8 # (at your option) any later version.
9 # Please read the file COPYING, README and AUTHORS for more information.
10 #
11
12 define(VERSION_ID,esyscmd(git describe|sed -e 's/rel-//g'|sed -e 's/-/~/'|tr -d \\n))
13
14 # -- Initialisation --
15
16 AC_PREREQ([2.61])
17 AC_INIT([ngIRCd], VERSION_ID,
18         [ngircd-ml@ngircd.barton.de], [ngircd], [http://ngircd.barton.de/])
19
20 AC_CONFIG_SRCDIR([src/ngircd/ngircd.c])
21 AC_CONFIG_HEADER([src/config.h])
22 AC_CANONICAL_HOST
23
24 AM_INIT_AUTOMAKE([1.10])
25
26 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
27
28 # -- Templates for config.h --
29
30 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
31 AH_TEMPLATE([HAVE_sockaddr_in_len], [Define if sockaddr_in.sin_len exists])
32 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
33 AH_TEMPLATE([IDENTAUTH], [Define if the server should do IDENT requests])
34 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
35 AH_TEMPLATE([PAM], [Define if PAM should be used])
36 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
37 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
38 AH_TEMPLATE([SYSLOG], [Define if syslog should be used for logging])
39 AH_TEMPLATE([TCPWRAP], [Define if TCP wrappers should be used])
40 AH_TEMPLATE([WANT_IPV6], [Define if IPV6 protocol should be enabled])
41 AH_TEMPLATE([ZLIB], [Define if zlib compression should be enabled])
42
43 AH_TEMPLATE([HOST_OS], [Target operating system name])
44 AH_TEMPLATE([HOST_VENDOR], [Target system vendor])
45 AH_TEMPLATE([HOST_CPU], [Target CPU name])
46
47 # -- C Compiler --
48
49 AC_PROG_CC
50 AC_PROG_CC_STDC
51
52 # -- Helper programs --
53
54 AC_PROG_AWK
55 AC_PROG_INSTALL
56 AC_PROG_LN_S
57 AC_PROG_MAKE_SET
58 AC_PROG_RANLIB
59
60 # -- Compiler Features --
61
62 AC_C_CONST
63 AC_C_INLINE
64 AM_C_PROTOTYPES
65
66 # -- Hard coded system and compiler dependencies/features/options ... --
67
68 AC_DEFUN([GCC_STACK_PROTECT_CC],[
69   ssp_cc=yes
70   # we use -fstack-protector-all for the test to enfoce the use of the guard variable 
71   AC_MSG_CHECKING([whether ${CC} accepts -fstack-protector])
72   ssp_old_cflags="$CFLAGS"
73   CFLAGS="$CFLAGS -fstack-protector-all"
74   AC_TRY_LINK(,,, ssp_cc=no)
75   echo $ssp_cc
76   CFLAGS="$ssp_old_cflags"
77   if test "X$ssp_cc" = "Xyes"; then
78       CFLAGS="$CFLAGS -fstack-protector"
79       AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
80   fi
81 ])
82
83 if test "$GCC" = "yes"; then
84         # We are using the GNU C compiler. Good!
85         CFLAGS="$CFLAGS -pipe -W -Wall -Wpointer-arith -Wstrict-prototypes"
86
87         GCC_STACK_PROTECT_CC
88 fi
89
90 case "$host_os" in
91         hpux*)
92                 # This is HP/UX, we need to define _XOPEN_SOURCE_EXTENDED
93                 # (tested with HP/UX 11.11)
94                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
95                 ;;
96 esac
97
98 # Add additional CFLAGS, eventually specified on the command line:
99 test -n "$CFLAGS_ADD" && CFLAGS="$CFLAGS $CFLAGS_ADD"
100
101 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
102
103 # -- Headers --
104
105 AC_HEADER_STDC
106 AC_HEADER_SYS_WAIT
107 AC_HEADER_TIME
108
109 # Required header files
110 AC_CHECK_HEADERS([ \
111         fcntl.h netdb.h netinet/in.h netinet/in_systm.h stdlib.h string.h \
112         strings.h sys/socket.h sys/time.h unistd.h \
113         ],,AC_MSG_ERROR([required C header missing!]))
114
115 # Optional header files
116 AC_CHECK_HEADERS_ONCE([ \
117         arpa/inet.h inttypes.h malloc.h netinet/ip.h stdbool.h stddef.h \
118         stdint.h varargs.h \
119         ])
120
121 # -- Datatypes --
122
123 AC_MSG_CHECKING(whether socklen_t exists)
124 AC_TRY_COMPILE([
125 #include <sys/types.h>
126 #include <sys/socket.h>
127         ],[
128         socklen_t a, b;
129         a = 2; b = 4; a += b;
130         ],[
131         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
132         ],[
133         AC_MSG_RESULT(no)
134 ])
135
136 AC_TYPE_PID_T
137 AC_TYPE_SIGNAL
138 AC_TYPE_SIZE_T
139 AC_TYPE_SSIZE_T
140 AC_TYPE_UID_T
141 AC_TYPE_UINT16_T
142 AC_TYPE_UINT32_T
143 AC_TYPE_UINT8_T
144
145 AC_CHECK_MEMBER([struct sockaddr_in.sin_len], AC_DEFINE(HAVE_sockaddr_in_len),,
146  [#include <arpa/inet.h>])
147
148 # -- Libraries --
149
150 # memmove: A/UX libUTIL
151 AC_SEARCH_LIBS([memmove], [UTIL], [], [
152         AC_MSG_ERROR([unable to find the memmove() function])
153 ])
154 # gethostbyname: Solaris libnsl
155 AC_SEARCH_LIBS([gethostbyname], [nsl], [], [
156         AC_MSG_ERROR([unable to find the gethostbyname() function])
157 ])
158 # bind: SVR4 libsocket
159 AC_SEARCH_LIBS([bind], [socket], [], [
160         AC_MSG_ERROR([unable to find the bind() function])
161 ])
162
163 # -- Functions --
164
165 AC_FUNC_FORK
166 AC_FUNC_STRFTIME
167
168 # Required functions
169 AC_CHECK_FUNCS([ \
170         alarm dup2 endpwent gethostbyaddr gethostbyname gethostname \
171         gettimeofday inet_ntoa memmove memset setsid socket strcasecmp \
172         strchr strcspn strerror strncasecmp strrchr strspn strstr \
173         ],,
174         AC_MSG_ERROR([required function missing!]))
175
176 # Optional functions
177 AC_CHECK_FUNCS_ONCE([ \
178         gai_strerror getaddrinfo getnameinfo inet_aton sigaction sigprocmask \
179         snprintf vsnprintf strdup strlcpy strlcat strtok_r waitpid])
180
181 # -- Configuration options --
182
183 # use syslog?
184
185 x_syslog_on=no
186 AC_ARG_WITH(syslog,
187         AS_HELP_STRING([--without-syslog],
188                        [disable syslog (autodetected by default)]),
189         [       if test "$withval" != "no"; then
190                         if test "$withval" != "yes"; then
191                                 CFLAGS="-I$withval/include $CFLAGS"
192                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
193                                 LDFLAGS="-L$withval/lib $LDFLAGS"
194                         fi
195                         AC_SEARCH_LIBS([syslog], [be], [x_syslog_on=yes], [
196                                 AC_MSG_ERROR([Can't enable syslog!])
197                         ])
198                 fi
199         ],
200         [       AC_SEARCH_LIBS([syslog], [be], [x_syslog_on=yes])
201         ]
202 )
203 if test "$x_syslog_on" = "yes"; then
204         AC_DEFINE(SYSLOG, 1)
205         AC_CHECK_HEADERS(syslog.h,,AC_MSG_ERROR([required C header missing!]))
206 fi
207
208 # use zlib compression?
209
210 x_zlib_on=no
211 AC_ARG_WITH(zlib,
212         AS_HELP_STRING([--without-zlib],
213                        [disable zlib compression (autodetected by default)]),
214         [       if test "$withval" != "no"; then
215                         if test "$withval" != "yes"; then
216                                 CFLAGS="-I$withval/include $CFLAGS"
217                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
218                                 LDFLAGS="-L$withval/lib $LDFLAGS"
219                         fi
220                         AC_CHECK_LIB(z, deflate)
221                         AC_CHECK_FUNCS(deflate, x_zlib_on=yes,
222                                 AC_MSG_ERROR([Can't enable zlib!])
223                         )
224                 fi
225         ],
226         [       AC_CHECK_LIB(z, deflate)
227                 AC_CHECK_FUNCS(deflate, x_zlib_on=yes)
228         ]
229 )
230 if test "$x_zlib_on" = "yes"; then
231         AC_DEFINE(ZLIB, 1)
232         AC_CHECK_HEADERS(zlib.h,,AC_MSG_ERROR([required C header missing!]))
233 fi
234
235 # detect which IO API to use:
236
237 x_io_backend=none
238
239 AC_ARG_WITH(select,
240         AS_HELP_STRING([--without-select],
241                        [disable select IO support (autodetected by default)]),
242         [       if test "$withval" != "no"; then
243                         if test "$withval" != "yes"; then
244                                 CFLAGS="-I$withval/include $CFLAGS"
245                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
246                                 LDFLAGS="-L$withval/lib $LDFLAGS"
247                         fi
248                         AC_CHECK_FUNCS(select, x_io_select=yes,
249                                 AC_MSG_ERROR([Can't enable select IO support!])
250                         )
251                 fi
252         ],
253         [
254                 AC_CHECK_FUNCS(select, x_io_select=yes)
255         ]
256 )
257
258 AC_ARG_WITH(poll,
259         AS_HELP_STRING([--without-poll],
260                        [disable poll support (autodetected by default)]),
261         [       if test "$withval" != "no"; then
262                         if test "$withval" != "yes"; then
263                                 CFLAGS="-I$withval/include $CFLAGS"
264                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
265                                 LDFLAGS="-L$withval/lib $LDFLAGS"
266                         fi
267                         AC_CHECK_FUNCS(poll, [
268                                 AC_CHECK_HEADERS(poll.h,
269                                         x_io_backend=poll\(\),
270                                         AC_MSG_ERROR(
271                                              [Can't enable poll IO support!])
272                                 )
273                         ], [
274                                 AC_MSG_ERROR([Can't enable poll IO support!])
275                         ])
276                 fi
277         ],
278         [
279                 AC_CHECK_FUNCS(poll, [
280                         AC_CHECK_HEADERS(poll.h, x_io_backend=poll\(\))
281                 ])
282         ]
283 )
284
285 AC_ARG_WITH(devpoll,
286         AS_HELP_STRING([--without-devpoll],
287                        [disable /dev/poll IO support (autodetected by default)]),
288         [       if test "$withval" != "no"; then
289                         if test "$withval" != "yes"; then
290                                 CFLAGS="-I$withval/include $CFLAGS"
291                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
292                                 LDFLAGS="-L$withval/lib $LDFLAGS"
293                         fi
294
295                                 AC_CHECK_HEADERS(sys/devpoll.h,,AC_MSG_ERROR([required C header missing!]))
296                 fi
297         ],
298         [
299                 AC_CHECK_HEADERS(sys/devpoll.h, x_io_backend=/dev/poll)
300         ]
301 )
302
303 AC_ARG_WITH(epoll,
304         AS_HELP_STRING([--without-epoll],
305                        [disable epoll IO support (autodetected by default)]),
306         [       if test "$withval" != "no"; then
307                         if test "$withval" != "yes"; then
308                                 CFLAGS="-I$withval/include $CFLAGS"
309                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
310                                 LDFLAGS="-L$withval/lib $LDFLAGS"
311                         fi
312                         AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes,
313                                 AC_MSG_ERROR([Can't enable epoll IO support!])
314                         )
315                 fi
316         ],
317         [
318                 AC_CHECK_FUNCS(epoll_create, x_io_epoll=yes)
319         ]
320 )
321
322 AC_ARG_WITH(kqueue,
323         AS_HELP_STRING([--without-kqueue],
324                        [disable kqueue IO support (autodetected by default)]),
325         [       if test "$withval" != "no"; then
326                         if test "$withval" != "yes"; then
327                                 CFLAGS="-I$withval/include $CFLAGS"
328                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
329                                 LDFLAGS="-L$withval/lib $LDFLAGS"
330                         fi
331                         AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\),
332                                 AC_MSG_ERROR([Can't enable kqueue IO support!])
333                         )
334                 fi
335         ],
336         [
337                 AC_CHECK_FUNCS(kqueue, x_io_backend=kqueue\(\))
338         ]
339 )
340
341 if test "$x_io_epoll" = "yes" -a "$x_io_select" = "yes"; then
342         # when epoll() and select() are available, we'll use both!
343         x_io_backend="epoll(), select()"
344 else
345         if test "$x_io_epoll" = "yes"; then
346                 # we prefere epoll() if it is available
347                 x_io_backend="epoll()"
348         else
349                 if test "$x_io_select" = "yes" -a "$x_io_backend" = "none"; then
350                         # we'll use select, when available and no "better"
351                         # interface has been detected ...
352                         x_io_backend="select()"
353                 fi
354         fi
355 fi
356
357 if test "$x_io_backend" = "none"; then
358         AC_MSG_ERROR([No useable IO API activated/found!?])
359 fi
360
361 # use SSL?
362
363 AC_ARG_WITH(openssl,
364         AS_HELP_STRING([--with-openssl],
365                        [enable SSL support using OpenSSL]),
366         [       if test "$withval" != "no"; then
367                         if test "$withval" != "yes"; then
368                                 CFLAGS="-I$withval/include $CFLAGS"
369                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
370                                 LDFLAGS="-L$withval/lib $LDFLAGS"
371                         fi
372                         AC_CHECK_LIB(crypto, BIO_s_mem)
373                         AC_CHECK_LIB(ssl, SSL_library_init)
374                         AC_CHECK_FUNCS(SSL_library_init, x_ssl_openssl=yes,
375                                 AC_MSG_ERROR([Can't enable openssl])
376                         )
377                 fi
378         ]
379 )
380
381 AC_ARG_WITH(gnutls,
382         AS_HELP_STRING([--with-gnutls],
383                        [enable SSL support using gnutls]),
384         [       if test "$withval" != "no"; then
385                         if test "$withval" != "yes"; then
386                                 CFLAGS="-I$withval/include $CFLAGS"
387                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
388                                 LDFLAGS="-L$withval/lib $LDFLAGS"
389                         fi
390                         AC_CHECK_LIB(gnutls, gnutls_global_init)
391                         AC_CHECK_FUNCS(gnutls_global_init, x_ssl_gnutls=yes,
392                                 AC_MSG_ERROR([Can't enable gnutls])
393                         )
394                 fi
395         ]
396 )
397
398 x_ssl_lib="no"
399 if test "$x_ssl_gnutls" = "yes"; then
400         if test "$x_ssl_openssl" = "yes";then
401                 AC_MSG_ERROR([Cannot enable both gnutls and openssl])
402         fi
403         x_ssl_lib=gnutls
404 fi
405 if test "$x_ssl_openssl" = "yes"; then
406         x_ssl_lib=openssl
407 fi
408
409 # use TCP wrappers?
410
411 x_tcpwrap_on=no
412 AC_ARG_WITH(tcp-wrappers,
413         AS_HELP_STRING([--with-tcp-wrappers],
414                        [enable TCP wrappers support]),
415         [       if test "$withval" != "no"; then
416                         if test "$withval" != "yes"; then
417                                 CFLAGS="-I$withval/include $CFLAGS"
418                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
419                                 LDFLAGS="-L$withval/lib $LDFLAGS"
420                         fi
421                         AC_MSG_CHECKING(for hosts_access)
422                         LIBS="-lwrap $LIBS"
423                         AC_TRY_LINK([
424 #include <tcpd.h>
425 int allow_severity = 0;
426 int deny_severity = 0;
427                                 ],[
428                                 tcpd_warn("link test");
429                                 ],[
430                                 AC_MSG_RESULT(yes)
431                                 AC_DEFINE(TCPWRAP, 1)
432                                 x_tcpwrap_on=yes
433                                 ],[
434                                 AC_MSG_RESULT(no)
435                                 AC_MSG_ERROR([Can't enable TCP wrappers!])
436                         ])
437                 fi
438         ]
439 )
440
441 # do IDENT requests using libident?
442
443 x_identauth_on=no
444 AC_ARG_WITH(ident,
445         AS_HELP_STRING([--with-ident],
446                        [enable "IDENT" ("AUTH") protocol support]),
447         [       if test "$withval" != "no"; then
448                         if test "$withval" != "yes"; then
449                                 CFLAGS="-I$withval/include $CFLAGS"
450                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
451                                 LDFLAGS="-L$withval/lib $LDFLAGS"
452                         fi
453                         AC_CHECK_LIB(ident, ident_id)
454                         AC_CHECK_FUNCS(ident_id, x_identauth_on=yes,
455                                 AC_MSG_ERROR([Can't enable IDENT support!])
456                         )
457                 fi
458         ]
459 )
460 if test "$x_identauth_on" = "yes"; then
461         AC_DEFINE(IDENTAUTH, 1)
462         AC_CHECK_HEADERS(ident.h,,AC_MSG_ERROR([required C header missing!]))
463 fi
464
465 # compile in PAM support?
466
467 x_pam_on=no
468 AC_ARG_WITH(pam,
469         AS_HELP_STRING([--with-pam],
470                        [enable user authentication using PAM]),
471         [       if test "$withval" != "no"; then
472                         if test "$withval" != "yes"; then
473                                 CFLAGS="-I$withval/include $CFLAGS"
474                                 CPPFLAGS="-I$withval/include $CPPFLAGS"
475                                 LDFLAGS="-L$withval/lib $LDFLAGS"
476                         fi
477                         AC_CHECK_LIB(pam, pam_authenticate)
478                         AC_CHECK_FUNCS(pam_authenticate, x_pam_on=yes,
479                                 AC_MSG_ERROR([Can't enable PAM support!])
480                         )
481                 fi
482         ]
483 )
484 if test "$x_pam_on" = "yes"; then
485         AC_DEFINE(PAM, 1)
486         AC_CHECK_HEADERS(security/pam_appl.h,pam_ok=yes)
487         if test "$pam_ok" != "yes"; then
488                 AC_CHECK_HEADERS(pam/pam_appl.h,pam_ok=yes,
489                         AC_MSG_ERROR([required C header missing!]))
490         fi
491 fi
492
493 # compile in IRC+ protocol support?
494
495 x_ircplus_on=yes
496 AC_ARG_ENABLE(ircplus,
497         AS_HELP_STRING([--disable-ircplus],
498                        [disable IRC+ protocol]),
499         if test "$enableval" = "no"; then x_ircplus_on=no; fi
500 )
501 if test "$x_ircplus_on" = "yes"; then
502         AC_DEFINE(IRCPLUS, 1)
503 fi
504
505 # enable support for IPv6?
506 x_ipv6_on=no
507 AC_ARG_ENABLE(ipv6,
508         AS_HELP_STRING([--enable-ipv6],
509                        [enable IPv6 protocol support]),
510         if test "$enableval" = "yes"; then x_ipv6_on=yes; fi
511 )
512 if test "$x_ipv6_on" = "yes"; then
513         # getaddrinfo() and getnameinfo() are optional when not compiling
514         # with IPv6 support, but are required for IPv6 to work!
515         AC_CHECK_FUNCS([ \
516                 getaddrinfo getnameinfo \
517                 ],,AC_MSG_ERROR([required function missing for IPv6 support!]))
518         AC_DEFINE(WANT_IPV6, 1)
519 fi
520
521 # compile in IRC "sniffer"?
522
523 x_sniffer_on=no; x_debug_on=no
524 AC_ARG_ENABLE(sniffer,
525         AS_HELP_STRING([--enable-sniffer],
526                        [enable IRC traffic sniffer (enables debug mode)]),
527         if test "$enableval" = "yes"; then
528                 AC_DEFINE(SNIFFER, 1)
529                 x_sniffer_on=yes; x_debug_on=yes
530         fi
531 )
532
533 # enable additional debugging code?
534
535 AC_ARG_ENABLE(debug,
536         AS_HELP_STRING([--enable-debug],
537                        [show additional debug output]),
538         if test "$enableval" = "yes"; then x_debug_on=yes; fi
539 )
540 if test "$x_debug_on" = "yes"; then
541         AC_DEFINE(DEBUG, 1)
542         test "$GCC" = "yes" && CFLAGS="-pedantic $CFLAGS"
543         AC_CHECK_FUNCS(mtrace)
544 fi
545
546 # enable "strict RFC rules"?
547
548 x_strict_rfc_on=no
549 AC_ARG_ENABLE(strict-rfc,
550         AS_HELP_STRING([--enable-strict-rfc],
551                        [strict RFC conformance -- may break clients!]),
552         if test "$enableval" = "yes"; then
553                 AC_DEFINE(STRICT_RFC, 1)
554                 x_strict_rfc_on=yes
555         fi
556 )
557
558 # -- Definitions --
559
560 AC_DEFINE_UNQUOTED(HOST_CPU, "$host_cpu" )
561 AC_DEFINE_UNQUOTED(HOST_VENDOR, "$host_vendor" )
562 AC_DEFINE_UNQUOTED(HOST_OS, "$host_os" )
563
564 # Add additional CFLAGS, eventually specified on the command line, but after
565 # running this configure script. Useful for "-Werror" for example.
566 test -n "$CFLAGS_END" && CFLAGS="$CFLAGS $CFLAGS_END"
567
568 # -- Generate files --
569
570 AC_CONFIG_FILES([ \
571         Makefile \
572         contrib/Anope/Makefile \
573         contrib/Debian/Makefile \
574         contrib/MacOSX/Makefile \
575         contrib/MacOSX/ngIRCd.pmdoc/Makefile \
576         contrib/MacOSX/ngIRCd.xcodeproj/Makefile \
577         contrib/Makefile \
578         doc/Makefile \
579         doc/src/Makefile \
580         man/Makefile \
581         src/ipaddr/Makefile \
582         src/Makefile \
583         src/ngircd/Makefile \
584         src/portab/Makefile \
585         src/testsuite/Makefile \
586         src/tool/Makefile \
587 ])
588
589 AC_OUTPUT
590
591 type dpkg >/dev/null 2>&1
592 if test $? -eq 0; then
593         # Generate debian/ link if the dpkg command exists
594         # (read: if we are running on a debian compatible system)
595         echo "creating Debian-specific links ..."
596         test -f debian/rules || ln -s contrib/Debian debian
597 fi
598
599 # -- Result --
600
601 echo
602 echo "ngIRCd $PACKAGE_VERSION has been configured with the following options:"
603 echo
604
605 # Someone please show me a better way :)  [borrowed by OpenSSH]
606 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
607 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
608 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
609 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
610 D=`eval echo ${docdir}` ; D=`eval echo ${D}`
611
612 echo "               Host: ${host}"
613 echo "           Compiler: ${CC}"
614 test -n "$CFLAGS"       && echo "     Compiler flags: ${CFLAGS}"
615 test -n "$CPPFLAGS"     && echo " Preprocessor flags: ${CPPFLAGS}"
616 test -n "$LDFLAGS"      && echo "       Linker flags: ${LDFLAGS}"
617 test -n "$LIBS"         && echo "          Libraries: ${LIBS}"
618 echo
619 echo "    'ngircd' binary: $S"
620 echo " Configuration file: $C"
621 echo "       Manual pages: $M"
622 echo "      Documentation: $D"
623 echo
624
625 echo $ECHO_N "     Syslog support: $ECHO_C"
626 test "$x_syslog_on" = "yes" \
627         && echo $ECHO_N "yes   $ECHO_C" \
628         || echo $ECHO_N "no    $ECHO_C"
629 echo $ECHO_N "  Enable debug code: $ECHO_C"
630 test "$x_debug_on" = "yes" \
631         && echo "yes" \
632         || echo "no"
633
634 echo $ECHO_N "   zlib compression: $ECHO_C"
635 test "$x_zlib_on" = "yes" \
636         && echo $ECHO_N "yes   $ECHO_C" \
637         || echo $ECHO_N "no    $ECHO_C"
638 echo $ECHO_N "        IRC sniffer: $ECHO_C"
639 test "$x_sniffer_on" = "yes" \
640         && echo "yes" \
641         || echo "no"
642
643 echo $ECHO_N "   Use TCP Wrappers: $ECHO_C"
644 test "$x_tcpwrap_on" = "yes" \
645         && echo $ECHO_N "yes   $ECHO_C" \
646         || echo $ECHO_N "no    $ECHO_C"
647 echo $ECHO_N "    Strict RFC mode: $ECHO_C"
648 test "$x_strict_rfc_on" = "yes" \
649         && echo "yes" \
650         || echo "no"
651
652 echo $ECHO_N "      IDENT support: $ECHO_C"
653 test "$x_identauth_on" = "yes" \
654         && echo $ECHO_N "yes   $ECHO_C" \
655         || echo $ECHO_N "no    $ECHO_C"
656 echo $ECHO_N "      IRC+ protocol: $ECHO_C"
657 test "$x_ircplus_on" = "yes" \
658         && echo "yes" \
659         || echo "no"
660
661 echo $ECHO_N "      IPv6 protocol: $ECHO_C"
662 test "$x_ipv6_on" = "yes" \
663         && echo $ECHO_N "yes   $ECHO_C" \
664         || echo $ECHO_N "no    $ECHO_C"
665 echo $ECHO_N "        I/O backend: $ECHO_C"
666         echo "\"$x_io_backend\""
667
668 echo $ECHO_N "        PAM support: $ECHO_C"
669 test "$x_pam_on" = "yes" \
670         && echo $ECHO_N "yes   $ECHO_C" \
671         || echo $ECHO_N "no    $ECHO_C"
672 echo $ECHO_N "        SSL support: $ECHO_C"
673 echo "$x_ssl_lib"
674
675 echo
676
677 # -eof-