- ngIRCd "Test-Suite" in Build-System aufgenommen.
[ngircd-alex.git] / configure.in
1 #
2 # ngIRCd -- The Next Generation IRC Daemon
3 # Copyright (c)2001,2002 by Alexander Barton (alex@barton.de)
4 #
5 # Dieses Programm ist freie Software. Sie koennen es unter den Bedingungen
6 # der GNU General Public License (GPL), wie von der Free Software Foundation
7 # herausgegeben, weitergeben und/oder modifizieren, entweder unter Version 2
8 # der Lizenz oder (wenn Sie es wuenschen) jeder spaeteren Version.
9 # Naehere Informationen entnehmen Sie bitter der Datei COPYING. Eine Liste
10 # der an ngIRCd beteiligten Autoren finden Sie in der Datei AUTHORS.
11 #
12 # $Id: configure.in,v 1.57 2002/09/09 10:00:15 alex Exp $
13 #
14
15 # -- Initialisierung --
16
17 AC_INIT
18 AC_PREREQ(2.50)
19 AC_CANONICAL_TARGET
20 AC_CONFIG_SRCDIR(src/config.h.in)
21 AM_INIT_AUTOMAKE(ngircd,CurrentCVS)
22 AM_CONFIG_HEADER(src/config.h)
23
24 # -- Templates fuer config.h --
25
26 AH_TEMPLATE([DEBUG], [Define if debug-mode should be enabled])
27 AH_TEMPLATE([HAVE_socklen_t], [Define if socklen_t exists])
28 AH_TEMPLATE([SNIFFER], [Define if IRC sniffer should be enabled])
29 AH_TEMPLATE([STRICT_RFC], [Define if ngIRCd should behave strict RFC compliant])
30 AH_TEMPLATE([USE_SYSLOG], [Define if syslog should be used for logging])
31 AH_TEMPLATE([IRCPLUS], [Define if IRC+ protocol should be used])
32
33 AH_TEMPLATE([TARGET_OS], [Target operating system name])
34 AH_TEMPLATE([TARGET_VENDOR], [Target system vendor])
35 AH_TEMPLATE([TARGET_CPU], [Target CPU name])
36
37 # -- C Compiler --
38
39 AC_PROG_CC
40
41 # -- Hilfsprogramme --
42
43 AC_PROG_AWK
44 AC_PROG_INSTALL
45 AC_PROG_LN_S
46 AC_PROG_MAKE_SET
47 AC_PROG_RANLIB
48
49 # -- Compiler Features --
50
51 AC_LANG_C
52
53 AM_C_PROTOTYPES
54 AC_C_CONST
55
56 # -- Header --
57
58 AC_HEADER_STDC
59
60 AC_HEADER_TIME
61
62 AC_HEADER_SYS_WAIT
63
64 AC_CHECK_HEADERS([ \
65         ctype.h errno.h fcntl.h netdb.h netinet/in.h stdlib.h string.h \
66         strings.h sys/socket.h sys/time.h unistd.h \
67         ],,AC_MSG_ERROR([required C header missing!]))
68
69 AC_CHECK_HEADERS(arpa/inet.h malloc.h stdint.h varargs.h)
70
71 # -- Datentypen --
72
73 AC_MSG_CHECKING(whether socklen_t exists)
74 AC_TRY_COMPILE([
75         #include <sys/socket.h>
76         #include <sys/types.h>
77         ],[
78         socklen_t a, b;
79         a = 2; b = 4; a += b;
80         ],[
81         AC_DEFINE(HAVE_socklen_t) AC_MSG_RESULT(yes)
82         ],[
83         AC_MSG_RESULT(no)
84 ])
85
86 AC_TYPE_SIGNAL
87
88 AC_TYPE_SIZE_T
89
90 # -- Libraries --
91
92 AC_CHECK_LIB(UTIL,memmove)
93 AC_CHECK_LIB(socket,bind)
94 AC_CHECK_LIB(nsl,gethostent)
95
96 # -- Funktionen --
97
98 AC_FUNC_MALLOC
99
100 AC_FUNC_FORK
101
102 AC_FUNC_STRFTIME
103
104 AC_CHECK_FUNCS([ \
105         bind gethostbyaddr gethostbyname gethostname inet_ntoa memmove \
106         memset select setsockopt socket strcasecmp strchr strerror \
107         strstr waitpid \
108         ],,AC_MSG_ERROR([required function missing!]))
109
110 AC_CHECK_FUNCS(inet_aton sigaction snprintf vsnprintf)
111
112 # -- Konfigurationsoptionen --
113
114 x_syslog_on=no
115 AC_ARG_ENABLE(syslog,
116         [  --disable-syslog        disable syslog (autodetected by default)],
117         [       if test "$enableval" = "yes"; then
118                         AC_CHECK_HEADER(syslog.h, x_syslog_on=yes,
119                                 AC_MSG_ERROR([Can't enable syslog: syslog.h not found!])
120                         )
121                 fi
122         ],
123         [       AC_CHECK_HEADER(syslog.h, x_syslog_on=yes) ]
124 )
125 if test "$x_syslog_on" = "yes"; then
126         AC_DEFINE(USE_SYSLOG, 1)
127         AC_CHECK_LIB(be,syslog)
128 fi
129
130 x_ircplus_on=yes
131 AC_ARG_ENABLE(ircplus,
132         [  --disable-ircplus       disable IRC+ protocol],
133         if test "$enableval" = "no"; then x_ircplus_on=no; fi
134 )
135 if test "$x_ircplus_on" = "yes"; then
136         AC_DEFINE(IRCPLUS, 1)
137 fi
138
139 AC_ARG_ENABLE(sniffer,
140         [  --enable-sniffer        enable IRC traffic sniffer (enables debug mode)],
141         if test "$enableval" = "yes"; then
142                 AC_DEFINE(SNIFFER, 1)
143                 x_sniffer_on=yes; x_debug_on=yes
144         fi
145 )
146
147 AC_ARG_ENABLE(debug,
148         [  --enable-debug          show additional debug output],
149         if test "$enableval" = "yes"; then x_debug_on=yes; fi
150 )
151 if test "$x_debug_on" = "yes"; then
152         AC_DEFINE(DEBUG, 1)
153 fi
154
155 AC_ARG_ENABLE(strict-rfc,
156         [  --enable-strict-rfc     strict RFC conformance -- may break clients!],
157         if test "$enableval" = "yes"; then
158                 AC_DEFINE(STRICT_RFC, 1)
159                 x_strict_rfc_on=yes
160         fi
161 )
162
163
164 # -- Definitionen --
165
166 AC_DEFINE_UNQUOTED(TARGET_CPU, "$target_cpu" )
167 AC_DEFINE_UNQUOTED(TARGET_VENDOR, "$target_vendor" )
168 AC_DEFINE_UNQUOTED(TARGET_OS, "$target_os" )
169
170 if test `uname` = "A/UX"; then
171         # unter A/UX sollte _POSIX_SOURCE definiert sein.
172         AC_MSG_RESULT([detected A/UX, defining _POSIX_SOURCE])
173         CFLAGS="$CFLAGS -D_POSIX_SOURCE"
174 fi
175
176 # -- Variablen --
177
178 if test "$GCC" = "yes"; then
179         CFLAGS="-Wall $CFLAGS"
180 fi
181
182 CFLAGS="$CFLAGS -DSYSCONFDIR='\"\$(sysconfdir)\"'"
183
184 # -- Ausgabe der Dateien --
185
186 AC_OUTPUT([ \
187         Makefile \
188         doc/Makefile \
189         doc/en/Makefile \
190         MacOSX/Makefile \
191         MacOSX/ngircd.pbproj/Makefile \
192         src/Makefile \
193         src/portab/Makefile \
194         src/ngircd/Makefile \
195         src/testsuite/Makefile \
196         man/Makefile \
197 ])
198
199 # -- Ergebnis --
200
201 echo
202
203 # Someone please show me a better way :)  [borrowed by OpenSSH]
204 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
205 S=`eval echo ${sbindir}` ; S=`eval echo ${S}`
206 C=`eval echo ${sysconfdir}` ; C=`eval echo ${C}`
207 M=`eval echo ${mandir}` ; M=`eval echo ${M}`
208
209 echo "                host: ${host}"
210 echo "            compiler: ${CC}"
211 echo "      compiler flags: ${CFLAGS}"
212 echo "  preprocessor flags: ${CPPFLAGS}"
213 echo "        linker flags: ${LDFLAGS}"
214 echo "           libraries: ${LIBS}"
215 echo
216
217 echo "     'ngircd' binary: $S"
218 echo "  configuration file: $C"
219 echo "        manual pages: $M"
220 echo
221
222 echo $ECHO_N "      active options: $ECHO_C"
223 test "$x_syslog_on" = "yes"     && echo $ECHO_N "Syslog $ECHO_C"
224 test "$x_debug_on" = "yes"      && echo $ECHO_N "Debug $ECHO_C"
225 test "$x_sniffer_on" = "yes"    && echo $ECHO_N "Sniffer $ECHO_C"
226 test "$x_strict_rfc_on" = "yes" && echo $ECHO_N "Strict-RFC $ECHO_C"
227 test "$x_ircplus_on" = "yes"    && echo $ECHO_N "IRC+ $ECHO_C"
228 echo; echo
229
230 # -eof-