macros/db3-check.m4

   1 dnl $Id: db3-check.m4,v 1.19 2009-07-03 08:15:19 franklahm Exp $
   2 dnl Autoconf macros to check for the Berkeley DB library
   3
   4 dnl -- check header for minimum version and return version in
   5 dnl -- $atalk_cv_bdb_MAJOR and $atalk_cv_bdb_MINOR
   6 AC_DEFUN([NETATALK_BDB_HEADER],[
   7     dnl check for header version
   8     AC_MSG_CHECKING([$1/db.h version >= ${DB_MAJOR_REQ}.${DB_MINOR_REQ}.${DB_PATCH_REQ}])
   9
  10     atalk_cv_bdb_MAJOR=`grep DB_VERSION_MAJOR "$1/db.h" | cut -f 3`
  11     atalk_cv_bdb_MINOR=`grep DB_VERSION_MINOR "$1/db.h" | cut -f 3`
  12
  13     if test $DB_MAJOR_REQ -gt $atalk_cv_bdb_MAJOR ; then
  14         AC_MSG_RESULT([no])
  15         atalk_cv_bdbheader=no
  16     elif test $DB_MINOR_REQ -gt $atalk_cv_bdb_MINOR ; then
  17         AC_MSG_RESULT([no])
  18         atalk_cv_bdbheader=no
  19     else
  20         AC_MSG_RESULT([yes])
  21         atalk_cv_bdbheader=yes
  22     fi
  23 ])
  24
  25 dnl -- Try to link and run with lib with version taken from
  26 dnl -- $atalk_cv_bdb_MAJOR and $atalk_cv_bdb_MINOR
  27 AC_DEFUN([NETATALK_BDB_TRY_LINK],[
  28     atalk_cv_bdb_version=no
  29     maj=$atalk_cv_bdb_MAJOR
  30     min=$atalk_cv_bdb_MINOR
  31     atalk_cv_bdb_try_libs="db$maj$min db$maj.$min db-$maj$min db-$maj.$min"
  32
  33     for lib in $atalk_cv_bdb_try_libs ; do
  34         LIBS="-l$lib $savedlibs"
  35         AC_MSG_CHECKING([Berkeley DB library (-l$lib)])
  36         AC_TRY_RUN([
  37             #include <stdio.h>
  38             #include <db.h>
  39             int main(void) {
  40                 int major, minor, patch;
  41                 char *version_str;
  42                 version_str = db_version(&major, &minor, &patch);
  43                 if (major < DB_MAJOR_REQ || minor < DB_MINOR_REQ || patch < DB_PATCH_REQ) {
  44                     printf("linking wrong library version (%d.%d.%d), ",major, minor, patch);
  45                     return (2);
  46                 }
  47                 if ( major != DB_VERSION_MAJOR || minor != DB_VERSION_MINOR || patch != DB_VERSION_PATCH) {
  48                     printf("header/library version mismatch (%d.%d.%d/%d.%d.%d), ",
  49                         DB_VERSION_MAJOR, DB_VERSION_MINOR, DB_VERSION_PATCH, major, minor, patch);
  50                     return (3);
  51                 }
  52                 printf("%d.%d.%d ... ",major, minor, patch);
  53                 return (0);
  54             }
  55         ],[
  56             AC_MSG_RESULT(yes)
  57             atalk_cv_bdb_version="yes"
  58             atalk_cv_lib_db="-l$lib"
  59             break
  60         ],[
  61             AC_MSG_RESULT(no)
  62         ],[
  63             bdblibs=`ls $bdblibdir/lib$lib.* 2>/dev/null`
  64             for bdblib in $bdblibs ; do
  65                 echo "Testing for lib file $bdblib" >&AS_MESSAGE_LOG_FD
  66                 if test -f "$bdblib" ; then
  67                     AC_MSG_RESULT([yes (cross-compiling)])
  68                     atalk_cv_bdb_version="yes"
  69                     atalk_cv_lib_db="-l$lib"
  70                     break
  71                 fi
  72             done
  73             if test "x$atalk_cv_bdb_version" = "xyes" ; then
  74                 break
  75             fi
  76             AC_MSG_RESULT([no (cross-compiling)])
  77         ])
  78     done
  79     LIBS="$savedlibs"
  80 ])
  81
  82 dnl -- This is called from configure
  83 AC_DEFUN([AC_PATH_BDB],[
  84     trybdbdir=""
  85     dobdbsearch=yes
  86     bdb_search_dirs="/usr/local /usr"
  87     search_subdirs="/ /db4.7 /db47 /db4.6 /db46 /db4.5 /db45 /db4.4 /db44 /db4"
  88
  89     dnl required BDB version: 4.4, because of DB_AUTO_COMMIT
  90     DB_MAJOR_REQ=4
  91     DB_MINOR_REQ=4
  92     DB_PATCH_REQ=0
  93
  94     dnl make sure atalk_libname is defined beforehand
  95     [[ -n "$atalk_libname" ]] || AC_MSG_ERROR([internal error, atalk_libname undefined])
  96
  97     dnl define the required BDB version
  98     AC_DEFINE_UNQUOTED(DB_MAJOR_REQ, ${DB_MAJOR_REQ}, [Required BDB version, major])
  99     AC_DEFINE_UNQUOTED(DB_MINOR_REQ, ${DB_MINOR_REQ}, [Required BDB version, minor])
 100     AC_DEFINE_UNQUOTED(DB_PATCH_REQ, ${DB_PATCH_REQ}, [Required BDB version, patch])
 101
 102     AC_ARG_WITH(bdb,
 103         [  --with-bdb=PATH         specify path to Berkeley DB installation[[auto]]],
 104         if test "x$withval" = "xno"; then
 105             dobdbsearch=no
 106         elif test "x$withval" = "xyes"; then
 107             dobdbsearch=yes
 108         else
 109             bdb_search_dirs="$withval"
 110         fi
 111     )
 112
 113     bdbfound=no
 114     savedcflags="$CFLAGS"
 115     savedldflags="$LDFLAGS"
 116     savedcppflags="$CPPFLAGS"
 117     savedlibs="$LIBS"
 118     saved_shlibpath_var=$shlibpath_var
 119
 120     if test "x$dobdbsearch" = "xyes"; then
 121         for bdbdir in $bdb_search_dirs; do
 122             if test $bdbfound = "yes"; then
 123                 break;
 124             fi
 125             for subdir in ${search_subdirs}; do
 126                 AC_MSG_CHECKING([for Berkeley DB headers in ${bdbdir}/include${subdir}])
 127                 dnl -- First check the mere existence of the header
 128                 if test -f "${bdbdir}/include${subdir}/db.h" ; then
 129                     AC_MSG_RESULT([yes])
 130
 131                     dnl -- Check if it meets minimun requirement, also return the version
 132                     NETATALK_BDB_HEADER([${bdbdir}/include${subdir}])
 133
 134                     if test ${atalk_cv_bdbheader} != "no"; then
 135                         bdblibdir="${bdbdir}/${atalk_libname}"
 136                         bdbbindir="${bdbdir}/bin"
 137
 138                         CPPFLAGS="-I${bdbdir}/include${subdir} $CPPFLAGS"
 139                         LDFLAGS="-L$bdblibdir $LDFLAGS"
 140
 141                         dnl -- Uses version set by NETATALK_BDB_HEADER to try to run
 142                         dnl -- a conftest that checks that header/lib version match
 143                         dnl -- $shlibpath_var is set by LIBTOOL, its value is
 144                         dnl -- LD_LIBRARY_PATH on many platforms. This will be fairly
 145                         dnl -- portable hopefully. Reference:
 146                         dnl -- http://lists.gnu.org/archive/html/autoconf/2009-03/msg00040.html
 147                         eval export $shlibpath_var=$bdblibdir
 148                         NETATALK_BDB_TRY_LINK
 149                         eval export $shlibpath_var=$saved_shlibpath_var
 150
 151                         if test x"${atalk_cv_bdb_version}" = x"yes"; then
 152                             BDB_CFLAGS="-I${bdbdir}/include${subdir}"
 153                             BDB_LIBS="-L${bdblibdir} ${atalk_cv_lib_db}"
 154                             BDB_BIN="$bdbbindir"
 155                             BDB_PATH="$bdbdir"
 156                             bdbfound=yes
 157                             break;
 158                         fi
 159                     fi
 160                     CFLAGS="$savedcflags"
 161                     LDFLAGS="$savedldflags"
 162                     CPPFLAGS="$savedcppflags"
 163                     LIBS="$savedlibs"
 164                 else
 165                     AC_MSG_RESULT([no])
 166                 fi
 167             done
 168         done
 169     fi
 170
 171     CFLAGS="$savedcflags"
 172     LDFLAGS="$savedldflags"
 173     CPPFLAGS="$savedcppflags"
 174     LIBS="$savedlibs"
 175
 176     if test "x$bdbfound" = "xyes"; then
 177         ifelse([$1], , :, [$1])
 178     else
 179         ifelse([$2], , :, [$2])
 180     fi
 181
 182     CFLAGS_REMOVE_USR_INCLUDE(BDB_CFLAGS)
 183     LIB_REMOVE_USR_LIB(BDB_LIBS)
 184     AC_SUBST(BDB_CFLAGS)
 185     AC_SUBST(BDB_LIBS)
 186     AC_SUBST(BDB_BIN)
 187     AC_SUBST(BDB_PATH)
 188 ])
 189
 190