etc/spotlight/slmod_sparql_parser.y

   1 %{
   2   #include <atalk/standards.h>
   3
   4   #include <stdbool.h>
   5   #include <stdio.h>
   6   #include <string.h>
   7   #include <time.h>
   8
   9   #include <gio/gio.h>
  10
  11   #include <atalk/talloc.h>
  12   #include <atalk/logger.h>
  13   #include <atalk/errchk.h>
  14   #include <atalk/spotlight.h>
  15
  16   #include "slmod_sparql_map.h"
  17
  18   struct yy_buffer_state;
  19   typedef struct yy_buffer_state *YY_BUFFER_STATE;
  20   extern int yylex (void);
  21   extern void yyerror (char const *);
  22   extern void *yyterminate(void);
  23   extern YY_BUFFER_STATE yy_scan_string( const char *str);
  24   extern void yy_delete_buffer ( YY_BUFFER_STATE buffer );
  25
  26   /* forward declarations */
  27   static const char *map_expr(const char *attr, char op, const char *val);
  28   static const char *map_daterange(const char *dateattr, time_t date1, time_t date2);
  29   static time_t isodate2unix(const char *s);
  30
  31  /* global vars, eg needed by the lexer */
  32   slq_t *ssp_slq;
  33
  34   /* local vars */
  35   static gchar *ssp_result;
  36   static char sparqlvar;
  37   static char *result_limit;
  38 %}
  39
  40 %code provides {
  41   #define SPRAW_TIME_OFFSET 978307200
  42   extern int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result);
  43   extern slq_t *ssp_slq;
  44 }
  45
  46 %union {
  47     int ival;
  48     const char *sval;
  49     bool bval;
  50     time_t tval;
  51 }
  52
  53 %expect 5
  54 %error-verbose
  55
  56 %type <sval> match expr line function
  57 %type <tval> date
  58
  59 %token <sval> WORD
  60 %token <bval> BOOL
  61 %token FUNC_INRANGE
  62 %token DATE_ISO
  63 %token OBRACE CBRACE EQUAL UNEQUAL GT LT COMMA QUOTE
  64 %left AND
  65 %left OR
  66 %%
  67
  68 input:
  69 /* empty */
  70 | input line
  71 ;
  72
  73 line:
  74 expr                           {
  75     if (ssp_slq->slq_result_limit)
  76         result_limit = talloc_asprintf(ssp_slq, "LIMIT %ld", ssp_slq->slq_result_limit);
  77     else
  78         result_limit = "";
  79     ssp_result = talloc_asprintf(ssp_slq,
  80                                  "SELECT ?url WHERE "
  81                                  "{ %s . ?obj nie:url ?url . FILTER(tracker:uri-is-descendant('file://%s/', ?url)) } %s",
  82                                  $1, ssp_slq->slq_vol->v_path, result_limit);
  83     $$ = ssp_result;
  84 }
  85 ;
  86
  87 expr:
  88 BOOL                             {
  89     if ($1 == false)
  90         YYACCEPT;
  91     else
  92         YYABORT;
  93 }
  94 | match OR match                 {
  95     if ($1 == NULL || $3 == NULL)
  96         YYABORT;
  97     if (strcmp($1, $3) != 0)
  98         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
  99     else
 100         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 101 }
 102 | match                        {$$ = $1; if ($$ == NULL) YYABORT;}
 103 | function                     {$$ = $1;}
 104 | OBRACE expr CBRACE           {$$ = talloc_asprintf(ssp_slq, "%s", $2);}
 105 | expr AND expr                {
 106     if (!ssp_slq->slq_allow_expr) {
 107         yyerror("Spotlight queries with logic expressions are disabled");
 108         YYABORT;
 109     }
 110     $$ = talloc_asprintf(ssp_slq, "%s . %s", $1, $3);
 111 }
 112 | expr OR expr                 {
 113     if (!ssp_slq->slq_allow_expr) {
 114         yyerror("Spotlight queries with logic expressions are disabled");
 115         YYABORT;
 116     }
 117     if (strcmp($1, $3) != 0)
 118         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
 119     else
 120         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 121 }
 122 ;
 123
 124 match:
 125 WORD EQUAL QUOTE WORD QUOTE     {$$ = map_expr($1, '=', $4);}
 126 | WORD UNEQUAL QUOTE WORD QUOTE {$$ = map_expr($1, '!', $4);}
 127 | WORD LT QUOTE WORD QUOTE      {$$ = map_expr($1, '<', $4);}
 128 | WORD GT QUOTE WORD QUOTE      {$$ = map_expr($1, '>', $4);}
 129 | WORD EQUAL QUOTE WORD QUOTE WORD    {$$ = map_expr($1, '=', $4);}
 130 | WORD UNEQUAL QUOTE WORD QUOTE WORD {$$ = map_expr($1, '!', $4);}
 131 | WORD LT QUOTE WORD QUOTE WORD     {$$ = map_expr($1, '<', $4);}
 132 | WORD GT QUOTE WORD QUOTE WORD     {$$ = map_expr($1, '>', $4);}
 133 ;
 134
 135 function:
 136 FUNC_INRANGE OBRACE WORD COMMA date COMMA date CBRACE {$$ = map_daterange($3, $5, $7);}
 137 ;
 138
 139 date:
 140 DATE_ISO OBRACE WORD CBRACE    {$$ = isodate2unix($3);}
 141 | WORD                         {$$ = atoi($1) + SPRAW_TIME_OFFSET;}
 142 ;
 143
 144 %%
 145
 146 static time_t isodate2unix(const char *s)
 147 {
 148     struct tm tm;
 149
 150     if (strptime(s, "%Y-%m-%dT%H:%M:%SZ", &tm) == NULL)
 151         return (time_t)-1;
 152     return mktime(&tm);
 153 }
 154
 155 static const char *map_daterange(const char *dateattr, time_t date1, time_t date2)
 156 {
 157     EC_INIT;
 158     char *result = NULL;
 159     struct spotlight_sparql_map *p;
 160     struct tm *tmp;
 161     char buf1[64], buf2[64];
 162
 163     EC_NULL_LOG( tmp = localtime(&date1) );
 164     strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 165     EC_NULL_LOG( tmp = localtime(&date2) );
 166     strftime(buf2, sizeof(buf2), "%Y-%m-%dT%H:%M:%SZ", tmp);
 167
 168     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 169         if (strcmp(dateattr, p->ssm_spotlight_attr) == 0) {
 170             result = talloc_asprintf(ssp_slq,
 171                                      "?obj %s ?%c FILTER (?%c > '%s' && ?%c < '%s')",
 172                                      p->ssm_sparql_attr,
 173                                      sparqlvar,
 174                                      sparqlvar,
 175                                      buf1,
 176                                      sparqlvar,
 177                                      buf2);
 178             sparqlvar++;
 179             break;
 180         }
 181     }
 182
 183 EC_CLEANUP:
 184     if (ret != 0)
 185         return NULL;
 186     return result;
 187 }
 188
 189 static char *map_type_search(const char *attr, char op, const char *val)
 190 {
 191     char *result = NULL;
 192     const char *sparqlAttr;
 193
 194     for (struct MDTypeMap *p = MDTypeMap; p->mdtm_value; p++) {
 195         if (strcmp(p->mdtm_value, val) == 0) {
 196             switch (p->mdtm_type) {
 197             case kMDTypeMapRDF:
 198                 sparqlAttr = "rdf:type";
 199                 break;
 200             case kMDTypeMapMime:
 201                 sparqlAttr = "nie:mimeType";
 202                 break;
 203             default:
 204                 return NULL;
 205             }
 206             result = talloc_asprintf(ssp_slq, "?obj %s '%s'",
 207                                      sparqlAttr,
 208                                      p->mdtm_sparql);
 209             break;
 210         }
 211     }
 212     return result;
 213 }
 214
 215 static const char *map_expr(const char *attr, char op, const char *val)
 216 {
 217     EC_INIT;
 218     char *result = NULL;
 219     struct spotlight_sparql_map *p;
 220     time_t t;
 221     struct tm *tmp;
 222     char buf1[64];
 223     bstring q = NULL, search = NULL, replace = NULL;
 224
 225     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 226         if (p->ssm_enabled && (strcmp(p->ssm_spotlight_attr, attr) == 0)) {
 227             if (p->ssm_type != ssmt_type && p->ssm_sparql_attr == NULL) {
 228                 yyerror("unsupported Spotlight attribute");
 229                 EC_FAIL;
 230             }
 231             switch (p->ssm_type) {
 232             case ssmt_bool:
 233                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 234                 break;
 235             case ssmt_num:
 236                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c%c '%s')",
 237                                          p->ssm_sparql_attr,
 238                                          sparqlvar,
 239                                          sparqlvar,
 240                                          op,
 241                                          op == '!' ? '=' : ' ', /* append '=' to '!' */
 242                                          val);
 243                 sparqlvar++;
 244                 break;
 245             case ssmt_str:
 246                 q = bformat("^%s$", val);
 247                 search = bfromcstr("*");
 248                 replace = bfromcstr(".*");
 249                 bfindreplace(q, search, replace, 0);
 250                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(regex(?%c, '%s'))",
 251                                          p->ssm_sparql_attr,
 252                                          sparqlvar,
 253                                          sparqlvar,
 254                                          bdata(q));
 255                 sparqlvar++;
 256                 break;
 257             case ssmt_fts:
 258                 result = talloc_asprintf(ssp_slq, "?obj %s '%s'", p->ssm_sparql_attr, val);
 259                 break;
 260             case ssmt_date:
 261                 t = atoi(val) + SPRAW_TIME_OFFSET;
 262                 EC_NULL( tmp = localtime(&t) );
 263                 strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 264                 result = talloc_asprintf(ssp_slq, "?obj %s ?%c FILTER(?%c %c '%s')",
 265                                          p->ssm_sparql_attr,
 266                                          sparqlvar,
 267                                          sparqlvar,
 268                                          op,
 269                                          buf1);
 270                 sparqlvar++;
 271                 break;
 272             case ssmt_type:
 273                 result = map_type_search(attr, op, val);
 274                 break;
 275             default:
 276                 EC_FAIL;
 277             }
 278             break;
 279         }
 280     }
 281
 282 EC_CLEANUP:
 283     if (q)
 284         bdestroy(q);
 285     if (search)
 286         bdestroy(search);
 287     if (replace)
 288         bdestroy(replace);
 289     return result;
 290 }
 291
 292 void yyerror(const char *str)
 293 {
 294 #ifdef MAIN
 295     printf("yyerror: %s\n", str);
 296 #else
 297     LOG(log_error, logtype_sl, "yyerror: %s", str);
 298 #endif
 299 }
 300
 301 int yywrap()
 302 {
 303     return 1;
 304 }
 305
 306 /**
 307  * Map a Spotlight RAW query string to a SPARQL query string
 308  *
 309  * @param[in]     slq            Spotlight query handle
 310  * @param[out]    sparql_result  Mapped SPARQL query, string is allocated in
 311  *                               talloc context of slq
 312  * @return        0 on success, -1 on error
 313  **/
 314 int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result)
 315 {
 316     EC_INIT;
 317     YY_BUFFER_STATE s = NULL;
 318     ssp_result = NULL;
 319
 320     ssp_slq = slq;
 321     s = yy_scan_string(slq->slq_qstring);
 322     sparqlvar = 'a';
 323
 324     EC_ZERO( yyparse() );
 325
 326 EC_CLEANUP:
 327     if (s)
 328         yy_delete_buffer(s);
 329     if (ret == 0)
 330         *sparql_result = ssp_result;
 331     else
 332         *sparql_result = NULL;
 333     EC_EXIT;
 334 }
 335
 336 #ifdef MAIN
 337 int main(int argc, char **argv)
 338 {
 339     int ret;
 340     YY_BUFFER_STATE s;
 341
 342     if (argc != 2) {
 343         printf("usage: %s QUERY\n", argv[0]);
 344         return 1;
 345     }
 346
 347     ssp_slq = talloc_zero(NULL, slq_t);
 348     struct vol *vol = talloc_zero(ssp_slq, struct vol);
 349     vol->v_path = "/Volumes/test";
 350     ssp_slq->slq_vol = vol;
 351     ssp_slq->slq_allow_expr = true;
 352     sparqlvar = 'a';
 353
 354     s = yy_scan_string(argv[1]);
 355
 356     ret = yyparse();
 357
 358     yy_delete_buffer(s);
 359
 360     if (ret == 0)
 361         printf("SPARQL: %s\n", ssp_result ? ssp_result : "(empty)");
 362
 363     return 0;
 364 }
 365 #endif