configure.in

   1 dnl $Id: configure.in,v 1.238 2010-02-10 14:05:36 franklahm Exp $
   2 dnl configure.in for netatalk
   3
   4 AC_INIT(etc/afpd/main.c)
   5
   6 NETATALK_VERSION=`cat $srcdir/VERSION`
   7 AC_SUBST(NETATALK_VERSION)
   8
   9 AC_CANONICAL_SYSTEM
  10 AM_INIT_AUTOMAKE(netatalk, ${NETATALK_VERSION})
  11 AM_CONFIG_HEADER(config.h)
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_CC_C99
  17 AC_PROG_INSTALL
  18 AC_PROG_LN_S
  19 AC_PROG_MAKE_SET
  20 AC_LIBTOOL_DLOPEN
  21 AC_PROG_LIBTOOL
  22 AC_PROG_PERL
  23 AC_PROG_GREP
  24 AC_PROG_PS
  25
  26 AM_PROG_CC_C_O
  27
  28 dnl *********************************************************************
  29 dnl FIXME! FIXME! These should be selectable properly, and should produce
  30 dnl the proper flags and defines...
  31 dnl *********************************************************************
  32
  33 ############################################
  34 # we need dlopen/dlclose/dlsym/dlerror for PAM, the password database plugins and the plugin loading code
  35 #AC_SEARCH_LIBS(dlopen, [dl])
  36 # dlopen/dlclose/dlsym/dlerror will be checked again later and defines will be set then
  37
  38 dnl Checks for libraries.
  39 dnl Replace `main' with a function in -labs:
  40 dnl AC_CHECK_LIB(abs, main)
  41 dnl Replace `main' with a function in -laudit:
  42 dnl AC_CHECK_LIB(audit, main)
  43 dnl Replace `main' with a function in -lauth:
  44 dnl AC_CHECK_LIB(auth, main)
  45 dnl Replace `main' with a function in -lcmd:
  46 dnl AC_CHECK_LIB(cmd, main)
  47 dnl Replace `main' with a function in -lcrypt:
  48 dnl AC_CHECK_LIB(crypt, main)
  49 dnl Replace `main' with a function in -ld:
  50 dnl AC_CHECK_LIB(d, main)
  51 dnl Replace `main' with a function in -ldl:
  52 dnl AC_CHECK_LIB(dl, dlopen)
  53 dnl Replace `main' with a function in -lkauth:
  54 dnl AC_CHECK_LIB(kauth, main)
  55 dnl Replace `main' with a function in -lkrb:
  56 dnl AC_CHECK_LIB(krb, main)
  57 dnl Replace `main' with a function in -llwp:
  58 dnl AC_CHECK_LIB(lwp, main)
  59 dnl Replace `main' with a function in -ln:
  60 dnl AC_CHECK_LIB(n, main)
  61
  62 dnl not the right stuff but should be enough for now
  63 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
  64 AC_CHECK_FUNC(connect,,[AC_CHECK_LIB(socket,connect)])
  65
  66 dnl Replace `main' with a function in -lprot:
  67 dnl AC_CHECK_LIB(prot, main)
  68 dnl Replace `main' with a function in -lrx:
  69 dnl AC_CHECK_LIB(rx, main)
  70 dnl Replace `main' with a function in -lrxkad:
  71 dnl AC_CHECK_LIB(rxkad, main)
  72 dnl Replace `main' with a function in -lsys:
  73 dnl AC_CHECK_LIB(sys, main)
  74 dnl Replace `main' with a function in -lubik:
  75 dnl AC_CHECK_LIB(ubik, main)
  76
  77
  78 #
  79 # Check presence of some functions
  80 #
  81 # Check for XPG4 access() function
  82 # Be sure to test before adding AFS libs in LIBS path as AFS lib
  83 # has such a function that works only on AFS filesystems.
  84 AC_CHECK_FUNCS(access)
  85 #
  86 AC_CHECK_FUNCS(pread pwrite)
  87
  88 dnl Checks for header files.
  89 AC_HEADER_DIRENT
  90 AC_HEADER_STDC
  91 AC_HEADER_SYS_WAIT
  92 AC_CHECK_HEADERS(fcntl.h limits.h stdint.h strings.h time.h sys/param.h sys/fcntl.h sys/file.h sys/ioctl.h sys/time.h sys/mnttab.h sys/statvfs.h sys/stat.h sys/vfs.h mntent.h syslog.h unistd.h termios.h sys/termios.h netdb.h sgtty.h ufs/quota.h mount.h statfs.h sys/types.h dlfcn.h errno.h sys/errno.h sys/uio.h)
  93 AC_CHECK_HEADER(sys/cdefs.h,,
  94         AC_MSG_RESULT([enabling generic cdefs.h from tree])
  95         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
  96 )
  97 AC_CHECK_HEADERS([sys/mount.h], , ,
  98 [#ifdef HAVE_SYS_PARAM_H
  99 #include <sys/param.h>
 100 #endif
 101 ])
 102
 103 AC_CHECK_HEADERS(langinfo.h locale.h sys/filio.h)
 104
 105 dnl Checks for typedefs, structures, and compiler characteristics.
 106 AC_C_CONST
 107 AC_TYPE_UID_T
 108 AC_C_INLINE
 109 AC_TYPE_MODE_T
 110 AC_TYPE_OFF_T
 111 AC_TYPE_PID_T
 112 AC_TYPE_SIZE_T
 113 AC_STRUCT_ST_RDEV
 114 AC_HEADER_TIME
 115 AC_STRUCT_TM
 116
 117 dnl --------------------------------------------------------------------------
 118 dnl check if dlsym needs to add an underscore, uses libtool macros
 119 dnl --------------------------------------------------------------------------
 120 AC_LTDL_DLLIB
 121 AC_CHECK_FUNCS(dlopen dlsym dlclose)
 122 AC_LTDL_DLSYM_USCORE
 123 if test x"$libltdl_cv_need_uscore" = xyes; then
 124     AC_DEFINE(DLSYM_PREPEND_UNDERSCORE, 1, [BSD compatibility macro])
 125 fi
 126
 127
 128 dnl Checks for library functions.
 129 AC_TYPE_GETGROUPS
 130 AC_PROG_GCC_TRADITIONAL
 131 AC_FUNC_MEMCMP
 132 AC_HEADER_MAJOR
 133 AC_FUNC_MMAP
 134 AC_TYPE_SIGNAL
 135 AC_FUNC_UTIME_NULL
 136 AC_FUNC_WAIT3
 137 AC_CHECK_FUNCS(getcwd gethostname gettimeofday getusershell mkdir rmdir select socket strdup strcasestr strstr strtoul strchr memcpy)
 138 AC_CHECK_FUNCS(backtrace_symbols setlocale nl_langinfo)
 139 AC_CHECK_FUNCS(waitpid getcwd strdup strndup strnlen strtoul strerror chown fchown chmod fchmod chroot link mknod mknod64)
 140 AC_CHECK_FUNCS(strlcpy strlcat setlinebuf gethostid dirfd)
 141 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
 142 AC_CACHE_SAVE
 143
 144 dnl Checks for (v)snprintf
 145 NETATALK_SNPRINTF_CHECK
 146
 147 dnl --------------------------------------------------------------------------
 148 dnl 64bit platform check
 149 dnl --------------------------------------------------------------------------
 150
 151 AC_MSG_CHECKING([whether to check for 64bit libraries])
 152 dnl Determine libdir name
 153 case $host in
 154 *-*-linux*)
 155   # Test if the compiler is 64bit
 156   echo 'int i;' > conftest.$ac_ext
 157   atalk_cv_cc_64bit_output=no
 158   if AC_TRY_EVAL(ac_compile); then
 159     case `/usr/bin/file conftest.$ac_objext` in
 160     *"ELF 64"*)
 161       atalk_cv_cc_64bit_output=yes
 162       ;;
 163     esac
 164   fi
 165   rm -rf conftest*
 166   ;;
 167 esac
 168
 169 dnl
 170 dnl FIXME: Do we need something like this for Solaris 64bit?
 171 dnl
 172
 173 case $host_cpu:$atalk_cv_cc_64bit_output in
 174 powerpc64:yes | s390x:yes | sparc64:yes | x86_64:yes)
 175   atalk_libname="lib64"
 176   AC_MSG_RESULT([yes])
 177   ;;
 178 *:*)
 179   atalk_libname="lib"
 180   AC_MSG_RESULT([no])
 181   ;;
 182 esac
 183
 184 dnl --------------------------------------------------------------------------
 185 dnl specific configuration comes in here:
 186 dnl --------------------------------------------------------------------------
 187
 188
 189 netatalk_cv_admin_group=yes
 190 AC_MSG_CHECKING([for administrative group support])
 191 AC_ARG_ENABLE(admin-group,
 192         [  --disable-admin-group   disable admin group],[
 193         if test x"$enableval" = x"no"; then
 194                 AC_DEFINE(ADMIN_GRP, 0, [Define if the admin group should be enabled])
 195                 netatalk_cv_admin_group=no
 196                 AC_MSG_RESULT([no])
 197         else
 198                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 199                 AC_MSG_RESULT([yes])
 200         fi],[
 201                 AC_DEFINE(ADMIN_GRP, 1, [Define if the admin group should be enabled])
 202                 AC_MSG_RESULT([yes])
 203         ]
 204 )
 205
 206 NETATALK_AFS_CHECK
 207
 208 NETATALK_CONFIG_DIRS
 209
 210 netatalk_cv_with_cracklib=no
 211 AC_ARG_WITH(cracklib,
 212         [  --with-cracklib=DICT    enable/set location of cracklib dictionary],[
 213         if test "x$withval" != "xno" ; then
 214                 cracklib="$withval"
 215                 AC_CHECK_LIB(crack, main, [
 216                         AC_DEFINE(USE_CRACKLIB, 1, [Define if cracklib should be used])
 217                         LIBS="$LIBS -lcrack"
 218                         if test "$cracklib" = "yes"; then
 219                                 cracklib="/usr/$atalk_libname/cracklib_dict"
 220                         fi
 221                         AC_DEFINE_UNQUOTED(_PATH_CRACKLIB, "$cracklib",
 222                                 [path to cracklib dictionary])
 223                         AC_MSG_RESULT([setting cracklib dictionary to $cracklib])
 224                         netatalk_cv_with_cracklib=yes
 225                         ],[
 226                         AC_MSG_ERROR([cracklib not found!])
 227                         ]
 228                 )
 229         fi
 230         ]
 231 )
 232 AC_MSG_CHECKING([for cracklib support])
 233 AC_MSG_RESULT([$netatalk_cv_with_cracklib])
 234
 235 netatalk_cv_ddp_enabled=yes
 236 AC_MSG_CHECKING([whether to enable DDP])
 237 AC_ARG_ENABLE(ddp,
 238         [  --disable-ddp           disable DDP],[
 239         if test "$enableval" = "no"; then
 240                 AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 241                 AC_MSG_RESULT([no])
 242                 netatalk_cv_ddp_enabled=no
 243         else
 244                 AC_MSG_RESULT([yes])
 245         fi
 246         ],[
 247                 AC_MSG_RESULT([yes])
 248         ]
 249 )
 250
 251 AC_MSG_CHECKING([whether to enable debug code])
 252 AC_ARG_ENABLE(debug1,
 253         [  --enable-debug1         enable debug code],[
 254         if test "$enableval" != "no"; then
 255                 if test "$enableval" = "yes"; then
 256                         AC_DEFINE(DEBUG1, 1, [Define if debugging information should be included])
 257                 else
 258                         AC_DEFINE_UNQUOTED(DEBUG1, $enableval, [Define if debugging information should be included])
 259                 fi
 260                 AC_MSG_RESULT([yes])
 261         else
 262                 AC_MSG_RESULT([no])
 263         fi
 264         ],[
 265                 AC_MSG_RESULT([no])
 266         ]
 267 )
 268
 269 AC_MSG_CHECKING([whether to enable verbose debug code])
 270 AC_ARG_ENABLE(debug,
 271         [  --enable-debug          enable verbose debug code],[
 272         if test "$enableval" != "no"; then
 273                 if test "$enableval" = "yes"; then
 274                         AC_DEFINE(DEBUG, 1, [Define if verbose debugging information should be included])
 275                 else
 276                         AC_DEFINE_UNQUOTED(DEBUG, $enableval, [Define if verbose debugging information should be included])
 277                 fi
 278                 AC_MSG_RESULT([yes])
 279         else
 280                 AC_MSG_RESULT([no])
 281         fi
 282         ],[
 283                 AC_MSG_RESULT([no])
 284         ]
 285 )
 286
 287 AC_MSG_CHECKING([whether to enable debugging with debuggers])
 288 AC_ARG_ENABLE(debugging,
 289         [  --enable-debugging      disable SIGALRM timers and DSI tickles (eg for debugging with gdb/dbx/...)],[
 290         if test "$enableval" != "no"; then
 291                 if test "$enableval" = "yes"; then
 292                         AC_DEFINE(DEBUGGING, 1, [Define if you want to disable SIGALRM timers and DSI tickles])
 293                 else
 294                         AC_DEFINE_UNQUOTED(DEBUGGING, $enableval, [Define if you want to disable SIGALRM timers and DSI tickles])
 295                 fi
 296                 AC_MSG_RESULT([yes])
 297         else
 298                 AC_MSG_RESULT([no])
 299         fi
 300         ],[
 301                 AC_MSG_RESULT([no])
 302         ]
 303 )
 304
 305
 306 afp3=no
 307 afp3set=no
 308 AC_MSG_CHECKING([whether AFP 3.x calls should be enabled])
 309 AC_ARG_ENABLE(afp3,
 310         [  --disable-afp3          disable AFP 3.x calls],
 311         [
 312             if test x"$enableval" != x"no"; then
 313                 afp3set=yes
 314                 afp3=yes
 315                 AC_MSG_RESULT([yes])
 316             else
 317                 AC_MSG_RESULT([no])
 318             fi
 319         ],[
 320             AC_MSG_RESULT([yes])
 321             afp3=yes
 322         ]
 323 )
 324
 325 if test x"$afp3" = x"yes"; then
 326         AC_SYS_LARGEFILE([
 327                 AC_DEFINE(AFP3x, 1, [Define to enable AFP 3.x support])
 328         ],[
 329                 if test x"$afp3set" = x"yes"; then
 330                         AC_MSG_ERROR([AFP 3.x support requires Large File Support.])
 331                 else
 332                         AC_MSG_WARN([AFP 3.x support requires Large File Support. AFP3.x support disabled])
 333                         afp3=no
 334                 fi
 335         ])
 336 fi
 337
 338 AC_CHECK_ICONV
 339
 340 dnl ----------- A NOTE ABOUT DROPKLUDGE
 341 dnl The trouble with this fix is that if you know what the file is called, it
 342 dnl can be read from the Unix side.  That's okay for most academic institutions
 343 dnl since the students don't have telnet access to the Mac servers.  There is
 344 dnl currently no one working on further development/fixes of DROPKLUDGE.
 345 dnl -----------
 346
 347 netatalk_cv_dropkludge=no
 348 AC_MSG_CHECKING([whether to enable experimental dropbox support])
 349 AC_ARG_ENABLE(dropkludge,
 350         [  --enable-dropkludge     enable the experimental dropbox fix (INSECURE!) ],[
 351         if test "$enableval" = "yes"; then
 352                 AC_DEFINE(DROPKLUDGE, 1, [Define if you want to use the experimental dropkludge support])
 353                 AC_MSG_RESULT([yes])
 354                 netatalk_cv_dropkludge=yes
 355         else
 356                 AC_MSG_RESULT([no])
 357         fi
 358         ],[
 359                 AC_MSG_RESULT([no])
 360         ]
 361 )
 362
 363 netatalk_cv_force_uidgid=no
 364 AC_MSG_CHECKING([whether to enable forcing of uid/gid per volume])
 365 AC_ARG_ENABLE(force-uidgid,
 366         [  --enable-force-uidgid   allow forcing of uid/gid per volume (BROKEN) ],[
 367         if test "$enableval" = "yes"; then
 368                 AC_DEFINE(FORCE_UIDGID, 1, [Define if you want forcing of uid/gid per volume])
 369                 AC_MSG_RESULT([enabling forcing of uid/gid per volume])
 370                 AC_MSG_RESULT([yes])
 371                 netatalk_cv_force_uidgid=yes
 372         else
 373                 AC_MSG_RESULT([no])
 374         fi
 375         ],[
 376                 AC_MSG_RESULT([no])
 377         ]
 378 )
 379
 380 dnl Check for CNID database backends
 381 bdb_required=no
 382 AC_NETATALK_CNID([bdb_required=yes],[bdb_required=no])
 383
 384 dnl Check for quota support
 385 AC_CHECK_QUOTA
 386
 387 dnl Check for optional server location protocol support (used by MacOS X)
 388 NETATALK_SRVLOC
 389
 390 dnl Check for PAM libs
 391 netatalk_cv_use_pam=no
 392 AC_PATH_PAM([
 393         use_pam_so=yes
 394         compile_pam=yes
 395         netatalk_cv_use_pam=yes
 396         AC_DEFINE(USE_PAM, 1, [Define to enable PAM support])
 397 ])
 398
 399 netatalk_cv_use_shadowpw=no
 400 AC_ARG_WITH(shadow,
 401         [  --with-shadow           enable shadow password support [[auto]]],
 402         [netatalk_cv_use_shadowpw="$withval"],
 403         [netatalk_cv_use_shadowpw=auto]
 404 )
 405
 406 if test "x$netatalk_cv_use_shadowpw" != "xno"; then
 407     AC_CHECK_HEADER([shadow.h])
 408     if test x"$ac_cv_header_shadow_h" = x"yes"; then
 409         netatalk_cv_use_shadowpw=yes
 410         AC_DEFINE(SHADOWPW, 1, [Define if shadow passwords should be used])
 411     else
 412       if test "x$shadowpw" = "xyes"; then
 413         AC_MSG_ERROR([shadow support not available])
 414       else
 415         netatalk_cv_use_shadowpw=no
 416       fi
 417     fi
 418 fi
 419
 420 AC_MSG_CHECKING([whether shadow support should be enabled])
 421 if test "x$netatalk_cv_use_shadowpw" = "xyes"; then
 422         AC_MSG_RESULT([yes])
 423 else
 424         AC_MSG_RESULT([no])
 425 fi
 426
 427
 428
 429 netatalk_cv_use_shellcheck=yes
 430 AC_MSG_CHECKING([whether checking for a valid shell should be enabled])
 431 AC_ARG_ENABLE(shell-check,
 432         [  --disable-shell-check   disable checking for a valid shell],[
 433         if test "$enableval" = "no"; then
 434                 AC_DEFINE(DISABLE_SHELLCHECK, 1, [Define if shell check should be disabled])
 435                 AC_MSG_RESULT([no])
 436                 netatalk_cv_use_shellcheck=no
 437         else
 438                 AC_MSG_RESULT([yes])
 439         fi
 440         ],[
 441                 AC_MSG_RESULT([yes])
 442         ]
 443 )
 444
 445 NETATALK_TCP_WRAPPERS
 446
 447 AC_MSG_CHECKING([whether system (fcntl) locking should be disabled])
 448 AC_ARG_ENABLE(locking,
 449         [  --disable-locking       disable system locking],[
 450                 if test "$enableval" = "no"; then
 451                         AC_DEFINE(DISABLE_LOCKING, 1, [Define if system (fcntl) locking should be disabled])
 452                         AC_MSG_RESULT([yes])
 453                 else
 454                         AC_MSG_RESULT([no])
 455                 fi
 456
 457         ],[
 458                 AC_MSG_RESULT([no])
 459         ]
 460
 461 )
 462
 463
 464 AC_ARG_ENABLE(redhat,
 465         [  --enable-redhat         use redhat-style sysv configuration ],[
 466         if test "$enableval" = "yes"; then
 467                 sysv_style=redhat
 468         fi
 469         AC_MSG_RESULT([enabling redhat-style sysv support])
 470         ]
 471 )
 472
 473 AC_ARG_ENABLE(suse,
 474         [  --enable-suse           use suse-style sysv configuration ],[
 475         if test "$enableval" = "yes"; then
 476                 sysv_style=suse
 477         fi
 478         AC_MSG_RESULT([enabling suse-style sysv support])
 479         ]
 480 )
 481
 482 AC_ARG_ENABLE(gentoo,
 483         [  --enable-gentoo         use gentoo-style sysv configuration ],[
 484         if test "$enableval" = "yes"; then
 485                 sysv_style=gentoo
 486         fi
 487         AC_MSG_RESULT([enabling gentoo-style sysv support])
 488         ]
 489 )
 490
 491 AC_ARG_ENABLE(cobalt,
 492         [  --enable-cobalt         use cobalt-style sysv configuration ],
 493         if test "$enableval" = "yes"; then
 494                 sysv_style=cobalt
 495         fi
 496         AC_MSG_RESULT([enabling cobalt-style sysv support])
 497 )
 498
 499 AC_ARG_ENABLE(netbsd,
 500         [  --enable-netbsd         use NetBSD-style rc.d configuration ],
 501         if test "x$enableval" = "xyes"; then
 502                 sysv_style=netbsd
 503         fi
 504         AC_MSG_RESULT([enabling NetBSD-style rc.d support])
 505 )
 506
 507 AC_ARG_ENABLE(debian,
 508         [  --enable-debian         use debian-style sysv configuration ],[
 509         if test "$enableval" = "yes"; then
 510                 sysv_style=debian
 511         fi
 512         AC_MSG_RESULT([enabling debian-style sysv support])
 513         ]
 514 )
 515
 516 dnl ----- timelord compilation (disabled by default)
 517 AC_MSG_CHECKING([whether timelord should be compiled])
 518 compile_timelord=no
 519 AC_ARG_ENABLE(timelord,
 520         [  --enable-timelord       enable compilation of timelord server],
 521         [compile_timelord="$enableval"],
 522         [compile_timelord="no"]
 523 )
 524 AC_MSG_RESULT([$compile_timelord])
 525
 526 dnl ----- a2boot compilation (disabled by default)
 527 AC_MSG_CHECKING([whether a2boot should be compiled])
 528 compile_a2boot=no
 529 AC_ARG_ENABLE(a2boot,
 530         [  --enable-a2boot         enable compilation of Apple2 boot server],
 531         [compile_a2boot="$enableval"],
 532         [compile_a2boot="no"]
 533 )
 534 AC_MSG_RESULT([$compile_a2boot])
 535
 536 AC_ARG_WITH(uams-path,
 537         [  --with-uams-path=PATH   path to UAMs [[PKGCONF/uams]]],[
 538                 uams_path="$withval"
 539         ],[
 540                 uams_path="${PKGCONFDIR}/uams"
 541         ]
 542 )
 543
 544 NETATALK_AC_CUPS
 545
 546 dnl check if we can use attribute unused (gcc only) from ethereal
 547 AC_MSG_CHECKING(to see if we can add '__attribute__((unused))' to CFLAGS)
 548 if test x$GCC != x ; then
 549   CFLAGS="-D_U_=\"__attribute__((unused))\" $CFLAGS"
 550   AC_MSG_RESULT(yes)
 551 else
 552   CFLAGS="-D_U_=\"\" $CFLAGS"
 553   AC_MSG_RESULT(no)
 554 fi
 555
 556 dnl --------------------------------------------------------------------------
 557 dnl FHS stuff has to be done last because it overrides other defaults
 558 dnl --------------------------------------------------------------------------
 559
 560 AC_MSG_CHECKING([whether to use Filesystem Hierarchy Standard (FHS) compatibility])
 561 AC_ARG_ENABLE(fhs,
 562         [  --enable-fhs            use Filesystem Hierarchy Standard (FHS) compatibility],[
 563         if test "$enableval" = "yes"; then
 564                 uams_path="${libdir}/netatalk"
 565                 sysconfdir="/etc"
 566                 PKGCONFDIR=${sysconfdir}/netatalk
 567                 SERVERTEXT="${PKGCONFDIR}/msg"
 568                 use_pam_so=yes
 569                 mandir="/usr/share/man"
 570                 AC_DEFINE(FHS_COMPATIBILITY, 1, [Define if you want compatibily with the FHS])
 571                 AC_MSG_RESULT([yes])
 572         else
 573                 AC_MSG_RESULT([no])
 574         fi
 575         ],[
 576                 AC_MSG_RESULT([no])
 577         ]
 578 )
 579
 580 dnl --------------------------------------------------------------------------
 581 dnl post-FHS substitutions, etc
 582 dnl --------------------------------------------------------------------------
 583
 584 dnl ***** UAMS_PATH
 585 dnl AC_DEFINE_UNQUOTED(UAMS_PATH, "${uams_path}",
 586 dnl     [path to UAMs [default=PKGCONF/uams]])
 587 UAMS_PATH="${uams_path}"
 588 AC_SUBST(UAMS_PATH)
 589
 590 dnl --------------------------------------------------------------------------
 591 dnl drop in includes for top level directory structures here...
 592 dnl --------------------------------------------------------------------------
 593
 594 dnl Note: $(top_srcdir)/include should be added before all other includes
 595 dnl       so that includes from that directory a preferred to includes from
 596 dnl       /usr/include or similar places.
 597 LIBS="$LIBS -L\$(top_srcdir)/libatalk"
 598 CFLAGS="-I\$(top_srcdir)/include $CFLAGS -I\$(top_srcdir)/sys"
 599
 600 dnl --------------------------------------------------------------------------
 601 dnl specific configuration comes in here:
 602 dnl --------------------------------------------------------------------------
 603
 604 dnl ac_cv_target_os is now host_os, ac_cv_target_cpu is now host_cpu
 605
 606 dnl --------------------- determine operating system from "target"
 607 case "$host_os" in
 608         *aix*)                          this_os=aix ;;
 609         *freebsd*)                      this_os=freebsd ;;
 610         *hpux11*)                       this_os=hpux11 ;;
 611         *irix*)                         this_os=irix ;;
 612         *linux*)                        this_os=linux ;;
 613         *osx*)                          this_os=macosx ;;
 614         *darwin*)                       this_os=macosx ;;
 615         *netbsd*)                       this_os=netbsd ;;
 616         *openbsd*)                      this_os=openbsd ;;
 617         *osf*)                          this_os=tru64 ;;
 618         *solaris*)                      this_os=solaris ;;
 619 esac
 620
 621 case "$host_cpu" in
 622         i386|i486|i586|i686|k7)         this_cpu=x86 ;;
 623         alpha)                                          this_cpu=alpha ;;
 624         mips)                                           this_cpu=mips ;;
 625         powerpc|ppc)                            this_cpu=ppc ;;
 626 esac
 627
 628 dnl --------------------- GNU source
 629 case "$this_os" in
 630         linux)  AC_DEFINE(_GNU_SOURCE, 1, [Whether to use GNU libc extensions])
 631         ;;
 632 esac
 633
 634 dnl --------------------- operating system specific flags (port from sys/*)
 635
 636 dnl ----- AIX specific -----
 637 if test x"$this_os" = "xaix"; then
 638         AC_MSG_RESULT([ * AIX specific configuration])
 639         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 640
 641         dnl This is probably a lie; AIX 4.3 supports a 64-bit long
 642         dnl compilation environment.  It's enough to get things defined
 643         dnl right in endian.h provided that long long is supported, though.
 644         AC_DEFINE(HAVE_32BIT_LONGS, 1, [Define if the data type long has 32 bit])
 645 fi
 646
 647 dnl ----- FreeBSD specific -----
 648 if test x"$this_os" = "xfreebsd"; then
 649         AC_MSG_RESULT([ * FreeBSD specific configuration])
 650         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 651         AC_DEFINE(FREEBSD, 1, [Define if OS is FreeBSD])
 652         AC_DEFINE(SENDFILE_FLAVOR_BSD, 1, [Define if the sendfile() function uses BSD semantics])
 653 fi
 654
 655 dnl ----- HP-UX 11 specific -----
 656 if test x"$this_os" = "xhpux11"; then
 657         AC_MSG_RESULT([ * HP-UX 11 specific configuration])
 658
 659         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 660         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 661 fi
 662
 663 dnl ----- IRIX specific -----
 664 if test x"$this_os" = "xirix"; then
 665         AC_MSG_RESULT([ * IRIX specific configuration])
 666
 667         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 668 fi
 669
 670 dnl ----- Linux specific -----
 671 if test x"$this_os" = "xlinux"; then
 672         AC_MSG_RESULT([ * Linux specific configuration])
 673
 674         dnl ----- kernel 2.6 changed struct at_addr to atalk_addr
 675         AC_MSG_CHECKING([for struct atalk_addr])
 676 dnl     AC_COMPILE_IFELSE([
 677         AC_TRY_COMPILE([
 678 #include <sys/socket.h>
 679 #include <asm/types.h>
 680 #include <linux/atalk.h>
 681
 682         struct atalk_addr foo;
 683 ],
 684 [ ], [
 685                 ac_have_atalk_addr=yes
 686                 AC_MSG_RESULT([yes])
 687         ], [
 688                 AC_MSG_RESULT([no])
 689         ])
 690
 691 if test "x$ac_have_atalk_addr" = "xyes"; then
 692         AC_DEFINE(HAVE_ATALK_ADDR, 1, [set if struct at_addr is called atalk_addr])
 693 fi
 694
 695         dnl ----- check if we need the quotactl wrapper
 696 #       AC_CHECK_HEADERS(sys/quota.h linux/quota.h)
 697 #       AC_CHECK_FUNC(quotactl,,
 698 #               AC_DEFINE(NEED_QUOTACTL_WRAPPER, 1, [Define if the quotactl wrapper is needed])
 699 #               AC_MSG_RESULT([enabling quotactl wrapper])
 700 #       )
 701
 702         # For quotas on Linux XFS filesystems
 703
 704         # For linux > 2.5.56
 705         AC_CHECK_HEADERS(linux/dqblk_xfs.h,,
 706                 [AC_CHECK_HEADERS(linux/xqm.h linux/xfs_fs.h)
 707                 AC_CHECK_HEADERS(xfs/libxfs.h xfs/xqm.h xfs/xfs_fs.h)]
 708         )
 709
 710
 711         dnl ----- as far as I can tell, dbtob always does the wrong thing
 712         dnl ----- on every single version of linux I've ever played with.
 713         dnl ----- see etc/afpd/quota.c
 714         AC_DEFINE(HAVE_BROKEN_DBTOB, 1, [Define if dbtob is broken])
 715
 716         netatalk_cv_linux_sendfile=yes
 717         AC_MSG_CHECKING([use sendfile syscall])
 718         AC_ARG_ENABLE(sendfile,
 719             [  --disable-sendfile       disable linux sendfile syscall],[
 720                 if test x"$enableval" = x"no"; then
 721                         netatalk_cv_linux_sendfile=no
 722                         AC_MSG_RESULT([no])
 723                 else
 724                         AC_MSG_RESULT([yes])
 725
 726                 fi
 727             ],[
 728                 AC_MSG_RESULT([yes])
 729         ]
 730
 731        )
 732
 733         if test x"$netatalk_cv_linux_sendfile" = "xyes"; then
 734             AC_CACHE_CHECK([for linux sendfile support],netatalk_cv_HAVE_SENDFILE,[
 735             AC_TRY_LINK([#include <sys/sendfile.h>],
 736 [\
 737 int tofd, fromfd;
 738 off_t offset;
 739 size_t total;
 740 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 741 ],
 742 netatalk_cv_HAVE_SENDFILE=yes,netatalk_cv_HAVE_SENDFILE=no)])
 743
 744 # Try and cope with broken Linux sendfile....
 745             AC_CACHE_CHECK([for broken linux sendfile support],netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE,[
 746             AC_TRY_LINK([\
 747 #if defined(_FILE_OFFSET_BITS) && (_FILE_OFFSET_BITS == 64)
 748 #undef _FILE_OFFSET_BITS
 749 #endif
 750 #include <sys/sendfile.h>],
 751 [\
 752 int tofd, fromfd;
 753 off_t offset;
 754 size_t total;
 755 ssize_t nwritten = sendfile(tofd, fromfd, &offset, total);
 756 ],
 757 netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=yes,netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE=no,netatalk_cv_HAVE_BROKEN_SENDFILE=cross)])
 758
 759             if test x"$netatalk_cv_HAVE_SENDFILE" = x"yes"; then
 760                 AC_DEFINE(HAVE_SENDFILE,1,[Whether sendfile() is available])
 761                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 762                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile() should be used])
 763             elif test x"$netatalk_cv_HAVE_BROKEN_LINUX_SENDFILE" = x"yes"; then
 764                 AC_DEFINE(SENDFILE_FLAVOR_LINUX,1,[Whether linux sendfile() API is available])
 765                 AC_DEFINE(LINUX_BROKEN_SENDFILE_API,1,[Whether (linux) sendfile() is broken])
 766                 AC_DEFINE(WITH_SENDFILE,1,[Whether sendfile should be used])
 767             else
 768                 netatalk_cv_linux_sendfile=no
 769                 AC_MSG_RESULT(no);
 770             fi
 771         fi
 772
 773         dnl ----- Linux/alpha specific -----
 774         if test x"$this_cpu" = "xalpha"; then
 775                 AC_MSG_RESULT([enabling gcc memcpy bug workaround])
 776                 AC_DEFINE(HAVE_GCC_MEMCPY_BUG, 1, [Define if memcpy is buggy])
 777         fi
 778         need_dash_r=no
 779
 780
 781 fi
 782
 783 dnl ----- Mac OSX specific -----
 784 if test x"$this_os" = "xmacosx"; then
 785         AC_MSG_RESULT([ * Mac OSX specific configuration])
 786         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 787         AC_DEFINE(HAVE_2ARG_DBTOB, 1, [Define if dbtob takes two arguments])
 788         dnl AC_DEFINE(NO_DLFCN_H)
 789         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 790         AC_DEFINE(NO_QUOTA_SUPPORT, 1, [Define if Quota support should be disabled])
 791         AC_DEFINE(MACOSX_SERVER, 1, [Define if compiling for MacOS X Server])
 792 fi
 793
 794 dnl ----- NetBSD specific -----
 795 if test x"$this_os" = "xnetbsd"; then
 796         AC_MSG_RESULT([ * NetBSD specific configuration])
 797         AC_DEFINE(BSD4_4, 1, [BSD compatiblity macro])
 798         AC_DEFINE(NETBSD, 1, [Define if OS is FreeBSD])
 799         CFLAGS="-I\$(top_srcdir)/sys/netbsd -I/usr/include/kerberosIV $CFLAGS"
 800         need_dash_r=yes
 801
 802         dnl ----- NetBSD does not have crypt.h, uses unistd.h -----
 803         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 804 fi
 805
 806 dnl ----- OpenBSD specific -----
 807 if test x"$this_os" = "xopenbsd"; then
 808         AC_MSG_RESULT([ * OpenBSD specific configuration])
 809         dnl ----- OpenBSD does not have crypt.h, uses unistd.h -----
 810         AC_DEFINE(UAM_DHX, 1, [Define if the DHX UAM modules should be compiled])
 811 fi
 812
 813 dnl ----- Solaris specific -----
 814 if test x"$this_os" = "xsolaris"; then
 815         AC_MSG_RESULT([ * Solaris specific configuration])
 816         AC_DEFINE(__svr4__, 1, [Solaris compatibility macro])
 817         AC_DEFINE(_ISOC9X_SOURCE, 1, [Compatibility macro])
 818         AC_DEFINE(NO_STRUCT_TM_GMTOFF, 1, [Define if the gmtoff member of struct tm is not available])
 819         AC_DEFINE(SOLARIS, 1, [Solaris compatibility macro])
 820         CFLAGS="-I\$(top_srcdir)/sys/generic $CFLAGS"
 821         need_dash_r=yes
 822         sysv_style=solaris
 823
 824         solaris_module=no
 825         AC_MSG_CHECKING([if we can build Solaris kernel module])
 826         if test -x /usr/ccs/bin/ld; then
 827                 solaris_module=yes
 828         fi
 829         AC_MSG_RESULT([$solaris_module])
 830
 831         COMPILE_64BIT_KMODULE=no
 832         KCFLAGS=""
 833         KLDFLAGS=""
 834         COMPILE_KERNEL_GCC=no
 835
 836         if test "$solaris_module" = "yes"; then
 837            dnl Solaris kernel module stuff
 838            AC_MSG_CHECKING([if we have to build a 64bit kernel module])
 839
 840            # check for isainfo, if not found it has to be a 32 bit kernel (<=2.6)
 841            if test -x /usr/bin/isainfo; then
 842                 # check for 64 bit platform
 843                 if isainfo -kv | grep '^64-bit'; then
 844                         COMPILE_64BIT_KMODULE=yes
 845                 fi
 846            fi
 847
 848            AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 849
 850            if test "${GCC}" = yes; then
 851                 COMPILE_KERNEL_GCC=yes
 852                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 853
 854                         AC_MSG_CHECKING([if we can build a 64bit kernel module])
 855
 856                         case `$CC --version 2>/dev/null` in
 857                         [[12]].* | 3.0.*)
 858                                 COMPILE_64BIT_KMODULE=no
 859                                 COMPILE_KERNEL_GCC=no
 860                                 solaris_module=no;;
 861                         *)
 862                                 # use for 64 bit
 863                                 KCFLAGS="-m64"
 864                                 #KLDFLAGS="-melf64_sparc"
 865                                 KLDFLAGS="-64";;
 866                         esac
 867
 868                         AC_MSG_RESULT([$COMPILE_64BIT_KMODULE])
 869
 870                 else
 871                         KCFLAGS=""
 872                         KLDFLAGS=""
 873                 fi
 874                 KCFLAGS="$KCFLAGS -D_KERNEL -Wall -Wstrict-prototypes"
 875            else
 876                 if test "$COMPILE_64BIT_KMODULE" = yes; then
 877                 # use Sun CC (for a 64-bit kernel, uncomment " -xarch=v9 -xregs=no%appl ")
 878                         KCFLAGS="-xarch=v9 -xregs=no%appl"
 879                         KLDFLAGS="-64"
 880                 else
 881                         KCFLAGS=""
 882                         KLDFLAGS=""
 883                 fi
 884                 KCFLAGS="-D_KERNEL $KCFLAGS -mno-app-regs -munaligned-doubles -fpcc-struct-return"
 885            fi
 886
 887            AC_CACHE_CHECK([for timeout_id_t],netatalk_cv_HAVE_TIMEOUT_ID_T,[
 888            AC_TRY_LINK([\
 889 #include <sys/stream.h>
 890 #include <sys/ddi.h>],
 891 [\
 892 timeout_id_t dummy;
 893 ],
 894 netatalk_cv_HAVE_TIMEOUT_ID_T=yes,netatalk_cv_HAVE_TIMEOUT_ID_T=no,netatalk_cv_HAVE_TIMEOUT_ID_T=cross)])
 895
 896            AC_DEFINE(HAVE_TIMEOUT_ID_T, test x"$netatalk_cv_HAVE_TIMEOUT_ID" = x"yes", [define for timeout_id_t])
 897         fi
 898
 899         AC_SUBST(COMPILE_KERNEL_GCC)
 900         AC_SUBST(COMPILE_64BIT_KMODULE)
 901         AC_SUBST(KCFLAGS)
 902         AC_SUBST(KLDFLAGS)
 903 fi
 904
 905 dnl ----- Tru64 specific -----
 906 if test x"$this_os" = "xtru64"; then
 907         AC_MSG_RESULT([ * Tru64 specific configuration])
 908         AC_DEFINE(NO_DDP, 1, [Define if DDP should be disabled])
 909         AC_DEFINE(HAVE_64BIT_LONGS, 1, [Define if the data type long has 64 bit])
 910         dnl AC_DEFINE(USE_MOUNT_H)
 911         AC_DEFINE(USE_OLD_RQUOTA, 1, [Define to use old rquota])
 912         dnl AC_DEFINE(USE_UFS_QUOTA_H)
 913         AC_DEFINE(TRU64, 1, [Define on Tru64 platforms])
 914         AC_DEFINE(_OSF_SOURCE, 1, [Define if the *passwd UAMs should be used])
 915         AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, [Define for Berkeley DB 4])
 916         AC_CHECK_LIB(security,set_auth_parameters)
 917         CFLAGS="-I\$(top_srcdir)/sys/tru64 $CFLAGS"
 918         need_dash_r=no
 919         sysv_style=tru64
 920 fi
 921
 922 dnl -- check for libgcrypt, if found enables DHX UAM
 923 AM_PATH_LIBGCRYPT([1:1.2.3],[neta_cv_compile_dhx2=yes
 924                         neta_cv_have_libgcrypt=yes
 925                         AC_MSG_NOTICE([Enabling DHX2 UAM])
 926                         AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define if the DHX2 modules should be built with libgcrypt])
 927                         AC_DEFINE(UAM_DHX2, 1, [Define if the DHX2 UAM modules should be compiled])
 928                         ])
 929
 930 dnl -- look for openssl, if found enables DHX UAM and Randnum UAM
 931 AC_PATH_SSL
 932
 933 dnl Check for Berkeley DB library
 934 if test "x$bdb_required" = "xyes"; then
 935         AC_PATH_BDB(, [
 936                 AC_MSG_RESULT([])
 937                 AC_MSG_RESULT([Make sure you have the required Berkeley DB libraries AND headers installed.])
 938                 AC_MSG_RESULT([You can download the latest version from http://www.sleepycat.com.])
 939                 AC_MSG_RESULT([If you have installed BDB in a non standard location use the])
 940                 AC_MSG_RESULT([--with-bdb=/path/to/bdb configure option and make sure])
 941                 AC_MSG_RESULT([your linker is configured to check for libraries there.])
 942                 AC_MSG_ERROR([Berkeley DB library required but not found!])
 943         ])
 944 fi
 945
 946 dnl -- check for crypt
 947 AC_CRYPT
 948
 949 dnl --------------------- check for building PGP UAM module
 950
 951 AC_MSG_CHECKING([whether the PGP UAM should be build])
 952 AC_ARG_ENABLE(pgp-uam,
 953         [  --enable-pgp-uam        enable build of PGP UAM module],[
 954         if test "$enableval" = "yes"; then
 955                 if test "x$neta_cv_have_openssl" = "xyes"; then
 956                         AC_DEFINE(UAM_PGP, 1, [Define if the PGP UAM module should be compiled])
 957                         compile_pgp=yes
 958                         AC_MSG_RESULT([yes])
 959                 else
 960                         AC_MSG_RESULT([no])
 961                 fi
 962         fi
 963         ],[
 964                 AC_MSG_RESULT([no])
 965         ]
 966 )
 967
 968 dnl --------------------- check for building Kerberos v4 UAM module
 969
 970 AC_MSG_CHECKING([whether the Kerberos IV UAM should be build])
 971 AC_ARG_ENABLE(krb4-uam,
 972         [  --enable-krb4-uam       enable build of Kerberos v4 UAM module],[
 973         if test "$enableval" = "yes"; then
 974                 AC_DEFINE(UAM_KRB4, 1, [Define if the Kerberos 4 UAM module should be compiled])
 975                 compile_kerberos=yes
 976                 AC_MSG_RESULT([yes])
 977         else
 978                 AC_MSG_RESULT([no])
 979         fi
 980         ],[
 981                 AC_MSG_RESULT([no])
 982         ]
 983 )
 984
 985 dnl --------------------- check for building Kerberos V UAM module
 986
 987 netatalk_cv_build_krb5_uam=no
 988 AC_ARG_ENABLE(krbV-uam,
 989         [  --enable-krbV-uam       enable build of Kerberos V UAM module],
 990         [
 991                 if test x"$enableval" = x"yes"; then
 992                         NETATALK_GSSAPI_CHECK([
 993                                 netatalk_cv_build_krb5_uam=yes
 994                         ],[
 995                                 AC_MSG_ERROR([need GSSAPI to build Kerberos V UAM])
 996                         ])
 997                 fi
 998         ]
 999
1000 )
1001
1002 AC_MSG_CHECKING([whether Kerberos V UAM should be build])
1003 if test x"$netatalk_cv_build_krb5_uam" = x"yes"; then
1004         AC_MSG_RESULT([yes])
1005 else
1006         AC_MSG_RESULT([no])
1007 fi
1008 AM_CONDITIONAL(USE_GSSAPI, test x"$netatalk_cv_build_krb5_uam" = x"yes")
1009
1010 dnl --------------------- overwrite the config files . . . or not.
1011
1012 AC_MSG_CHECKING([whether configuration files should be overwritten])
1013 AC_ARG_ENABLE(overwrite,
1014         [  --enable-overwrite      overwrite configuration files during installation],
1015         [OVERWRITE_CONFIG="${enable_overwrite}"],
1016         [OVERWRITE_CONFIG="no"]
1017 )
1018 AC_MSG_RESULT([$OVERWRITE_CONFIG])
1019
1020 dnl --------------------- check for ACL support
1021 neta_cv_nfsv4acl="no"
1022 AC_MSG_CHECKING([if NFSv4 ACL Support should be enabled])
1023 AC_ARG_ENABLE(nfsv4acls,
1024         [  --enable-nfsv4acls      enable NFSv4 ACL Support],[
1025         if test x"$enableval" = x"yes"; then
1026            AC_MSG_RESULT([yes])
1027            neta_cv_nfsv4acl="yes"
1028         else
1029            AC_MSG_RESULT([no])
1030         fi],[
1031            AC_MSG_RESULT([no])
1032         ]
1033 )
1034 if test x$neta_cv_nfsv4acl = xyes; then
1035         AC_CHECK_HEADER([ldap.h],,[
1036                 AC_MSG_ERROR([ACL Support need the LDAP client headers not found.])
1037                 neta_cv_nfsv4acl=no
1038                 ]
1039         )
1040         AC_CHECK_LIB(ldap,ldap_init,neta_cv_nfsv4acl=yes,neta_cv_nfsv4acl=no)
1041 fi
1042 if test x$neta_cv_nfsv4acl = xyes; then
1043         AC_CHECK_HEADER([sys/acl.h],[
1044                 AC_DEFINE([HAVE_NFSv4_ACLS], 1, [Enable ACL code])
1045                 AC_MSG_NOTICE([Enabling ACL support])
1046                 ],
1047                 neta_cv_nfsv4acl=no
1048         )
1049 fi
1050 if test x$neta_cv_nfsv4acl = xyes; then
1051         LIBATALK_ACLS="acl/libacl.la"
1052 else
1053         LIBATALK_ACLS=""
1054 fi
1055 AC_SUBST(LIBATALK_ACLS)
1056
1057 dnl --------------------- check for Extended Attributes support
1058 neta_cv_eas="files"
1059 neta_cv_eas_sys_found=no
1060 neta_cv_eas_sys_not_found=no
1061
1062 AC_CHECK_HEADERS(sys/attributes.h attr/xattr.h sys/xattr.h sys/extattr.h sys/uio.h sys/ea.h)
1063
1064 case "$this_os" in
1065
1066   *osf*)
1067         AC_SEARCH_LIBS(getproplist, [proplist])
1068         AC_CHECK_FUNCS([getproplist fgetproplist setproplist fsetproplist],
1069                    [neta_cv_eas_sys_found=yes],
1070                    [neta_cv_eas_sys_not_found=yes])
1071         AC_CHECK_FUNCS([delproplist fdelproplist add_proplist_entry get_proplist_entry],,
1072                    [neta_cv_eas_sys_not_found=yes])
1073         AC_CHECK_FUNCS([sizeof_proplist_entry],,
1074                    [neta_cv_eas_sys_not_found=yes])
1075   ;;
1076
1077   *solaris*)
1078         AC_CHECK_FUNCS([attropen],
1079                    [neta_cv_eas_sys_found=yes],
1080                    [neta_cv_eas_sys_not_found=yes])
1081   ;;
1082
1083   *)
1084         AC_SEARCH_LIBS(getxattr, [attr])
1085
1086     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1087        AC_CHECK_FUNCS([getxattr lgetxattr fgetxattr listxattr llistxattr],
1088                       [neta_cv_eas_sys_found=yes],
1089                       [neta_cv_eas_sys_not_found=yes])
1090            AC_CHECK_FUNCS([flistxattr removexattr lremovexattr fremovexattr],,
1091                       [neta_cv_eas_sys_not_found=yes])
1092            AC_CHECK_FUNCS([setxattr lsetxattr fsetxattr],,
1093                       [neta_cv_eas_sys_not_found=yes])
1094     fi
1095
1096     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1097            AC_CHECK_FUNCS([getea fgetea lgetea listea flistea llistea],
1098                       [neta_cv_eas_sys_found=yes],
1099                       [neta_cv_eas_sys_not_found=yes])
1100            AC_CHECK_FUNCS([removeea fremoveea lremoveea setea fsetea lsetea],,
1101                       [neta_cv_eas_sys_not_found=yes])
1102     fi
1103
1104     if test "x$neta_cv_eas_sys_found" != "xyes" ; then
1105            AC_CHECK_FUNCS([attr_get attr_list attr_set attr_remove],,
1106                       [neta_cv_eas_sys_not_found=yes])
1107        AC_CHECK_FUNCS([attr_getf attr_listf attr_setf attr_removef],,
1108                       [neta_cv_eas_sys_not_found=yes])
1109     fi
1110   ;;
1111 esac
1112
1113 # Do xattr functions take additional options like on Darwin?
1114 if test x"$ac_cv_func_getxattr" = x"yes" ; then
1115         AC_CACHE_CHECK([whether xattr interface takes additional options], smb_attr_cv_xattr_add_opt, [
1116                 old_LIBS=$LIBS
1117                 LIBS="$LIBS $ACL_LIBS"
1118                 AC_TRY_COMPILE([
1119                         #include <sys/types.h>
1120                         #if HAVE_ATTR_XATTR_H
1121                         #include <attr/xattr.h>
1122                         #elif HAVE_SYS_XATTR_H
1123                         #include <sys/xattr.h>
1124                         #endif
1125                 ],[
1126                         getxattr(0, 0, 0, 0, 0, 0);
1127                 ],
1128                 [smb_attr_cv_xattr_add_opt=yes],
1129                 [smb_attr_cv_xattr_add_opt=no;LIBS=$old_LIBS])
1130         ])
1131         if test x"$smb_attr_cv_xattr_add_opt" = x"yes"; then
1132                 AC_DEFINE(XATTR_ADD_OPT, 1, [xattr functions have additional options])
1133         fi
1134 fi
1135
1136 # Check if we have extattr
1137 case "$this_os" in
1138   *freebsd4* | *dragonfly* )
1139     AC_DEFINE(BROKEN_EXTATTR, 1, [Does extattr API work])
1140     ;;
1141   *)
1142     AC_CHECK_FUNCS(extattr_delete_fd extattr_delete_file extattr_delete_link)
1143     AC_CHECK_FUNCS(extattr_get_fd extattr_get_file extattr_get_link)
1144     AC_CHECK_FUNCS(extattr_list_fd extattr_list_file extattr_list_link)
1145     AC_CHECK_FUNCS(extattr_set_fd extattr_set_file extattr_set_link)
1146     ;;
1147 esac
1148
1149 if test "x$neta_cv_eas_sys_found" = "xyes" ; then
1150    if test "x$neta_cv_eas_sys_not_found" != "xyes" ; then
1151       neta_cv_eas="$neta_cv_eas | native"
1152    fi
1153 fi
1154
1155 dnl --------------------- Check if realpath() takes NULL
1156 AC_CACHE_CHECK([if the realpath function allows a NULL argument],
1157     neta_cv_REALPATH_TAKES_NULL, [
1158         AC_TRY_RUN([
1159             #include <stdio.h>
1160             #include <limits.h>
1161             #include <signal.h>
1162
1163             void exit_on_core(int ignored) {
1164                  exit(1);
1165             }
1166
1167             main() {
1168                 char *newpath;
1169                 signal(SIGSEGV, exit_on_core);
1170                 newpath = realpath("/tmp", NULL);
1171                 exit((newpath != NULL) ? 0 : 1);
1172             }],
1173             neta_cv_REALPATH_TAKES_NULL=yes,
1174             neta_cv_REALPATH_TAKES_NULL=no,
1175             neta_cv_REALPATH_TAKES_NULL=cross
1176         )
1177     ]
1178 )
1179
1180 if test x"$neta_cv_REALPATH_TAKES_NULL" = x"yes"; then
1181     AC_DEFINE(REALPATH_TAKES_NULL,1,[Whether the realpath function allows NULL])
1182 fi
1183
1184 dnl --------------------- Netatalk Webmin
1185 NETATALK_WEBMIN
1186
1187 dnl --------------------- last minute substitutions
1188
1189 AC_SUBST(LIBS)
1190 AC_SUBST(CFLAGS)
1191 AC_SUBST(OVERWRITE_CONFIG)
1192
1193 AM_CONDITIONAL(SOLARIS_MODULE, test x$solaris_module = xyes)
1194 AM_CONDITIONAL(COMPILE_TIMELORD, test x$compile_timelord = xyes)
1195 AM_CONDITIONAL(COMPILE_A2BOOT, test x$compile_a2boot = xyes)
1196 AM_CONDITIONAL(HAVE_LIBGCRYPT, test x$neta_cv_have_libgcrypt = xyes)
1197 AM_CONDITIONAL(HAVE_OPENSSL, test x$neta_cv_have_openssl = xyes)
1198 AM_CONDITIONAL(USE_NFSv4_ACLS, test x$neta_cv_nfsv4acl = xyes)
1199 AM_CONDITIONAL(USE_DHX, test x$neta_cv_compile_dhx = xyes)
1200 AM_CONDITIONAL(USE_DHX2, test x$neta_cv_compile_dhx2 = xyes)
1201 AM_CONDITIONAL(USE_RANDNUM, test x$neta_cv_have_openssl = xyes)
1202 AM_CONDITIONAL(USE_KERBEROS, test x$compile_kerberos = xyes)
1203 AM_CONDITIONAL(USE_PAM_SO, test x$use_pam_so = xyes)
1204 AM_CONDITIONAL(USE_PAM, test x$netatalk_cv_install_pam = xyes)
1205 AM_CONDITIONAL(BUILD_PAM, test x$compile_pam = xyes)
1206 AM_CONDITIONAL(USE_PGP, test x$compile_pgp = xyes)
1207 AM_CONDITIONAL(DEFAULT_HOOK, test x$neta_cv_have_libgcrypt != xyes && test x$neta_cv_have_openssl != xyes)
1208 AM_CONDITIONAL(USE_COBALT, test x$sysv_style = xcobalt)
1209 AM_CONDITIONAL(USE_NETBSD, test x$sysv_style = xnetbsd)
1210 AM_CONDITIONAL(USE_REDHAT, test x$sysv_style = xredhat)
1211 AM_CONDITIONAL(USE_SUSE, test x$sysv_style = xsuse)
1212 AM_CONDITIONAL(USE_SHADOWPW, test x$shadowpw = xyes)
1213 AM_CONDITIONAL(USE_TRU64, test x$sysv_style = xtru64)
1214 AM_CONDITIONAL(USE_SOLARIS, test x$sysv_style = xsolaris)
1215 AM_CONDITIONAL(USE_GENTOO, test x$sysv_style = xgentoo)
1216 AM_CONDITIONAL(USE_DEBIAN, test x$sysv_style = xdebian)
1217 AM_CONDITIONAL(USE_UNDEF, test x$sysv_style = x)
1218 AM_CONDITIONAL(USE_BDB, test x$bdb_required = xyes)
1219
1220 dnl --------------------- generate files
1221
1222 AC_OUTPUT([Makefile
1223         bin/Makefile
1224         bin/adv1tov2/Makefile
1225         bin/aecho/Makefile
1226         bin/afile/Makefile
1227         bin/afppasswd/Makefile
1228         bin/cnid/Makefile
1229         bin/cnid/cnid2_create
1230         bin/getzones/Makefile
1231         bin/megatron/Makefile
1232     bin/misc/Makefile
1233         bin/nbp/Makefile
1234         bin/pap/Makefile
1235         bin/psorder/Makefile
1236         bin/uniconv/Makefile
1237         config/Makefile
1238     config/pam/Makefile
1239         contrib/Makefile
1240         contrib/macusers/Makefile
1241         contrib/macusers/macusers
1242         contrib/printing/Makefile
1243         contrib/shell_utils/Makefile
1244         contrib/shell_utils/afpd-mtab.pl
1245         contrib/shell_utils/apple_cp
1246     contrib/shell_utils/apple_dump
1247         contrib/shell_utils/apple_mv
1248         contrib/shell_utils/apple_rm
1249         contrib/shell_utils/asip-status.pl
1250         contrib/timelord/Makefile
1251         contrib/a2boot/Makefile
1252         distrib/Makefile
1253         distrib/config/Makefile
1254         distrib/config/netatalk-config
1255         distrib/initscripts/Makefile
1256         distrib/m4/Makefile
1257         doc/Makefile
1258         etc/Makefile
1259         etc/afpd/Makefile
1260         etc/atalkd/Makefile
1261         etc/cnid_dbd/Makefile
1262         etc/uams/Makefile
1263         etc/uams/uams_krb4/Makefile
1264         etc/papd/Makefile
1265         etc/psf/Makefile
1266         include/Makefile
1267         include/atalk/Makefile
1268         libatalk/Makefile
1269         libatalk/acl/Makefile
1270         libatalk/adouble/Makefile
1271         libatalk/asp/Makefile
1272         libatalk/atp/Makefile
1273         libatalk/cnid/Makefile
1274         libatalk/cnid/cdb/Makefile
1275         libatalk/cnid/last/Makefile
1276         libatalk/cnid/dbd/Makefile
1277         libatalk/cnid/tdb/Makefile
1278         libatalk/compat/Makefile
1279         libatalk/dsi/Makefile
1280         libatalk/nbp/Makefile
1281         libatalk/netddp/Makefile
1282         libatalk/util/Makefile
1283         libatalk/util/test/Makefile
1284         libatalk/tdb/Makefile
1285         libatalk/unicode/Makefile
1286         libatalk/unicode/charsets/Makefile
1287         libatalk/vfs/Makefile
1288         macros/Makefile
1289         man/Makefile
1290         man/man1/Makefile
1291         man/man3/Makefile
1292         man/man4/Makefile
1293         man/man5/Makefile
1294         man/man8/Makefile
1295         sys/Makefile
1296         sys/generic/Makefile
1297         sys/generic/sys/Makefile
1298         sys/netatalk/Makefile
1299         sys/netbsd/Makefile
1300         sys/netbsd/netatalk/Makefile
1301         sys/solaris/Makefile
1302         sys/sunos/Makefile
1303         sys/ultrix/Makefile
1304         ],
1305         [chmod a+x distrib/config/netatalk-config contrib/shell_utils/apple_*]
1306 )
1307
1308 AC_NETATALK_LIBS_SUMMARY
1309 AC_NETATALK_CONFIG_SUMMARY