macros/ssl-check.m4

   1 dnl $Id: ssl-check.m4,v 1.8.6.1 2003-09-09 16:42:22 didg Exp $
   2 dnl Autoconf macro to check for SSL or OpenSSL
   3
   4 AC_DEFUN([AC_PATH_SSL], [
   5         AC_ARG_WITH(ssl-dir, [  --with-ssl-dir=PATH     specify path to OpenSSL installation (must contain
   6                           lib and include dirs)],
   7                 [
   8                         if test "x$withval" = "xno"; then
   9                                 tryssl=no
  10                         elif test "x$withval" = "xyes"; then
  11                                 tryssl=yes
  12                                 tryssldir=
  13                         else
  14                                 dnl FIXME: should only try in $withval
  15                                 tryssl=yes
  16                                 tryssldir="$withval"
  17                         fi
  18                 ], [tryssl=yes]
  19         )
  20
  21         SSL_CFLAGS=""
  22         SSL_LIBS=""
  23         saved_LIBS=$LIBS
  24         compile_ssl=no
  25
  26         if test "$tryssl" = "yes"; then
  27                 AC_MSG_CHECKING([for SSL])
  28                 for ssldir in "" $tryssldir /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl /usr/local/ssl ; do
  29                         if test -f "$ssldir/include/openssl/cast.h" ; then
  30                                 SSL_CFLAGS="$SSL_CFLAGS -I$ssldir/include -I$ssldir/include/openssl"
  31                                 SSL_LIBS="$SSL_LIBS -L$ssldir/lib -L$ssldir -lcrypto"
  32                                 if test "x$need_dash_r" = "xyes"; then
  33                                         SSL_LIBS="$SSL_LIBS -R$ssldir/lib -R$ssldir"
  34                                 fi
  35                                 AC_MSG_RESULT([$ssldir (enabling RANDNUM and DHX support)])
  36
  37 dnl FIXME: The following looks crude and probably doesn't work properly.
  38                                 dnl Check for the crypto library:
  39                                 AC_CHECK_LIB(crypto, main)
  40                                 dnl Check for "DES" library (for SSLeay, not openssl):
  41                                 AC_CHECK_LIB(des, main)
  42
  43                                 AC_DEFINE(OPENSSL_DHX,  1, [Define if the OpenSSL DHX modules should be built])
  44                                 AC_DEFINE(UAM_DHX,      1, [Define if the DHX UAM modules should be compiled])
  45                                 compile_ssl=yes
  46                                 break
  47                         fi
  48                 done
  49                 if test "x$compile_ssl" = "xno"; then
  50                         AC_MSG_RESULT([no])
  51                 fi
  52         fi
  53         CFLAGS_REMOVE_USR_INCLUDE(SSL_CFLAGS)
  54         LIB_REMOVE_USR_LIB(SSL_LIBS)
  55         AC_SUBST(SSL_CFLAGS)
  56         AC_SUBST(SSL_LIBS)
  57         LIBS=$saved_LIBS
  58 ])