etc/afpd/spotlight_rawquery_parser.y

   1 %{
   2   #include <atalk/standards.h>
   3
   4   #include <stdbool.h>
   5   #include <stdio.h>
   6   #include <string.h>
   7   #include <time.h>
   8
   9   #include <gio/gio.h>
  10
  11   #include <atalk/talloc.h>
  12   #include <atalk/logger.h>
  13   #include <atalk/errchk.h>
  14
  15   #include "spotlight_SPARQL_map.h"
  16   #include "spotlight.h"
  17
  18   struct yy_buffer_state;
  19   typedef struct yy_buffer_state *YY_BUFFER_STATE;
  20   extern int yylex (void);
  21   extern void yyerror (char const *);
  22   extern void *yyterminate(void);
  23   extern YY_BUFFER_STATE yy_scan_string( const char *str);
  24   extern void yy_delete_buffer ( YY_BUFFER_STATE buffer );
  25
  26   /* forward declarations */
  27   static const char *map_expr(const char *attr, char op, const char *val);
  28   static const char *map_daterange(const char *dateattr, time_t date1, time_t date2);
  29   static time_t isodate2unix(const char *s);
  30
  31  /* global vars, eg needed by the lexer */
  32   slq_t *ssp_slq;
  33
  34   /* local vars */
  35   static gchar *ssp_result;
  36
  37 %}
  38
  39 %code provides {
  40   #define SPRAW_TIME_OFFSET 978307200
  41   extern int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result);
  42   extern slq_t *ssp_slq;
  43 }
  44
  45 %union {
  46     int ival;
  47     const char *sval;
  48     bool bval;
  49     time_t tval;
  50 }
  51
  52 %expect 1
  53 %error-verbose
  54
  55 %type <sval> match expr line function
  56 %type <tval> date
  57
  58 %token <sval> WORD
  59 %token <bval> BOOL
  60 %token FUNC_INRANGE
  61 %token DATE_ISO
  62 %token OBRACE CBRACE EQUAL UNEQUAL GT LT COMMA QUOTE
  63 %left AND
  64 %left OR
  65 %%
  66
  67 input:
  68 /* empty */
  69 | input line
  70 ;
  71
  72 line:
  73 expr                           {
  74     ssp_result = talloc_asprintf(ssp_slq,
  75                                  "SELECT DISTINCT ?url WHERE "
  76                                  "{ ?x nie:url ?url FILTER(fn:starts-with(?url, 'file://%s/')) . %s}",
  77                                  ssp_slq->slq_vol->v_path, $1);
  78     $$ = ssp_result;
  79 }
  80 ;
  81
  82 expr:
  83 BOOL                             {
  84     if ($1 == false)
  85         YYACCEPT;
  86     else
  87         YYABORT;
  88 }
  89 | match OR match                 {
  90     if (strcmp($1, $3) != 0)
  91         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
  92     else
  93         $$ = talloc_asprintf(ssp_slq, "%s", $1);
  94 }
  95 | match                        {$$ = $1; if ($$ == NULL) YYABORT;}
  96 | function                     {$$ = $1;}
  97 | OBRACE expr CBRACE           {$$ = talloc_asprintf(ssp_slq, "%s", $2);}
  98 | expr AND expr                {$$ = talloc_asprintf(ssp_slq, "%s . %s", $1, $3);}
  99 | expr OR expr                 {
 100     if (strcmp($1, $3) != 0)
 101         $$ = talloc_asprintf(ssp_slq, "{ %s } UNION { %s }", $1, $3);
 102     else
 103         $$ = talloc_asprintf(ssp_slq, "%s", $1);
 104 }
 105 ;
 106
 107 match:
 108 WORD EQUAL QUOTE WORD QUOTE     {$$ = map_expr($1, '=', $4);}
 109 | WORD UNEQUAL QUOTE WORD QUOTE {$$ = map_expr($1, '!', $4);}
 110 | WORD LT QUOTE WORD QUOTE      {$$ = map_expr($1, '<', $4);}
 111 | WORD GT QUOTE WORD QUOTE      {$$ = map_expr($1, '>', $4);}
 112 ;
 113
 114 function:
 115 FUNC_INRANGE OBRACE WORD COMMA date COMMA date CBRACE {$$ = map_daterange($3, $5, $7);}
 116 ;
 117
 118 date:
 119 DATE_ISO OBRACE WORD CBRACE    {$$ = isodate2unix($3);}
 120 | WORD                         {$$ = atoi($1) + SPRAW_TIME_OFFSET;}
 121 ;
 122
 123 %%
 124
 125 static time_t isodate2unix(const char *s)
 126 {
 127     struct tm tm;
 128
 129     if (strptime(s, "%Y-%m-%dT%H:%M:%SZ", &tm) == NULL)
 130         return (time_t)-1;
 131     return mktime(&tm);
 132 }
 133
 134 const char *map_daterange(const char *dateattr, time_t date1, time_t date2)
 135 {
 136     EC_INIT;
 137     char *result = NULL;
 138     struct spotlight_sparql_map *p;
 139     struct tm *tmp;
 140     char buf1[64], buf2[64];
 141
 142     EC_NULL( tmp = localtime(&date1) );
 143     strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 144     EC_NULL( tmp = localtime(&date2) );
 145     strftime(buf2, sizeof(buf2), "%Y-%m-%dT%H:%M:%SZ", tmp);
 146
 147     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 148         if (strcmp(dateattr, p->ssm_spotlight_attr) == 0) {
 149             result = talloc_asprintf(ssp_slq,
 150                                      "?x %s ?d FILTER (?d > '%s' && ?d < '%s')",
 151                                      p->ssm_sparql_attr,
 152                                      buf1,
 153                                      buf2);
 154         }
 155     }
 156
 157 EC_CLEANUP:
 158     if (ret != 0)
 159         return NULL;
 160     return result;
 161 }
 162
 163 const char *map_expr(const char *attr, char op, const char *val)
 164 {
 165     EC_INIT;
 166     char *result = NULL;
 167     struct spotlight_sparql_map *p;
 168     time_t t;
 169     struct tm *tmp;
 170     char buf1[64];
 171
 172     for (p = spotlight_sparql_map; p->ssm_spotlight_attr; p++) {
 173         if (strcmp(p->ssm_spotlight_attr, attr) == 0) {
 174             switch (p->ssm_type) {
 175             case ssmt_bool:
 176                 result = talloc_asprintf(ssp_slq, "?x %s '%s'", p->ssm_sparql_attr, val);
 177                 break;
 178             case ssmt_num:
 179                 result = talloc_asprintf(ssp_slq, "?x %s ?y FILTER(?y %c '%s')", p->ssm_sparql_attr, op, val);
 180                 break;
 181             case ssmt_str:
 182                 result = talloc_asprintf(ssp_slq, "?x %s ?y FILTER(regex(?y, '%s'))", p->ssm_sparql_attr, val);
 183                 break;
 184             case ssmt_fts:
 185                 result = talloc_asprintf(ssp_slq, "?x %s '%s'", p->ssm_sparql_attr, val);
 186                 break;
 187             case ssmt_date:
 188                 t = atoi(val) + SPRAW_TIME_OFFSET;
 189                 EC_NULL( tmp = localtime(&t) );
 190                 strftime(buf1, sizeof(buf1), "%Y-%m-%dT%H:%M:%SZ", tmp);
 191                 result = talloc_asprintf(ssp_slq, "?x %s ?y FILTER(?y %c '%s')", p->ssm_sparql_attr, op, buf1);
 192                 break;
 193             default:
 194                 yyerror("unknown Spotlight attribute type");
 195                 EC_FAIL;
 196             }
 197             break;
 198         }
 199     }
 200
 201 EC_CLEANUP:
 202     return result;
 203 }
 204
 205 void yyerror(const char *str)
 206 {
 207 #ifdef MAIN
 208     printf("yyerror: %s\n", str);
 209 #else
 210     LOG(log_error, logtype_sl, "yyerror: %s", str);
 211 #endif
 212 }
 213
 214 int yywrap()
 215 {
 216     return 1;
 217 }
 218
 219 /**
 220  * Map a Spotlight RAW query string to a SPARQL query string
 221  *
 222  * @param[in]     slq            Spotlight query handle
 223  * @param[out]    sparql_result  Mapped SPARQL query, string is allocated in
 224  *                               talloc context of slq
 225  * @return        0 on success, -1 on error
 226  **/
 227 int map_spotlight_to_sparql_query(slq_t *slq, gchar **sparql_result)
 228 {
 229     EC_INIT;
 230     YY_BUFFER_STATE s = NULL;
 231     ssp_result = NULL;
 232
 233     ssp_slq = slq;
 234     s = yy_scan_string(slq->slq_qstring);
 235
 236     EC_ZERO( yyparse() );
 237
 238 EC_CLEANUP:
 239     if (s)
 240         yy_delete_buffer(s);
 241     if (ret == 0)
 242         *sparql_result = ssp_result;
 243     else
 244         *sparql_result = NULL;
 245     EC_EXIT;
 246 }
 247
 248 #ifdef MAIN
 249 int main(int argc, char **argv)
 250 {
 251     int ret;
 252     YY_BUFFER_STATE s;
 253
 254     if (argc != 2) {
 255         printf("usage: %s QUERY\n", argv[0]);
 256         return 1;
 257     }
 258
 259     ssp_slq = talloc_zero(NULL, slq_t);
 260     struct vol *vol = talloc_zero(ssp_slq, struct vol);
 261     vol->v_path = "/Volumes/test";
 262     ssp_slq->slq_vol = vol;
 263
 264     s = yy_scan_string(argv[1]);
 265
 266     ret = yyparse();
 267
 268     yy_delete_buffer(s);
 269
 270     if (ret == 0)
 271         printf("SPARQL: %s\n", ssp_result ? ssp_result : "(empty)");
 272
 273     return 0;
 274 }
 275 #endif